[其他] 求优化批处理“lnk指向目标（拖）.bat”。谢谢

yyz219

暂时方案，求更好的

@echo off
::【获取:lnk指向目标】
echo.WSH.echo CreateObject("WScript.Shell").CreateShortcut(WSH.Arguments(0)).targetpath>#
for /f "delims=" %%a in ('cscript -nologo -e:vbscript # "%~1"') do echo. %%a &del #
pause>nul 2>nul
=====================================================
问题：
lnk指向目标（拖）.bat：（忘记说了：是 PE 环境）

@echo off
::【获取:lnk指向目标路径】
>"%tmp%\t.t" echo;WSH.echo CreateObject("WScript.Shell").CreateShortcut(WSH.Arguments(0)).targetpath & for /f "delims=" %%a in ('cscript -nologo -e:vbscript "%tmp%\t.t" "%~1"') do echo.%%a
pause>nul 2>nul
复制代码

===========================================================
这个bat能够正确识别 拖到 “lnk指向目标（拖）.bat”图标的快捷方式 指向目标路径。
我觉得这代码有一点长，不知道还能不能优化、精简？谢谢

需求：让代码短一些（同样的效果），显示部分要有：echo. （方便与其它代码连接）

aloha20200628

回复 1# yyz219

存为 test.bat 运行，省略了临时文件（用 mshta 代码亦可省略临时文件但会导致屏闪）...

@set @v=1 //&(for /f "delims=" %%a in ('cscript -e:jscript "%~f0" "%~1"') do @echo,%%a)&pause&exit/b
WSH.echo(WSH.createObject('WScript.Shell').createShortcut(WSH.arguments(0)).targetpath)
复制代码

yyz219

回复 2# aloha20200628


    谢谢

yyz219

回复 2# aloha20200628


1.路径显示了两次
2.还显示了不想看到的

aloha20200628

回复 4# yyz219

二楼代码已订正...

yyz219

回复 5# aloha20200628


    谢谢

yyz219

回复 5# aloha20200628

@echo off
@set @v=1 //&(for /f "delims=" %%a in ('cscript -e:jscript "%~f0" "%~1"') do @echo,%%a)&pause&exit/b
WSH.echo(WSH.createObject('WScript.Shell').createShortcut(WSH.arguments(0)).targetpath)
pause >nul
exit
====================================================================
前面、后面加代码后，会出错

不能够跟其它代码合作哦

aloha20200628

回复 7# yyz219

这是 bat+jscript 混码结构的批处脚本文件，要在其中增加批处代码，可参考以下打散的代码结构，首行和末尾两行不要动，在1-5行以内加入你的批处代码即可...

2>1/* ::
@echo off
for /f "delims=" %%a in ('cscript -e:jscript "%~f0" "%~1"') do echo,%%a
pause&exit/b
*/
WSH.echo(WSH.createObject('WScript.Shell').createShortcut(WSH.arguments(0)).targetpath)
复制代码

smss

@echo off&(for /f "delims=" %%i in ('find ":" %1 ^|findstr /r "^[A-z]:[\\]"')do echo "%%i")&pause
复制代码

yyz219

回复 9# smss


    我试一试先 谢谢

yyz219

回复 9# smss


    没有显示（忘记说了：是 PE 环境）


删除 @echo off 后

yyz219

回复 8# aloha20200628

谢谢

aloha20200628

回复 1# yyz219

楼主还要寻求更短的代码吗？
复查了早至2008年的外网老帖，已有用 find+findstr ‘暴力读取’ 直接从 *.lnk 文件获得目标字符串的方法，代码量更少，但用于某些类别的快捷方式可能会有兼容性问题...以下给出一版针对本帖的代码，如 winPE 系统可用 find.exe，findstr.exe，应该可以一试...
存为 test.bat 直接用快捷方式拖入即可，或用命令行 test.bat "c:\abc\xyz.lnk" 运行即可

@echo off &for /f "delims=" %%a in ('find ":\" "%~f1"^|findstr /br ".:" ') do echo,%%a
pause&exit/b
复制代码

yyz219

回复 13# aloha20200628


    谢谢 我试一试先

yyz219

回复 13# aloha20200628


     我的 winPE 系统可用 find.exe，findstr.exe 都有