[已解决]20元求助批处理移动文本文件

lxh623

文本文件名称：
T01n0054--佛说释摩男本四子经(1卷)--〖吴 支谦译〗
T01n0059--佛说诸法本经(1卷)--〖吴 支谦译〗

第一、最好把含有“〖吴”的子文件夹文件都移动到三国文件夹（可以自己设定路径）。
第二、也可以有文本a，比如：
T01n0054
T01n0059
然后，所有子文件夹的文件搜索移动到指定文件夹。

谢谢！

zaqmlp

@echo off
cd /d "%~dp0"
set "newfolder=D:\xxx\三国"
if not exist "%newfolder%\" md "%newfolder%\"
for /f "delims=" %%a in ('dir /a-d/b/s "*〖吴*.txt" 2^>nul') do move "%%a" "%newfolder%\"
 
set "txtfile=.\a.txt"
set "newfolder=D:\yyy\指定文件夹"
if not exist "%newfolder%\" md "%newfolder%\"
for /f "delims=" %%a in ('type "%txtfile%"') do (
    for /f "delims=" %%b in ('dir /a-d/b/s "*%%a*.txt" 2^>nul') do move "%%b" "%newfolder%\"
)
pause
exitCOPY

flashercs

@echo off
cd /d "%~dp0"
set "dstfolder=e:\三国"
if not exist "%dstfolder%\" md "%dstfolder%\"
for /r . %%A in ("*〖吴*.txt") do move "%%A" "%dstfolder%\"
 
set "filea=a.txt"
set "dstfolder=e:\目标目录"
if not exist "%dstfolder%\" md "%dstfolder%\"
for /f "usebackq delims=" %%A in ("%filea%") do (
  for /r . %%B in ("*%%A*.txt") do (
    move "%%B" "%dstfolder%\"
  )
)
pause
exit /bCOPY

WHY

先测试，显示结果正确的话删除 -WhatIf，再次执行即可。

@echo off
md "三国" 2>nul
PowerShell "dir -Path . -Include '*〖吴*.txt' -File -Recurse | move -Dest '三国\' -Force -WhatIf"
pauseCOPY

@echo off
md "三国" 2>nul
PowerShell "dir -Path . -Include ((type a.txt) -replace '$', '*.txt') -File -Recurse | move -Dest '三国\' -Force -WhatIf"
pauseCOPY

lxh623

回复 4# WHY
请查收。
谢谢诸位！

fafa258

回复 1# lxh623


    我也正在整理大藏经，是按照每部经的每经品来分类，例如长阿含经分为了41品。