[其他] 求助：批处理批量下载网站上的多个图片

lemonlm99

帮忙写一个批处理文件，能够批量下载http网站上的图片,网址：cos.myqcloud.com/11000032/szldt/City440300CAPPI_20150717083600.png
图片隔6分钟会自动生成，需下载当天的图片并命名为日期+时间（例如：20150717083600.png），求各位大神帮忙解决，谢谢！

pcl_test

本版规则
1、求助时，务必在顶楼一次性把问题交代清楚，建议给出完整有针对性的样本，样本过大可发网盘分享链接。勿发无意义的标题
2、使用 code 标记把代码部分括起来（单击回复框的 <> 按钮，复制粘贴代码进去），以便复制。问题解决后，请编辑顶楼帖子在标题前面注明[已解决]

lemonlm99

亟需使用 谢谢

pcl_test

第三方工具curl
下载地址http://batch-cn.qiniudn.com/tool/curl.exe

@echo off&setlocal enabledelayedexpansion
set "url=http://cos.myqcloud.com/11000032/szldt"
:0
cls
echo;1、下载昨天生成的所有图片    2、下载当天00:00到当前时间生成的所有图片
echo;
set c=
set /p c=输入相应序号并回车：
if "%c%" equ "1" (goto 1) else if "%c%" equ "2" (goto 2) else (goto 0)
:1
>"%tmp%\getdt.vbs" echo;LastDate=date()-1:FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2):wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%tmp%\getdt.vbs"') do set dt=%%a
if not exist "%dt%\" md "%dt%\"
for /l %%b in (100 1 123) do (
   for /l %%c in (100 6 154) do (
      set h=%%b
      set m=%%c
      set t=!h:~1!!m:~1!00
      curl -o ".\%dt%\%dt%!t!.png" "%url%/City440300CAPPI_%dt%!t!.png"
   )
)
echo;已完成下载昨天生成的所有图&ping -n 3 0 >nul&goto 0
:2
for /f "tokens=2 delims==" %%a in ('wmic path win32_operatingsystem get LocalDateTime /value') do set dt=%%a
)
set dt=%dt:~,12%
if not exist "%dt:~,8%\" md "%dt:~,8%\"
set /a h1=1%dt:~-4,2%
set /a h2=%h1%-1
set /a m=1%dt:~-2,2%

for /l %%b in (100 1 %h2%) do (
   for /l %%c in (100 6 154) do (
      set a=%%b
      set b=%%c
      set t=!a:~1!!b:~1!00
      curl -o ".\%dt:~,8%\%dt:~,8%!t!.png" "%url%/City440300CAPPI_%dt:~,8%!t!.png"
   )
)

for /l %%d in (100 6 %m%) do (
    set b=%%d
    set t=!h1:~1!!b:~1!00
    curl -o ".\%dt:~,8%\%dt:~,8%!t!.png" "%url%/City440300CAPPI_%dt:~,8%!t!.png"
)
echo;已完成下载当天00:00到当前时间生成的所有图片&ping -n 3 0 >nul&goto 0
复制代码

lemonlm99

回复 4# pcl_test
已经可以使用了，非常完美，感谢！