[数值计算] [已解决]批处理for语句里if嵌套

梦缘隋都

for /f "skip=1 tokens=1,2,3 delims= " %%i in ('wmic logicaldisk where "drivetype=3" get name^,size^,freespace') do (

    for /f %%a in ("%%i") do (

        set /a n+=1 

        set  AAA=%%i

        set  BBB=%%k

        rem 循环取值
        
        call :division !BBB! 1073741824  quote 2
        
        
        call:division !AAA! !BBB! quot 2 
       set degree=0.8  
echo 盘符%%j  空间!quote!GB  使用率为!quot! 

       )


)
复制代码

这段代码，需要在echo前面做一个判断  if !degree! lss !quot2!  则 输出  echo 盘符%%j  空间!quote!GB  使用率为!quot!
即想把使用率大于80%（这里是0.8）的磁盘分区信息打印出来，如果不是for在外面 就可以实现比较，但是在for里面就不知道该怎么实现了 ~~

pcl_test

回复 1# 梦缘隋都

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1-3 delims= " %%i in ('wmic logicaldisk where "drivetype=3" get name^,size^,freespace ^|findstr "[0-9]"') do (
>temp.vbs echo,a=%%i
>>temp.vbs echo,b=%%k
>>temp.vbs echo,s=b/1024/1024/1024
>>temp.vbs echo,fs=a/1024/1024/1024
>>temp.vbs echo,n=a/b*100
>>temp.vbs echo,wscript.echo round^(s,2^),round^(fs,2^),round^(n^)
for /f "tokens=1-3 delims= " %%a in ('cscript /nologo temp.vbs') do set "size=%%a" & set "freesize=%%b" & set "usage=%%c"
set /a usage=100-!usage!
del temp.vbs 2>nul
if !usage! gtr 80 echo,盘符%%j 总空间!size!GB 剩余空间!freesize!GB 使用率!usage!%%
)
pause
复制代码

梦缘隋都

太感谢 了，比我写的脚本高端多了 ，谢谢！

pcl_test

回复 3# 梦缘隋都
问题得到解答以后在标题最前面注明[已解决]
http://www.bathome.net/thread-3473-1-1.html