【出题】批处理输出n阶幻方

lhjoanna

所谓n阶幻方：1-n^2个数排为n行n列，横、竖、对角线相加和相同。
  输入：幻方阶数n (暂限制为奇数阶)
  输出：n行n列的方阵，横、竖、对角线相加和相同。
  举例：5阶幻方，横、竖、对角线相加和为65

17 24  1  8 15
23  5  7 14 16
4  6 13 20 22
10 12 19 21  3
11 18 25  2  9

pusofalse

这个题目相当难啊~ 以前做过类似的，没做出来~ - -|||

batman

解此题最重要的不是代码，而是思路。。。

lhjoanna

恩，幻方生成规则知道了，代码也就不难了。^_^

lhjoanna

是不是太难了，怎么没人贴代码来？可以先到网上搜索一下奇次幻方的构造规律，然后再转化为代码就相对容易些了！

Lumiere

是想自己摸索出来那个规则吧？

slore

cn-dos不是有么

lhjoanna

哦？我刚搜了下没搜到啊。slore兄不妨把那帖子链接贴来，看能不能激发些灵感想出些不同的方法。

Batcher

不知道slore兄是不是说的这个：
http://www.cn-dos.net/forum/viewthread.php?tid=26647

CN-DOS这次出问题看来丢了十来天的数据，哎~

lhjoanna

呵，我发现什么帖子都逃不过batcher的眼睛啊~此链接中楼主所说的九宫格就是三阶幻方，又看到了namejm的精彩代码~~不过此题要求是n阶幻方(暂定为奇数阶)，下面11楼 pengfei所上传的附件sigil.exe符合此题题意。虽然没提供代码，但是提供了算法。大家尝试着看谁能写出代码？

more

试试:

@echo off
:bgn
set input=&set /p input=请输入3以上的单数(回车退出):
if not defined input goto :eof
cls
if %input% lss 3 (echo.你输入的也太小了吧...&goto :bgn)
echo.%input:~-1%|findstr "[^13579]" >nul&&(echo.请输入单数...&goto :bgn)
set /a num1=(%input%*%input%+1)*%input%/2,num2=%input%*%input%
echo.%input%阶幻方各行,列以及对角线相加的和为:%num1%
set /a lie=%input%/2+1,hang=1,all=1
set h1l%lie%=1
:agn
set /a hang-=1,lie+=1,all+=1
if %hang% lss 1 set hang=%input%
if %lie% gtr %input% set lie=1
if defined h%hang%l%lie% (set /a hang+=2,lie-=1)
set h%hang%l%lie%=%all%
if "%hang%"=="1" (
  if "%lie%"=="%input%" (
    set /a hang+=1,all+=1
    call set h%%hang%%l%lie%=%%all%%
  )
)
if %all% equ %num2% goto :show
goto :agn
:show
for /l %%a in (1 1 %input%) do (
  for /l %%b in (1 1 %input%) do (
    call set/p=%%h%%al%%b%%  <nul
    set "h%%al%%b="
  )
  echo.
)
goto :bgn
复制代码

tyc

 
program aa;
var
i,j,m,n:integer;
a:array [1..100,1..100] of integer;
begin
repeat
readln(n);
m:=n mod 2;
until m<>0;
for i:=1 to n do
  for j:=1 to n do a[i][j]:=0;
i:=2;j:=n div 2;
for m:=1 to n*n do
begin
  i:=i-1;j:=j+1;
  if (i=0) and (j<>n+1) then  i:=n;
  if (j=n+1) and (i<>0) then j:=1;
  if (a[i][j]<>0) or (i=0) and (j=n+1) then
  begin
    i:=i+2;
    j:=j-1;
  end;
  a[i][j]:=m;
end;
for i:=1 to n do
  begin
  for j:=1 to n do
   write(a[i][j]:5);
  writeln;
  end;
end.
复制代码

[ 本帖最后由 tyc 于 2009-4-2 16:20 编辑 ]

lhjoanna

Re:more
      结果符合幻方的要求，代码也不错，在此基础上提些小建议(供参考)：
   1、对于大于3的要求我觉得不必，因为1阶幻方也是幻方，只不过所含的元素只有一个而已，可以统一起来考虑；
   2、对于输入的限制，兄所用的方法是判断最后一位是否奇数，对于要求不高的情况可以满足，但如果要求苛刻些，比如输入a3、12a5等情况，可能会出错。最好还是用完全匹配来限制输入；
   3、对于算法的实现，我没有仔细的验证，应该没问题，毕竟结果正确，并且也符合了行++，列- -，到边的话首尾相接，元素已存在的话放到正下方 等规则；
   4、输出结果正确，再加上对齐就完美了。^_^

Re：tyc
      不知兄用的什么语言，我还真没用过，不过我基本看懂了，一些语法的问题我就无从知晓了，不过算法是正确的。其实对于输出幻方来说，实现起来这样的高级语言比批处理容易些，因为数组类型是内置的，而批处理则需要自己构建一个类似的二维数组来方便操作；此题要求是用批处理来实现，所以希望兄闲暇时也考虑下用批处理来实现~不管怎么说，毕竟动了一番脑子，加分鼓励^_^

more

应版主的要求,再做一些修改吧:

@echo off
:bgn
set input=&set /p input=请输入一个单数(回车退出):&cls
if not defined input goto :eof
echo.%input%|findstr /v "^[0-9]*$" >nul&&(echo.请输入纯数字!!!&goto :bgn)
echo.%input:~-1%|findstr "[^13579]" >nul&&(echo.请输入单数!!!&goto :bgn)
set /a num1=(%input%*%input%+1)*%input%/2,num2=%input%*%input%
echo.%input%阶幻方各行,列以及对角线相加的和为:%num1%&echo.
set /a lie=%input%/2+1,hang=1,all=1
if %num2% gtr 99 (set h1l%lie%=  1) else (set h%hang%l%lie%= 1)
:agn
set /a hang-=1,lie+=1,all+=1
if %hang% lss 1 set hang=%input%
if %lie% gtr %input% set lie=1
if defined h%hang%l%lie% (set /a hang+=2,lie-=1)
call :duiqi
if "%hang%"=="1" (
  if "%lie%"=="%input%" (
    set /a hang+=1,all+=1
    call :duiqi
  )
)
if %all% geq %num2% goto :show
goto :agn
:show
for /l %%a in (1 1 %input%) do (
  for /l %%b in (1 1 %input%) do (
    call set/p=%%h%%al%%b%%  <nul
    set "h%%al%%b="
  )
  echo.&echo.
)
goto :bgn
:duiqi
if %num2% gtr 99 (
  if %all% lss 10 (
    set h%hang%l%lie%=  %all%
  ) else (
    if %all% lss 100 (
      set h%hang%l%lie%= %all%
    ) else (
      set h%hang%l%lie%=%all%
    )
  )
) else (
  if %num2% gtr 9 (
    if %all% lss 10 (
      set h%hang%l%lie%= %all%
    ) else (
      set h%hang%l%lie%=%all%
    )
  ) else (set h%hang%l%lie%= %all%)
)
复制代码

tyc

我用pascal，批处理写不出来，一急就用其它高级语言了，不过这一题是初中生的竞赛题。

[ 本帖最后由 tyc 于 2009-4-3 07:34 编辑 ]