WHY

我贴一个VBS

On Error ReSume Next
Dim fso, myDir, dstFolder
Set fso = CreateObject("Scripting.FileSystemObject")
myDir = fso.GetFile(WSH.ScriptFullName).ParentFolder.Path           '脚本自身目录
dstFolder = myDir & "\Result"                                       '目标目录
If Not fso.FolderExists(dstFolder) Then fso.CreateFolder(dstFolder) '创建目标目录

Dim objFile
For Each objFile In fso.GetFolder(myDir).Files
    If LCase(Right(objFile.Name, 4)) = ".txt" Then
        If objFile.Size > 0 Then
            CheckEncoding objFile.Path, dstFolder & "\" & objFile.Name
        End If
    End If
Next

Function DeleteStr(ByRef str)
    Dim reg, arrIn, n, i, arrOut()
    Set reg = New RegExp
    reg.IgnoreCase = True
    reg.Pattern = "PS[0-9]*："      '删除包含 "PS" + 数字 + "："的行 
    str = Replace(str, vbCrLf, vbLf)
    arrIn = Split(str, vbLf)
    n = 0
    For i = 0 To UBound(arrIn)
        If Not reg.Test(arrIn(i)) Then
            ReDim PreServe arrOut(n)
            arrOut(n) = arrIn(i)
            n = n + 1
        End If
    Next
    DeleteStr = Join(arrOut, vbCrLf)
End Function

Function ConvertUtf32ToUtf16(srcFile, dstFile, encName)
    Dim xmlDoc, node
    Set xmlDoc = CreateObject("MSXML2.DOMDocument")
    Set node = xmlDoc.CreateElement("binary")
    node.DataType = "bin.hex"
    Dim ado, sz, i, j, arr()
    Set ado = CreateObject("ADODB.Stream")
    ado.Type = 1
    ado.Open
    ado.LoadFromFile srcFile
    sz = ado.Size
    ReDim arr(sz\4)
    Dim h(3)
    For i = 1 To sz Step 4
        For j = 0 To 3
            h(j) = Right("00" & Hex(AscB(ado.Read(1))), 2)
        Next
        If encName = "UTF32LE" Then
            arr(i\4) = h(0) & h(1)
        ElseIf encName = "UTF32BE" Then
            arr(i\4) = h(2) & h(3)
        End If
    Next
    node.Text = Join(arr, "")
    ado.Position = 0
    ado.Write node.NodeTypedValue
    ado.SetEOS()
    ado.SaveToFile dstFile, 2
    ado.Close()
    SaveFileUtf16ToAnsi dstFile, dstFile
End Function

Function SaveFileUtf16ToAnsi(srcFile, dstFile)
    Dim f, str
    Set f = fso.OpenTextFile(srcFile, 1, True, -1)
    str = DeleteStr(f.ReadAll)
    f.Close
    fso.OpenTextFile(dstFile, 2, True).Write(str)
End Function

Function SaveFileUtf8ToAnsi(srcFile, dstFile, charset)
    Dim ado, str
    Set ado = CreateObject("ADODB.Stream")
    ado.Type = 2
    ado.CharSet = charset
    ado.Open
    ado.LoadFromFile srcFile
    str = ado.ReadText(-1)
    ado.Position = 0
    ado.CharSet = "GB2312"
    ado.WriteText DeleteStr(str)
    ado.SetEOS
    ado.SaveToFile dstFile, 2
    ado.Close
End Function

Function SaveFileAnsiToAnsi(srcFile, dstFile)
    Dim f, str
    Set f = fso.OpenTextFile(srcFile, 1, True)
    str = DeleteStr(f.ReadAll)
    f.Close
    fso.OpenTextFile(dstFile, 2, True).Write(str)
End Function

Function CheckEncoding(srcFile, dstFile)
    Dim ado, i, BOM
    Set ado = CreateObject("ADODB.Stream")
    ado.Type = 1
    ado.Open
    ado.LoadFromFile srcFile
    For i = 0 To 3
        BOM = BOM & Right("00" & Hex(AscB(ado.Read(1))), 2)
    Next
    If BOM = "FFFE0000" Then
        ado.Close
        ConvertUtf32ToUtf16 srcFile, dstFile, "UTF32LE"
    ElseIf BOM = "0000FEFF" Then
        ado.Close
        ConvertUtf32ToUtf16 srcFile, dstFile, "UTF32BE"
    ElseIf Left(BOM, 4) = "FFFE" or Left(BOM, 4) = "FEFF" Then
        ado.Close
        SaveFileUtf16ToAnsi srcFile, dstFile   'UNICODE
    ElseIf Left(BOM, 6) = "EFBBBF" Then
        ado.Close
        SaveFileUtf8ToAnsi srcFile, dstFile, "UTF-8"
    ElseIf Left(BOM, 6) = "2B2F76" Then
        ado.Close
        SaveFileUtf8ToAnsi srcFile, dstFile, "UTF-7"
    Else
        Dim sz, arr()
        ado.Position = 0
        sz = ado.Size
        ReDim arr(sz-1)
        For i = 1 To sz
            arr(i-1) = ChrW(AscB(ado.Read(1)))
        Next
        If isUTF8(arr) Then
            ado.Close
            SaveFileUtf8ToAnsi srcFile, dstFile, "UTF-8"
        Else
            ado.Close
            SaveFileAnsiToAnsi srcFile, dstFile  'ANSI
        End If
    End If
