[系统相关] 批处理清理使用痕迹

随风

代码征集
  批处理清理使用痕迹
功能：
    1、清理ie地址栏的使用痕迹
    2、清理开始运行里的使用痕迹
    3、清理表单内容
    4、清理密码
    5、清空cookies
要求：
  可以是原创，也可以是转载（转载需注明出处及原创作者信息）
  不一定要5项全有，知道一个发一个也行。
  凡是与 清理使用痕迹 有关的都可以，并不局限与上面的5项

fastslz

@echo off
echo 清空cookies
del /s/q/f "%USERPROFILE%\cookies\*.*" >nul  2>nul
echo 清理最近打开的文档纪录
del /s/q/a-s "%USERPROFILE%\Recent\*.*" >nul  2>nul
echo 清理历史纪录
del /s/q/f "%USERPROFILE%\Local Settings\History\*.*" >nul  2>nul
echo 清理 Google 历史纪录
del /s/q/f "%USERPROFILE%\Application Data\Google\Local Search History\*.*"
echo 清理 IE 临时文件
set regkey=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders
for /f "skip=4 tokens=2,*" %%i in ('reg query "%regkey%" /v "Cache"') do del /f/s/q "%%j\*.*" >nul 2>nul
echo 清理 IE 地址栏的使用痕迹
reg delete "HKCU\Software\Microsoft\Internet Explorer\TypedURLs" /f >nul 2>nul
echo 清理搜索纪录
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\RecentDocs" /f >nul 2>nul
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\DocFindSpecMRU" /f >nul 2>nul
echo 清理开始运行里的使用痕迹
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\RunMRU" /f >nul 2>nul
echo 清理 Windows Media Player 最近打开纪录
reg delete "HKCU\Software\Microsoft\MediaPlayer\Player\RecentFileList" /f >nul 2>nul
echo 清理 RealPlayer 最近打开纪录
for /l %%i in (1,1,10) do reg delete "HKCU\Software\RealNetworks\RealPlayer\6.0\Preferences\MostRecentClips%%i" /f >nul 2>nul
pause
复制代码