[文本处理] [已解决]文本文件中含有!和%特殊字符，如何正确读出并赋值给变量

shootman2

我的配置文件conf.txt中的内容为

#服务器信息
sftp.host=192.168.101.100
sftp.port=22
sftp.user=sjjh_qyw
sftp.passwd=gsxt!2017
ssh.host=192.168.101.101
ssh.port=22
ssh.user=gbase
ssh.passwd=gbase%122

读取配置文件的bat脚本为

echo 正在获取服务器信息...
for /f "usebackq eol=# delims=" %%x in ("conf.txt") do set %%x
echo 获取完毕

读取完毕后，打印sftp.passwd变量时，显示结果为gsxt2017，中间的!丢失了，
如果要正确赋值，该如何处理？求助大神出手相助！

lifei259

开了延时变量，原来如此。

0000

如果一定要有setlocal enabledelayedexpansion的话

@echo off
setlocal enabledelayedexpansion

::find /v /c "" <conf.txt >_&set /p n=<_&del _ 2>nul
set n=10
(
 for /l %%n in (1,1,!n!) do (
  set line=
  set /p line=
  if defined line if not "!line:~,1!"=="#" set !line!
)) <"conf.txt"

echo 获取完毕
复制代码

yhcfsr

用你的代码，WIN10 测试

@echo off
echo 正在获取服务器信息...
for /f "usebackq eol=# delims=" %%x in ("conf.txt") do echo %%x
echo 获取完毕
pause
复制代码

测试结果

shootman2

用你的代码，WIN10 测试测试结果
yhcfsr 发表于 2017-12-2 23:29

    忘了说了，程序中是开启了变量延迟了。。。

shootman2

回复 2# lifei259


    打开了变量延迟了，我测试了还是不行！

yhcfsr

回复 5# shootman2

@echo off&setlocal enabledelayedexpansion
echo 正在获取服务器信息...
for /f "usebackq eol=# delims=" %%x in ("conf.txt") do (
endlocal
set "pr=%%x"
setlocal enabledelayedexpansion
echo !pr!
)
echo 获取完毕
pause
复制代码

测试有效

shootman2

回复 7# yhcfsr


    感谢大神，成功解决！！！