End Function

Function isUTF8(ByRef arr)
    Dim s, reg
    s = "[\xC0-\xDF](?:[^\x80-\xBF]|$)"
    s = s & "|[\xE0-\xEF].{0,1}(?:[^\x80-\xBF]|$)"
    s = s & "|[\xF0-\xF7].{0,2}(?:[^\x80-\xBF]|$)"
    s = s & "|[\xF8-\xFB].{0,3}(?:[^\x80-\xBF]|$)"
    s = s & "|[\xFC-\xFD].{0,4}(?:[^\x80-\xBF]|$)"
    s = s & "|[\xFE-\xFE].{0,5}(?:[^\x80-\xBF]|$)"
    s = s & "|[\x00-\x7F][\x80-\xBF]"
    s = s & "|[\xC0-\xDF].[\x80-\xBF]"
    s = s & "|[\xE0-\xEF]..[\x80-\xBF]"
    s = s & "|[\xF0-\xF7]...[\x80-\xBF]"
    s = s & "|[\xF8-\xFB]....[\x80-\xBF]"
    s = s & "|[\xFC-\xFD].....[\x80-\xBF]"
    s = s & "|[\xFE-\xFE]......[\x80-\xBF]"
    s = s & "|^[\x80-\xBF]"
    Set reg = New RegExp
    reg.Pattern = s
    isUTF8 = Not reg.Test(Join(arr, ""))
End Function

MsgBox "Done"
复制代码

czjt1234

回复 16# WHY


   所以说很烦

保存备用

terse

发一个js的  先粗暴处理32编码文件

1>1/* :
@echo off
set "ph=%cd%\Result\"
set "enc=gb2312"
md "%ph%" 2>nul
dir /b /a-d *.txt *.jpg| cscript -nologo -e:jscript %0 "%ph%" "%enc%"
pause & exit
*/
var cp1252 = "\u20AC\u0081\u201A\u0192\u201E\u2026\u2020\u2021\u02C6\u2030\u0160\u2039\u0152\u008D\u017D\u008F\u0090\u2018\u2019\u201C\u201D\u2022\u2013\u2014\u02DC\u2122\u0161\u203A\u0153\u009D\u017E\u0178"; 
var reg = /^(fffe00|00feff|efbbbf|fffe|feff)/i, re = /(?:^|\n)(PS\d*：.*)/g,
charsets = { 'fffe00' : 'unicodefffe', '00feff' : 'unicodefeff', 'efbbbf' : "UTF-8",  'fffe' : 'unicodefffe', 'feff' : 'unicodefeff' };
function getText(file, enc) {
       var i = 0, stream, bin, count, content, hex='';
       stream = new ActiveXObject("ADODB.Stream");
       stream.type = 2;
       stream.charset = 'Latin1';
       stream.open();
       stream.loadFromFile(file);
       bin= stream.ReadText(-1);
       count = (bin.length > 4096) ? 4096 : bin.length;
       for (;i<4;) hex += bin.charCodeAt(i++).toString(16);
       var bom = reg.test(hex) ? hex.match(reg)[0] : '';
       stream.Position = 0;
       stream.Type = 2;
       stream.charset = bom ? charsets[bom] : getEncoding(bin, count) ? 'UTF-8' : 'gbk';
       content = stream.readText(-1);
       if (/00/.test(bom))
       {
            if (bom == '00feff') { content = content.slice(2) };
            content = content.replace(/\x00/g, '');
       }
       stream.Close
       return content
}

function getEncoding(b, len) {
       var n = 1;
       for ( var i = 0; i < len; i++)
       {
               var byt = (b.charCodeAt(i) <= 255) ? b.charCodeAt(i):
                     128+cp1252.indexOf(b.charAt(i));
               if (n == 1)
               {
                      if (byt >= 0x80)
                      {
                          while (((byt <<= 1) & 0x80) != 0) {n++}
                          if (n == 1 || n > 6) { return false }
                      }
               } else {
                   if ((byt & 0xC0) != 0x80) { return false}
                   n--;
               }
       }
       return true;
}
var enc = WScript.Arguments(1);
while (!WScript.StdIn.AtEndOfStream){
       var file = WScript.StdIn.ReadLine();
       var text = getText( file ).replace(re, '');
       var path = WScript.Arguments(0) + file;
       var stream = new ActiveXObject("ADODB.Stream");
       stream.type = 2;
       stream.charset = enc;
       stream.open();
       stream.writetext(text);
       stream.SaveToFile(path, 2);
       stream.Close
}
复制代码

xp3000

学习了，谢谢各位大神