【练习-042】批处理将文本数值按尾数分类

batman

＆＆有一文本文件a.txt，内容如下：

530 862 477 448
407 68 191 157 929
76 866 730 445 665
591 99 285 868
352 64 196 755 220
922 245 966 294 118
839 757 564 701 391
629 794
110 349 604 962 868
846 20 637 11 782
复制代码

　　要求用批处理将这些数值按尾数分类排出如下：

0  530 730 220 110 20
1  191 591 701 391 11
2  862 352 922 962 782
4  64 294 564 794 604
5  445 665 285 755 245
6  76 866 196 966 846
7  477 407 157 757 637
8  448 68 868 118 868
9  929 99 839 629 349
复制代码

　　本题满分10分，视情况加分（以思路为重）。
　　如成功解答后请加大难度，加入数值排序，输出如下：

0 20 110 220 530 730
1 11 191 391 591 701
2 352 782 862 922 962
4 64 294 564 604 794
5 245 285 445 665 755
6 76 196 846 866 966
7 157 407 477 637 757
8 68 118 448 868 868
9 99 349 629 839 929
复制代码

　　如成功完成，本人将给予额外的加分，分值视情况而定。
　　注：所有数值都在3位数内，排序时请考虑数值会出现相等的情况

[ 本帖最后由 batman 于 2009-4-13 17:39 编辑 ]

Batcher

如果a.txt里面没有以5结尾的数字，结果应该如何显示？

batman

TO二楼，文本中本就没有以3结尾的数字。。。

terse

先抛砖 感觉可以少个FOR

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (
   for %%j in (%%i) do (
       set str=%%j
       for /l %%a in (0,1,9) do (
       if "!str:~-1!"=="%%a" set _%%a=!_%%a! %%j
)))
for /l %%a in (0,1,9) do if not "!_%%a!"=="" echo;%%a !_%%a!
pause
复制代码

[ 本帖最后由 terse 于 2009-4-13 17:12 编辑 ]

stuqx

这个不是应该放到新手练习区么

batman

TO　楼上，这题对新手有点难，不适宜放在新手练习区的。

pusofalse

如果用设置变量的方法，恐怕站长前辈又会说好的程序员应注意内存的占用问题。
在想有无别的方法？~ 肯定会有的。。

batman

我一直就喜欢用变量赋值法（原因已多次说明过），但以往总是没有处理数值相同的情
况，现在已经想到解决办法了。

[ 本帖最后由 batman 于 2009-4-13 17:42 编辑 ]

stuqx

@echo off
set "n0=0 "
set "n1=1 "
set "n2=2 "
set "n3=3 "
set "n4=4 "
set "n5=5 "
set "n6=6 "
set "n7=7 "
set "n8=8 "
set "n9=9 "
for /f "delims=" %%a in (1.txt) do (
	for %%b in (%%a) do (
		setlocal ENABLEDELAYEDEXPANSION
		set num=%%b
		set re=n!num:~-1!
		call set "!re!=!!re!! %%b"
		ENDLOCAL
		)
	)
echo %n0%
echo %n1%
echo %n2%
echo %n3%
echo !n4!
echo !n5!
echo !n6!
echo !n7!
echo !n8!
echo !n9!
复制代码

问下这个为什么不行  变量嵌套的还是用不好

Batcher

楼主出这个题目，意图应该不仅仅是考察截取最后一位字符的方法，你可以先尝试一下其它思路，比如：取余。

tireless

@echo off&setlocal enabledelayedexpansion
(for /f "tokens=*" %%a in (a.txt) do (
  for %%i in (%%a) do set "var=00%%i" & echo !var:~-3!
))>a_tmp.txt

for /f "tokens=* delims=0" %%a in ('sort a_tmp.txt') do (
  set var=%%a
  for %%i in (#!var:~-1!) do set %%i=!%%i! %%a
)

for /l %%a in (0 1 9) do if defined #%%a echo %%a!#%%a!
del a_tmp.txt & pause
复制代码

[ 本帖最后由 tireless 于 2009-4-14 11:50 编辑 ]

gohai

下面是我做的， 分类 + 排序，

@echo off
setlocal EnableDelayedExpansion

del b.txt&del 1.txt&del 2.txt
for /f "usebackq delims=" %%i in (`more a.txt`) do (
  for %%j in (%%i)do (
    set "number=   %%j"
    echo !number:~-4!>>1.txt
  )
)
for /f "usebackq" %%i in (`sort 1.txt`) do (
  echo %%i>>2.txt
)
del 1.txt
for /l %%i in (0,1,9) do (
	set /a input=0
	for /f "delims=" %%j in (2.txt) do (		
		set /a num=%%j
		set /a flag=!num:~-1,1!
		if !flag! equ %%i (
			if !input! equ 0 (
				set /p=!flag! <nul>>b.txt	
			)
			set /a input=1
			set /p=!num! <nul >>b.txt
		)
	)
	if !input! equ 1 (
		echo. >>b.txt	
	)
)
start b.txt
del 1.txt&del 2.txt
exit
复制代码

rat

@echo off & setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
  for %%b in (%%a) do (
    call :p %%b
  )
)
for /l %%i in (0,1,9) do (
  if defined f%%i (
    call :sortstr str%%i newstr
    echo !newstr!
  )
)
pause
goto :eof



:p
set s=%1
for /l %%i in (0,1,9) do (
  if "!s:~-1!"=="%%i" (
    if not defined f%%i2 set f%%i2=1&set str%%i=%%i
    set str%%i=!str%%i! %%b
    if not defined f%%i set f%%i=1
    goto :eof
  )
)
goto :eof

:sortstr
setlocal
for %%a in (!%1!) do (
	set/ajj+=1
	set s!jj!=%%a
)
call :sort s %jj%
for /l %%a in (1,1,%jj%) do (
	set ss=!ss! !s%%a!
)
endlocal&set %2=%ss%&goto :eof

:sort arrname %ubound%
set a=%1&set u=%2&set i=2
:sort_1
if %i% gtr %u% goto :eof
set /a %a%0=%a%%i%,j=i-1
:sort_2
if !%a%0! lss !%a%%j%! (
	set /a k=j+1
	set /a %a%!k!=%a%%j%,j-=1
	goto sort_2
)
set /a k=j+1
set /a %a%%k%=%a%0,i+=1
goto sort_1
复制代码

rat

js有个sort方法

随风

这个题目已经不是新手题了啊。
各位版主也出出手吧，是否应该考虑把terse兄的帖子也打开呢
batman 版主也把自己的代码晒晒吧。
11 楼 tireless 的代码产生了临时文件、效率还行、但不能处理重复数字。
12 楼 gohai 的代码同上。
rat 版主的代码是否能提高下效率。

[ 本帖最后由 随风 于 2009-4-14 04:24 编辑 ]