[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖

[原创] 在 VBScript 中使用动态数组(ArrayList)

本帖最后由 老刘1号 于 2023-7-24 10:58 编辑

环境要求


  • Windows XP 及以上。
  • Windows 10Windows 11Windows 功能 中勾选 .NET Framework 3.5 (包括 .NET 2.0 和 3.0)

优点


  • 相比 VBScript 内置的数组,大小可自动变化。
  • 原生支持尾部添加、插入、删除、修改、切片、范围删除、翻转、查询、克隆等操作,免去了手动编写相关逻辑。
  • 可方便的转换为 VBScript 内置的数组。

使用

创建一个 ArrayList 对象:
  1. Set oArr = CreateObject("System.Collections.ArrayList")
复制代码
Add 方法:在动态数组末尾添加元素

均摊时间复杂度 O(1)
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. oArr.Add Empty
  3. oArr.Add Null
  4. oArr.Add "String"
  5. oArr.Add 0
  6. oArr.Add 3.14
  7. oArr.Add CreateObject("Scripting.FileSystemObject")
  8. oArr.Add New RegExp
复制代码
Count 属性:表示动态数组当前元素个数

时间复杂度 O(1)
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. WSH.Echo oArr.Count()
复制代码
  1. 0
复制代码
  1. oArr.Add 8
  2. WSH.Echo oArr.Count()
复制代码
  1. 1
复制代码
Item 属性:表示动态数组的各元素

接收一个整数作为索引,下标从 0 开始。

时间复杂度 O(1)
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. oArr.Add Empty
  3. oArr.Add Null
  4. oArr.Add "String"
  5. oArr.Add 0
  6. oArr.Add 3.14
  7. oArr.Add CreateObject("Scripting.FileSystemObject")
  8. WSH.Echo oArr.Item(4)
复制代码
  1. 3.14
复制代码
  1. oArr.Item(4) = 3.1415926
  2. WSH.Echo oArr.Item(4)
复制代码
  1. 3.1415926
复制代码
  1. Set oArr.Item(4) = CreateObject("Scripting.FileSystemObject")
  2. WSH.Echo TypeName(oArr.Item(4))
复制代码
  1. FileSystemObject
复制代码
Default 默认属性:表示动态数组的各元素

Item 属性。
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. oArr.Add Empty
  3. oArr.Add Null
  4. oArr.Add "String"
  5. oArr.Add 0
  6. oArr.Add 3.14
  7. oArr.Add CreateObject("Scripting.FileSystemObject")
  8. WSH.Echo oArr(4)
复制代码
  1. 3.14
复制代码
  1. oArr(4) = 3.1415926
  2. WSH.Echo oArr(4)
复制代码
  1. 3.1415926
复制代码
  1. Set oArr(4) = CreateObject("Scripting.FileSystemObject")
  2. WSH.Echo TypeName(oArr(4))
复制代码
  1. FileSystemObject
复制代码
Capacity 属性:表示动态数组目前的容量

若容量不足,会自动扩容并拷贝原来的元素。

扩容的时间复杂度是O(n)
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. WSH.Echo oArr.Count, oArr.Capacity
复制代码
  1. 0 0
复制代码
  1. For i = 1 To 100
  2.     oArr.Add i
  3. Next
  4. WSH.Echo oArr.Count, oArr.Capacity
复制代码
  1. 100 128
复制代码
  1. oArr.Capacity = oArr.Count
  2. WSH.Echo oArr.Count, oArr.Capacity
复制代码
  1. 100 100
复制代码
IsFixedSize 属性:数组是否为固定大小

会返回 False
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. WSH.Echo oArr.IsFixedSize()
复制代码
  1. 0
复制代码
IsReadOnly 属性:数组是否为只读

会返回 False
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. WSH.Echo oArr.IsReadOnly()
复制代码
  1. 0
复制代码
IsSynchronized 属性:表示是否同步对数组的访问

由于 VBScript 是单线程的,此属性无意义。

会返回 False
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. WSH.Echo oArr.IsSynchronized()
复制代码
  1. 0
复制代码
Clear 方法:清空动态数组
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. oArr.Add 6
  3. WSH.Echo oArr.Count()
复制代码
  1. 1
复制代码
  1. oArr.Clear
  2. WSH.Echo oArr.Count()
复制代码
  1. 0
复制代码
Clone 方法:返回该动态数组的拷贝

时间复杂度O(n)
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. oArr.Add 666
  3. Set oArr2 = oArr.Clone
  4. oArr2.Add 888
  5. WSH.Echo oArr Is oArr2, oArr.Count(), oArr2.Count()
复制代码
  1. 0 1 2
复制代码
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. oArr.Add 666
  3. Set oArr2 = oArr
  4. oArr2.Add 888
  5. WSH.Echo oArr Is oArr2, oArr.Count(), oArr2.Count()
复制代码
  1. -1 2 2
复制代码
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. oArr.Add New RegExp
  3. oArr.Add CreateObject("Scripting.FileSystemObject")
  4. Set oArr2 = oArr.Clone
  5. WSH.Echo oArr Is oArr2, oArr(0) Is oArr2(0), oArr(1) Is oArr2(1)
复制代码
  1. 0 -1 -1
复制代码
ToArray 方法:将动态数组转为普通 VBScript 数组

时间复杂度 O(n)
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. oArr.Add 1
  3. oArr.Add 3.1415926
  4. oArr.Add True
  5. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 1 3.1415926 True
复制代码
Contains 方法:检查动态数组内是否包含特定元素

时间复杂度O(n)
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. oArr.Add 2333
  3. oArr.Add Null
  4. oArr.Add oArr
  5. WSH.Echo oArr.Contains(2333), oArr.Contains(233), oArr.Contains(Null)
复制代码
  1. -1 0 -1
复制代码
  1. WSH.Echo oArr.Contains(oArr), oArr.Contains(CreateObject("System.Collections.ArrayList"))
复制代码
  1. -1 0
复制代码
GetRange 方法:返回数组的一个切片

参数:起始下标、切片长度。

时间复杂度 O(n)
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. For i = 0 To 9
  3.     oArr.Add i
  4. Next
  5. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 0 1 2 3 4 5 6 7 8 9
复制代码
  1. Set oArr2 = oArr.GetRange(2, 5)
  2. WSH.Echo Join(oArr2.ToArray(), " ")
复制代码
  1. 2 3 4 5 6
复制代码
Insert 方法:插入元素

时间复杂度O(n)

参数:下标、元素。
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. oArr.Add 0
  3. oArr.Add 5
  4. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 0 5
复制代码
  1. oArr.Insert 1, 4
  2. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 0 4 5
复制代码
  1. oArr.Insert 3, 6
  2. oArr.Insert 1, 2
  3. oArr.Insert 2, 3
  4. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 0 2 3 4 5 6
复制代码
Remove 方法:移除指定的元素

时间复杂度 O(n)

注意:


  • 只会移除从头至尾第一个遇到的和指定元素相等的元素。
  • 如果没有找到指定的元素,那么什么也不会发生。
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. For i = 1 To 5
  3.     oArr.Add i Mod 2
  4. Next
  5. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 1 0 1 0 1
复制代码
  1. oArr.Remove 1
  2. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 0 1 0 1
复制代码
  1. oArr.Remove 2
  2. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 0 1 0 1
复制代码
RemoveAt 方法:移除指定位置的元素

时间复杂度 O(n)
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. For i = 1 To 5
  3.     oArr.Add i Mod 2
  4. Next
  5. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 1 0 1 0 1
复制代码
  1. oArr.RemoveAt 0
  2. oArr.RemoveAt 1
  3. oArr.RemoveAt 2
  4. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 0 0
复制代码
RemoveRange 方法:移除指定区间的元素

参数:起始下标、长度。

时间复杂度 O(n)
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. For i = 0 To 5
  3.     oArr.Add i
  4. Next
  5. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 0 1 2 3 4 5
复制代码
  1. oArr.RemoveRange 3, 2
  2. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 0 1 2 5
复制代码
Reverse 方法:翻转数组

时间复杂度 O(n)
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. For i = 0 To 9
  3.     oArr.Add i
  4. Next
  5. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 0 1 2 3 4 5 6 7 8 9
复制代码
  1. oArr.Reverse
  2. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 9 8 7 6 5 4 3 2 1 0
复制代码
Sort 方法:将数组内元素排序

时间复杂度 O(n * log(n))
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. For i = 0 To 9
  3.     oArr.Add Fix(Rnd() * 100)
  4. Next
  5. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 70 53 57 28 30 77 1 76 81 70
复制代码
  1. oArr.Sort()
  2. WSH.Echo Join(oArr.ToArray(), " ")
复制代码
  1. 1 28 30 53 57 70 70 76 77 81
复制代码
TrimToSize 方法:使容量缩减为正好与当前元素个数相等
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. For i = 0 To 9
  3.     oArr.Add Fix(Rnd() * 100)
  4. Next
  5. WSH.Echo oArr.Capacity(), oArr.Count()
复制代码
  1. 16 10
复制代码
  1. oArr.TrimToSize
  2. WSH.Echo oArr.Capacity()
复制代码
  1. 10
复制代码
LastIndexOf 方法:返回数组中指定元素的索引

若有重复的元素,则返回最靠后的指定元素的索引。

若未找到元素,则返回 -1
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. oArr.Add 1
  3. WSH.Echo oArr.LastIndexOf(1)
复制代码
  1. 0
复制代码
  1. oArr.Add(1)
  2. WSH.Echo oArr.LastIndexOf(1), oArr.LastIndexOf(2)
复制代码
  1. 1 -1
复制代码
ToString 方法:返回类名
  1. Set oArr = CreateObject("System.Collections.ArrayList")
  2. WSH.Echo oArr.ToString(), TypeName(oArr)
复制代码
  1. System.Collections.ArrayList ArrayList
复制代码
参考

回复 1# 老刘1号


    但,用vbs写个动态数组类也不难啊?尤其是栈,反倒最简单,倒是队列最麻烦

TOP

回复 2# jyswjjgdwtdtj


    动态数组队列堆栈都不难,但是人家net是编译好的,vbs实现的临时解释运行速度上不去
哈希表有点复杂,但也不难
有序数组就很难自己实现了,不过我之前试过用vbs写avl树,github上有代码
net的有序数组应该是红黑树写的

TOP

回复 3# 老刘1号

谁用vbs处理大量数据啊🤔

TOP

测个效率(插入100000个数据
dictionary:
  1. a=timer
  2. set d=createobject("scripting.dictionary")
  3. for i=0 to 100000
  4. d.add i,0
  5. next
  6. b=d.keys()
  7. msgbox timer-a
复制代码
0.13
原生动态数组:
  1. a=timer
  2. dim d()
  3. redim d(-1)
  4. for i=0 to 100000
  5. redim preserve d(i)
  6. d(i)=0
  7. next
  8. b=ubound(d)
  9. msgbox timer-a
复制代码
0.13(和上面的几乎一致
原生普通数组:
  1. a=timer
  2. dim d(100000)
  3. for i=0 to 100000
  4. d(i)=0
  5. next
  6. msgbox timer-a
复制代码
0.007
js数组:
  1. c=timer
  2. set html=createobject("htmlfile")
  3. Set window = html.parentWindow
  4. window.execScript "var j=new Array()"
  5. set a=window.j
  6. for i=0 to 100000
  7. a.push 0
  8. next
  9. msgbox timer-c
复制代码
0.14(转换为vbs数组需要用到new vbarray 时间会再长一点
wia vector:
  1. c=timer
  2. set v=createobject("wia.vector")
  3. for i=0 to 100000
  4. v.add 0
  5. next
  6. msgbox timer-c
复制代码
0.51
.net arraylist:
  1. c=timer
  2. Set a = CreateObject("System.Collections.ArrayList")
  3. for i=0 to 100000
  4. a.add 0
  5. next
  6. msgbox timer-c
复制代码
0.4

当然 各有千秋 比如arraylist里的一大堆方法 原生的速度 vector的byte() js数组同时可以作为栈 队列等等

TOP

回复 5# jyswjjgdwtdtj


    可以试试更大的数量级
我这里的测试数据
  1. c=timer
  2. Set a = CreateObject("System.Collections.ArrayList")
  3. for i=0 to 1000000
  4. a.add 0
  5. next
  6. msgbox timer-c
  7. a=timer
  8. dim d()
  9. redim d(-1)
  10. for i=0 to 1000000
  11. redim preserve d(i)
  12. d(i)=0
  13. next
  14. b=ubound(d)
  15. msgbox timer-a
复制代码
5.6
22.7
也就是说在大数量级上频繁redim的效率很低
因为redim的底层实现其实是新开一块空间并把原来的拷贝进去
一个优化过的版本
  1. a=timer
  2. dim d()
  3. redim d(-1)
  4. for i=0 to 1000000
  5. if i > ubound(d) then
  6. redim preserve d(i * 2)
  7. end if
  8. d(i)=0
  9. next
  10. redim preserve d(1000000)
  11. b=ubound(d)
  12. msgbox timer-a
复制代码
0.2
对你没看错,只用了0.2s

TOP

回复 5# jyswjjgdwtdtj


    再扯远一点,数据数量级扩大1,耗时扩大2个数量级,说明是O(n^2)的时间复杂度
数量级扩大1,耗时扩大1个数量级说明是O(n)的时间复杂度
可以测出NET的ArrayList和我的实现都是O(n)的,而你的频繁ReDim的实现是O(n^2)的
其实几乎所有语言的动态数组的标准库实现也是使用较为惰性的增减空间的(类似我那种)
之前和别人在VBS群里讨论的时候就谈过这个事情,和我讨论的那个人还说:官方示例就是那么写的
我只能说官方示例里面也有坑哈哈

TOP

回复 7# 老刘1号


    嗯 为啥选这么个较小的数 是因为如果加个0dictionary会卡着不动就很怪

一般来说用动态数组都会像你这么说地“惰性” 比如要遍历文件夹啥的

之前老是听说dictionary要比动态数组慢 这么看似乎还要快些?

TOP

回复 8# jyswjjgdwtdtj


    dict底层都是哈希表实现,哈希表增删改查时间复杂度都是 O(1) 的。
缺点嘛,就是耗内存。
哈希表只能有效使用10%~20%的内存空间,元素再多性能就会明显下降,所以一般的语言标准库实现都会选择扩容。
算法嘛就是两条原则,时间换空间,或者空间换时间。

TOP

返回列表