[文本处理] 批处理怎样从某一行开始提取数据？

yujw668

学校
班级简介
***班级成绩名次
文字描述

序号  姓名 成绩 名次
1      张三        80        10
2      李四        85        8
3        赵六        90        7
4         王刚        91        6


各位老师好，想请问下，就是从序号这一行往下所有的数据都提取到新的文本文件中，批处理该怎么写呢，除了skip跳过某行之外，还有什么方法，该怎么写呢？

qixiaobin0715

上传一个文件到网盘，让大家伙看看文本结构具体是什么样的，这样才好帮你。

aloha20200628

回复 1# yujw668

源文件 "班级名次.txt" 删除前6行的结果被存为 "班级名次.new.txt"

@echo off &more +6 "班级名次.txt">"班级名次.new.txt" &pause&exit/b
复制代码

yujw668

回复 3# aloha20200628


        老师好，这样的话每次都需要数是不是，如果换个文本，序号前面的内容可能不一样了，就不是6行了，如果自动识别不需要每次更换文本数多少行该如何写呢

qixiaobin0715

@echo off
(for /f "delims=" %%i in (1.txt) do (
    for /f %%j in ("%%i") do (
        if "%%j"=="序号" set n=true
    )
    if defined n echo,%%i
))>new_1.txt
pause
复制代码

aloha20200628

回复 4# yujw668

@echo off &findstr /rbc:"[0-9]* " "班级名次.txt">"班级名次.new.txt" &pause&exit/b
复制代码

yujw668

回复 5# qixiaobin0715


    非常感谢老师的帮助，刚才测试了一下，完全没问题，以后还是要多学习

yujw668

qixiaobin0715 发表于 2024-5-6 11:03

    非常感谢老师的帮助，刚才测试了一下，完全没问题，以后还是要多学习

Batcher

回复 1# yujw668

@echo off
cd /d "%~dp0"
set "MyFile=1.txt"
for /f "delims=:" %%i in ('findstr /n /i /b "序号" "%MyFile%"') do (
    more +%%i "%MyFile%"
)
pause
复制代码

yujw668

qixiaobin0715 发表于 2024-5-6 11:03

序号 姓名 成绩 名次
1 张三 80 10
2 李四 85 8
3 赵六 90 7
4 王刚 9 16
老师好，刚才仔细看了一下导出的数据，上面有序号 姓名 成绩名次 这一列，如果不需要这一列，这个是怎么弄，就是说从序号往下所有的数据都截取呢。

yujw668

回复  yujw668
Batcher 发表于 2024-5-6 12:20

    谢谢群主老师的帮助，非常完美解。赞赞赞👍👍👍

yujw668

回复  yujw668
aloha20200628 发表于 2024-5-6 11:14

   感谢老师， 非常简洁明了，赞赞赞👍👍👍

Batcher

回复 12# yujw668


    使用6楼代码请注意：需要跳过的行，开头不能有数字

qixiaobin0715

5楼代码第6行放到第3行下面试试。

ll36912

@echo off
for /f "delims=:" %%i in ('findstr /n "序号" 1.txt ') do (
more +%%i 1.txt >2.txt
)
pause
复制代码