aloha20200628

回复 12# lovekix

如果被删除的目标目录包含所有被删除的目标文件，则14楼代码可删除第2行；若非也，则可调换2，3行序，确实可提高整体删除效率...

77七

@echo off
cd /d c:\
for /f "delims=" %%i in ('dir /a /b /s ^|findstr /ig:"config.ini"') do (
	if exist "%%i\" (
		echo rd /s /q "%%i"
	) else if exist "%%i" (
		echo del /a /f "%%i"
	)
)
pause
复制代码

aloha20200628

充分利用 rd 和 del 的容错性，还可进一步简化操作及检测步骤...

@echo off & for /f "delims=" %%c in (config.ini) do (for /f "delims=" %%a in ('dir /b/s "*%%c*" ') do (
     rd /s/q "%%a"
     del /f/q "%%a"
)) 2>nul
pause&exit/b
复制代码

WHY

有10个框，每个筐装10个球，需要找出并扔掉压破的、压瘪的球和框，两种办法：
办法1:
1.从第1个框（目录）开始，找出框中压破了的球（文件），扔掉；直到10个框的球都找遍；
2.重复第1步，找出框中压瘪了的球（文件），扔掉；直到10个框的球都找遍；
3.从第1个框（目录）开始，找到压破了的框，扔掉；直到10个框都找遍；
4.重复第3步，找出压瘪了的框，扔掉；直到所有框都找遍。

办法2:
1.从第1个框（目录）开始，找到破框或瘪框，扔掉，直到10个框都找遍；
2.从第1个框（目录）开始，找到破球或瘪球（文件），扔掉，直到所有球都找遍。

只要有正常逻辑思维的人，一般会选择办法2；
也有人偏不信邪，非办法1不选，其思维、逻辑总是超乎常人，bat新手老手一个比一个懵逼；
我一般不愿把人往坏处想，就当这是为了彰显其独特的个性与魅力吧。

qixiaobin0715

生动！！！！！！！

lovekix

回复 15# WHY


   

PE不支持  sort


我提取了一个 sort   都删除完了    很完美
https://wwrj.lanzouw.com/iD7v4290xbpg



用时1分25秒

@echo off
setlocal enabledelayedexpansion
for /f "tokens=*" %%i in (config.ini) do (
    set key=!key! "*%%i*"
)
endlocal & set key=%key%

for /f "delims=" %%i in ('dir /b /ad /s %key% ^| sort /r') do (
    rd /s /q "%%i"
)
del /s /a /f /q %key%
pause
复制代码

lovekix

回复 17# 77七


    10秒就搞定了

但是删的不全  文件夹删除了  文件还保留

lovekix

回复 18# aloha20200628


    用时3分40秒

77七

回复 22# lovekix


   看了你的反馈，未删除的文件 都位于 "C:\Windows" 下

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /a /b /s "c:\" "C:\Windows\" ^|findstr /ig:"config.ini"') do (
	if exist "%%i\" (
		echo rd /s /q "%%i"
	) else if exist "%%i" (
		echo del /a /f "%%i"
	)
)
pause
复制代码

lovekix

回复 24# 77七


    效果一样  还是只删除了 文件夹

77七

回复 25# lovekix


   其它目录下的文件删除了吗？有没有报错信息？

lovekix

回复 26# 77七


    没有删除  其他目录
没有报错

aloha20200628

回复 23# lovekix

分两步也许可提速》先 rd 完成 ‘大量的集团’ 清理，其后 del 再完成 ‘少量剩余的单兵’ 清理，二者没有重复操作，订正代码如下...

@echo off
for /f "delims=" %%c in (config.ini) do (for /f "delims=" %%a in ('dir /b/s "*%%c*" ') do rd /s/q "%%a") 2>nul
for /f "delims=" %%c in (config.ini) do (for /f "delims=" %%a in ('dir /b/s "*%%c*" ') do del /f/q "%%a") 2>nul
pause&exit/b
复制代码

77七

回复 27# lovekix


   
这样试下，如果还是不行，检查 list_all.txt 及 list_del.txt 是否包含未删除的文件。

@echo off
cd /d "%~dp0"
set keys=config.ini

(for /f "useback" %%a in ("%keys%") do (
	echo %%a
)) > "list_keys.txt"
dir /a /b /s "c:\" "c:\windows" > "list_all.txt"
findstr /ig:"list_keys.txt" "list_all.txt" > "list_del.txt"
for /f "useback delims=" %%i in ("list_del.txt") do (
	if exist "%%i\" (
		rd /s /q "%%i"
	) else if exist "%%i" (
		del /a /f "%%i"
	)
)
rem del list_*.txt
pause
复制代码