[已解决]请教！如果用批处理更改某进程的CPU关联和优先级？

avi33

大大们，请教一下

怎么用批处理更改某个进程的CPU关联？
比如我想让红警2的程序game.exe和ra2.exe只关联CPU0，请问怎么写？

还有修改这两个进程的优先级为“实时”！

谢谢！

pcl_test

设置进程优先级为“实时”

@echo off
for %%a in ("game.exe" "ra2.exe") do wmic process where name="%%~a" call setpriority 256
pause
::64 Idle 优先级–低
::16384 Below Normal 优先级–低于标准
::32 Normal 优先级–标准
::32768 Above Normal 优先级–高于标准
::128 High Priority 优先级–高
::256 Real Time 优先级–实时
复制代码

avi33

谢谢，请问指定CPU0或CPU1运行，这个可以实现吗？

avi33

如果批处理不能实现，其他的能实现吗？非常感谢

pcl_test

回复 4# avi33

参看下http://www.bathome.net/thread-13677-1-1.html

avi33

谢谢！:)

pcl_test

@echo off 2>nul 3>nul
::需要安装.Net Framework 2.0及以上
set "netpath=%systemroot%\Microsoft.NET\Framework"
for /f "delims=" %%a in ('dir /ad /b "%netpath%\v?.*"') do (
    if exist "%netpath%\%%a\csc.exe" (
        set "cscpath=%netpath%\%%a\csc.exe"
        goto :0
    )
)
:0
>"%tmp%\$" more +15 "%~f0"
"%cscpath%" /out:"%tmp%\$SetAffinity.exe" "%tmp%\$"
"%tmp%\$SetAffinity.exe"
pause&exit
::C# codes 参考http://caoshugui.blog.163.com/blog/static/25375653200910115329888/
using System;
using System.Diagnostics;
namespace SetAffinity{
    class Myclass{ 
        static void Main(string[] args){
            //设置需修改CPU相关性的进程名
            String[] proname = new String[]{"game","ra2"};
            for (int i=0; i<proname.Length; i++){
                Process pro = Process.GetProcessesByName(proname[i])[0];
                //设置CPU相关性为cpu0
                pro.ProcessorAffinity = (System.IntPtr)1;
            }
        }
    }
}
复制代码