[文本处理] 批处理怎样批量统计文件夹下文件个数和文件大小？求大神

asy666

一个总文件夹（A） 总文件夹下有多个子文件(B) 子文件夹里有音频 每个文件夹音频个数不一样

想实现，把总文件夹下面的子文件夹里所有资源统计出来。并且在每个子文件夹里生成一个TXT文件

TXT里显示 子文件的名称和多少个文件 还有总大小

显示格式w


周杰伦传记
一共20集
大小600MB



不知道可不可以实现，我是小白，啥也不懂，有大佬能帮我搞一下吗，谢谢了

flashercs

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"

for /d %%A in (*) do (
  set a=
  set b=
  for /f "delims=" %%B in ('dir /a-d /-c "%%A\*.mp4"') do (
    set a=!b!
    set b=%%B
  )
  (
    for /f "tokens=1-3" %%C in ("!a!") do (
      echo %%~nxA
      echo 一共%%C集
      for /f "delims=" %%F in ('powershell -c "function Format-FileSize {param ([long]$FileSize ) switch ($FileSize) { { $_ -lt 1KB } { return '{0}Bytes' -f $_ } { $_ -lt 1MB } { return '{0:F2}KB' -f ($_ / 1KB) }{ $_ -lt 1GB } { return '{0:F2}MB' -f ($_ / 1MB) }{ $_ -lt 1TB } { return '{0:F2}GB' -f ($_ / 1GB) }{ $_ -lt 1PB } { return '{0:F2}TB' -f ($_ / 1TB) }Default { return '{0:F2}PB' -f ($_ / 1PB) }}}Format-FileSize %%E"') do (
        echo 大小%%F
      )
    )
  )>"%%A\info.txt"
)

endlocal
pause
复制代码

批处理放到A文件夹下面; 保存为ANSI编码.

CrLf

http://www.bathome.net/viewthread.php?tid=25682

人懒，代码不写了

asy666

回复 2# flashercs


    感谢大佬 这个是可以的，

现在输出的是

31《盗墓笔记》（共6集）
一共6集
大小210,330,331 字节


可以把这个 大小210,330,331 字节 改成大小多少MB 或者GB 吗

aloha20200628

给一个用过的简版...代码磁盘在音频文件总目录A下（子目录音频文件总计不超过2G均可）
@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%d in ('dir/s/b/ad') do (
   cd/d "%%~d"
   for /f "tokens=1-3" %%1 in (' dir/a-d/-c *.mp3 *.flac 2^>nul^|findstr /r /c:" 个文件[ 0-9]*" ') do (
      set/a "sizeF=%%3/1048576"
      (echo,文件个数=%%1 总计大小=!sizeF!MB)>"【简报】.txt"
        )
)
endlocal&exit/b

asy666

回复 2# flashercs


    在感谢了。完美了