[文本处理] [已解决]批处理怎样用身份列表在名录库里导出他们的全信息？

gcbgczhang

各位老师
a.txt内容
211281201105302014
21120319581019201X
211203195608142027
………………
b.txt
211203196812032030    张三      34632
211281201105302014    李四      7768
21120319581019201X    麻子      gsdfhs
211203195608142027    呆瓜      gfjhgbv
211203198810092039    弟弟      54654
211281201906102012    表哥      dh879
要求，a.txt中的每一行如果在b.txt找到，则输出b.txt中的这一行累加到c.txt中
我现在用的

@echo off
setlocal enabledelayedexpansion
(for /f %%a in (a.txt) do (
    findstr /c:"%%a" b.csv
))>c.txt
复制代码

这两文件分别有20万行，搞起来非常慢。有好的方法吗。这样执行是不是两个20万就是400亿，能不能两个文件直接比较的方法？每行部分匹配可以直接比较吗
在线等

yakeyun

回复 1# gcbgczhang

试下看看速度怎么样：
@echo off
(for /f %%a in (a.txt) do for /f "delims=^  tokens=1,*" %%b in ('type "b.txt"^|find "%%a"') do echo,%%b %%c) >.\c.txt
exit

idwma

@qixiaobin0715
现抄现学现用

@echo off
setlocal enabledelayedexpansion
for /f  %%a in (a.txt) do set #%%a=true
(for /f "tokens=1*" %%b in (b.txt) do if defined #%%b echo;%%b   %%c)>c.txt
pause
复制代码

gcbgczhang

回复 3# idwma


    不是只有3列

idwma

回复 4# gcbgczhang


    100列也显示的

Batcher

回复 1# gcbgczhang


试试这样能否成功：

findstr /l /g:a.txt b.txt > c.txt
复制代码

idwma

回复 6# Batcher


    学到了,又去看了下帮助,这个还可以用管道
type a.txt |findstr /g:/ b.txt >c.txt

gcbgczhang

回复  gcbgczhang


试试这样能否成功：
Batcher 发表于 2021-7-31 18:40

    管理员牛！！！！！！
这段代码用时3秒，和我花了1小时弄出来的一个字符了不差。……………。

gcbgczhang

回复 6# Batcher


    成功！！！！！！！！！用时3秒，索引文件13万行，全信息库文件22万行
我用的for加finstr,用了1个多小时。其它方案和我这进度差不多。