[文件操作] [分享]批处理重命名文件添加父父文件夹名称作为前缀

Batcher

【问题描述】

@echo off & title 
cd /d "%~dp0"
 
for /r /d %%a in (*) do (
    pushd "%%~a"
        set "DEST="
        for /d %%b in (*) do set DEST=OK
        if not defined DEST (
            for /f "delims=" %%c in ("%%~nxa") do (
                for /f "delims=" %%i in ('dir /a-d/b *.jpg *.png *.tif') do (
                    ren "%%~i" "%%~c-%%~i" >nul && (
                        echo "%%~i" --^>^> "%%~c-%%~i"
                    )
                )
            )
        )
     popd
)
pause
复制代码

想在这个基础上 再加一层文件夹名称？应该怎么改？  
比如现在的效果是重命名文件名为： 父文件夹+文件     需要的效果：父父文件夹名称+父文件夹名称+文件名

Batcher

【解决方案】

@echo off
cd /d "%~dp0"
for /r /d %%a in (*) do (
    pushd "%%a"
    set "DEST="
    for /d %%b in (*) do set DEST=OK
    if not defined DEST (
        for /f "delims=" %%c in ("%%a\..") do (
            for /f "delims=" %%i in ('dir /a-d /b *.jpg *.png *.tif 2^>nul') do (
                echo "%%~i" --^>^> "%%~nxc-%%~nxa-%%~i"
                ren "%%~i" "%%~nxc-%%~nxa-%%~i"
            )
        )
    )
    popd
)
pause
复制代码

a6236130

我的是这样的，从上往下.....

@echo off
cd /d %~dp0 
for /d %%a in (*) do (
    pushd "%%~a"
        for /d %%b in (*) do (
            pushd "%%~b"
                        for /f "delims=" %%c in ('dir /a-d/b *.*') do (
                           call ren "%%~c" "%%~a-%%~b-%%~c" >nul && (
                               echo "%%~c" --^>^> "%%~a-%%~b-%%~c"
                             )
                        )
                    popd
                 )
             popd
         )
pause
复制代码