计算机单位换算脚本.BAT

jiavip

--------------------------------计算机单位换算脚本.BAT-----------扔代码-------

1. @Echo off
   
2. Rem;;;;;;下句 +1 是为了防止 %b% = 0
   
3. Set/a b=%Random% %% 9 + 1
   
4. :Run
   
5. Set/a a+=1
   
6. Set s=%s%%Random%
   
7. If Not %a% equ %b% Goto,Run
   
8. Rem;;;;;; 下句 %s% 是转换值，可以用其他变量或数值取代，上面几句是编写临时测试脚本用的，可以扔了。。
   
9. Echo.i="%s%" >$
   
10. Echo.If i^<1024 Then  >>$
    
11. Echo.l=i^&" Byte" >>$
    
12. Echo.ElseIf i^<1048576 Then l=Round(i/1024,2)^&" KB" >>$
    
13. Echo.ElseIf i^<1073741824 Then l=Round(i/1048576,2)^&" MB" >>$
    
14. Echo.Elseif i^<1099511627776 Then l=Round(i/1073741824,2)^&" GB" >>$
    
15. Echo.Elseif i^<1125899906842624 Then l=Round(i/1099511627776,2)^&" TB" >>$
    
16. Echo.Elseif i^<1152921504606846976 Then l=Round(i/1125899906842624,2)^&" PB" >>$
    
17. Echo.Elseif i^<1180591620717411303424 Then l=Round(i/1152921504606846976,2)^&" EB" >>$
    
18. Echo.Elseif i^<1208925819614629174706176 Then l=Round(i/1180591620717411303424,2)^&" ZB" >>$
    
19. Echo.Elseif i^<1237940039285380274899124224 Then l=Round(i/1208925819614629174706176,2)^&" YB" >>$
    
20. Echo.Elseif i^<1267650600228229401496703205376 Then l=Round(i/1237940039285380274899124224,2)^&" BB" >>$
    
21. Echo.Elseif i^<1298074214633706907132624082305024 Then l=Round(i/1267650600228229401496703205376,2)^&" NB" >>$
    
22. Echo.Elseif i^<1329227995784915872903807060280344576 Then l=Round(i/1298074214633706907132624082305024,2)^&" DB" >>$
    
23. Echo.Elseif i^<1361129467683753853853498429727072845824 Then l=Round(i/1329227995784915872903807060280344576,2)^&" CB" >>$
    
24. Echo.Else l=Round(i/1361129467683753853853498429727072845824,2)^&" XB" >>$
    
25. Echo.End If >>$
    
26. Echo.Wscript.Echo l >>$
    
27. Rem;;;;;;如果单纯的求换算可以把以下生成的代码删了，保留自删那行就可以了
    
28. Echo.BE=i^&" Byte" >>$
    
29. Echo.KB=Round(i/1024,2)^&" KB" >>$
    
30. Echo.MB=Round(i/1048576,2)^&" MB" >>$
    
31. Echo.GB=Round(i/1073741824,2)^&" GB" >>$
    
32. Echo.TB=Round(i/1099511627776,2)^&" TB" >>$
    
33. Echo.PB=Round(i/1125899906842624,2)^&" PB" >>$
    
34. Echo.EB=Round(i/1152921504606846976,2)^&" EB" >>$
    
35. Echo.ZB=Round(i/1180591620717411303424,2)^&" ZB" >>$
    
36. Echo.YB=Round(i/1208925819614629174706176,2)^&" YB" >>$
    
37. Echo.BB=Round(i/1237940039285380274899124224,2)^&" BB" >>$
    
38. Echo.NB=Round(i/1267650600228229401496703205376,2)^&" NB" >>$
    
39. Echo.DB=Round(i/1298074214633706907132624082305024,2)^&" DB" >>$
    
40. Echo.CB=Round(i/1329227995784915872903807060280344576,2)^&" CB" >>$
    
41. Echo.XB=Round(i/1361129467683753853853498429727072845824,2)^&" XB" >>$
    
42. Echo.Wscript.Echo "=====================" ^& chr(10) ^& l ^& chr(10) ^& "---------------------" ^& chr(10) ^& BE ^& chr(10) ^& KB ^& chr(10) ^& MB ^& chr(10) ^& GB ^& chr(10) ^& TB ^& chr(10) ^& PB ^& chr(10) ^& EB ^& chr(10) ^& ZB ^& chr(10) ^& YB ^& chr(10) ^& BB ^& chr(10) ^& NB ^& chr(10) ^& DB ^& chr(10) ^& CB ^& chr(10) ^& XB ^&  chr(10) ^& "=====================" >>$
    
43. Rem;;;;;;下句是VBS 自删语句，不建议删除
    
44. Echo.CreateObject("Scripting.Filesystemobject").DeleteFile(Wscript.ScriptFullName)>>$
    
45. Rem;;;;;;下句是脚本该脚本调用显示，完整获取 可以用 FOR Cscript -e:vbs -nologo $ 获取转换值和单位，，
    
46. Start/Max "随机生成计算机单位" Cmd /t:e0 /k Echo.随机数【%s%】，循环 %b% 次！^& Cscript -e:vbs -nologo $ ^& Pause^>Nul ^& Exit & Exit
    

复制代码

------------------------------存ANSI 编码---------名 XXXXXX.BAT  -------

朋友写脚本问我，怎么把获取到的文件大小 Size 准确的换成合适的单位来表达，保留小数点后两位
原本我是叫他去找A1的，不过那家伙功底好像有点低，而且比我还懒，，
帮他找里几个A1答复，感觉不是很满意，，
那叼毛，想找的就是全单位转换，Byte，KB、MB、GB、TB、PB、EB、ZB、YB、BB、NB、DB、CB，XB
BAT 下不可转换，可以借助 VBS 来转换，，于是编写了该脚本，，，
编写的时候，计算的位数高达 40 位，1361129467683753853853498429727072845824

普通市面上的计算器 根本无法精确计算，，

找了很多计算器，要么不支持，要么挂羊头卖狗肉，，要么要登录下载，要么过期，
找了几款在线 大整数计算器 ，广告还特别的多，，

于是于昨天，一气之下 ， 抽取了其中一款在线计算器的部分核心计算源码，，
借助 A1 改写了一款  “大整数计算器 — 超大整数运算与进制转换”，的计算器，
https://www.bathome.net/thread-95286-1-1.html
支持 10万位整数计算表达，，，算是意外所得，，
，人啊，不能吃太饱，闲得慌！，，，

77七

让AI参考 https://bbs.bathome.net/forum.ph ... 1593&pid=153139

逐位长除法

bytes_convert.bat

1. @echo off
   
2. setlocal EnableExtensions EnableDelayedExpansion
   
3. 
   
4. :input
   
5. set "bytes="
   
6. set /p "bytes=Bytes: "
   
7. if not defined bytes exit /b
   
8. 
   
9. rem 检查输入是否全部为数字
   
10. set "bad=!bytes!"
    
11. for %%D in (0 1 2 3 4 5 6 7 8 9) do if defined bad set "bad=!bad:%%D=!"
    
12. if defined bad (
    
13.     echo Please enter a nonnegative integer using digits only.
    
14.     goto input
    
15. )
    
16. if not "!bytes:~1000,1!"=="" (
    
17.     echo Please enter at most 1000 digits.
    
18.     goto input
    
19. )
    
20. 
    
21. rem 去除多余的前导零
    
22. :trim_input
    
23. if "!bytes:~0,1!"=="0" if not "!bytes:~1!"=="" (
    
24.     set "bytes=!bytes:~1!"
    
25.     goto trim_input
    
26. )
    
27. 
    
28. rem 末尾补三个零，相当于乘以1000，内部保留三位小数
    
29. set "scaled=!bytes!000"
    
30. set "best=!bytes! Byte"
    
31. echo(
    
32. echo !bytes! Byte
    
33. 
    
34. for %%U in (KB MB GB TB PB EB ZB YB BB NB DB CB XB) do (
    
35.     call :divide1024
    
36.     call :format2
    
37.     echo !shown! %%U
    
38.     rem scaled至少有四位，说明换算结果不小于1
    
39.     if not "!scaled:~3,1!"=="" set "best=!shown! %%U"
    
40. )
    
41. 
    
42. echo(
    
43. echo Auto: !best!
    
44. echo(
    
45. pause
    
46. exit /b
    
47. 
    
48. rem 大整数除以1024，商仍然保存为字符串
    
49. :divide1024
    
50. setlocal EnableDelayedExpansion
    
51. set "src=!scaled!"
    
52. set "quotient="
    
53. set /a rem=0
    
54. 
    
55. :divide_next
    
56. set /a "work=rem*10+!src:~0,1!,digit=work/1024,rem=work%%1024"
    
57. if defined quotient (
    
58.     set "quotient=!quotient!!digit!"
    
59. ) else if !digit! neq 0 (
    
60.     set "quotient=!digit!"
    
61. )
    
62. set "src=!src:~1!"
    
63. if defined src goto divide_next
    
64. 
    
65. if not defined quotient set "quotient=0"
    
66. endlocal & set "scaled=%quotient%"
    
67. exit /b
    
68. 
    
69. rem 四舍五入到两位小数，不修改内部的scaled
    
70. :format2
    
71. setlocal EnableDelayedExpansion
    
72. set "digits=000!scaled!"
    
73. set "round=!digits:~-1!"
    
74. set "digits=!digits:~0,-1!"
    
75. if !round! lss 5 goto format_trim
    
76. 
    
77. rem 对任意长度的数字字符串加1，处理连续进位
    
78. set "tail="
    
79. 
    
80. :format_carry
    
81. set "digit=!digits:~-1!"
    
82. set "digits=!digits:~0,-1!"
    
83. if "!digit!"=="9" (
    
84.     set "tail=0!tail!"
    
85.     goto format_carry
    
86. )
    
87. set /a digit+=1
    
88. set "digits=!digits!!digit!!tail!"
    
89. 
    
90. :format_trim
    
91. if "!digits:~0,1!"=="0" if not "!digits:~3!"=="" (
    
92.     set "digits=!digits:~1!"
    
93.     goto format_trim
    
94. )
    
95. set "shown=!digits:~0,-2!.!digits:~-2!"
    
96. endlocal & set "shown=%shown%"
    
97. exit /b

复制代码

aloha20200628

用 bat+powershell 简化此题的解法如下，虽然目前存储设备厂商单个最大容量产品仍在 TB 量级，代码中还是扩展至 XB 量级作为示例，超过 XB 量级的转换结果均以 XB 为单位。

test.bat

1. @echo off &setlocal &set "u=B KB MB GB TB PB EB ZB YB BB NB DB CB XB"
   
2. :loop
   
3.   set "v=" &set/p "v=输入一个字节值，须为正整数(直接回车键退出)："
   
4.   if not defined v exit/b
   
5.   for /f "delims=1234567890" %%i in ("%v:"=%") do goto :loop
   
6.   powershell -nop -c "$n,$v,$u=0,%v%,'%u%'.split(); while($v/1kb -ge 1){$v/=1kb;if(++$n -eq $u.length-1){break}};(('{0:n2}' -f $v) -replace '\.*0+$')+' '+$u[$n]"
   
7.   goto :loop

复制代码

flashercs

77七 发表于 2026-10-2 21:33
让AI参考 https://bbs.bathome.net/forum.php?mod=redirect&goto=findpost&ptid=31593&pid=153139

逐位长 ...

长除法用的真好,解决了任意长度的整数的除法问题;
这是AI写的代码吗?哪个AI写的?

flashercs

aloha20200628 发表于 2026-10-5 17:33
用 bat+powershell 简化此题的解法如下，虽然目前存储设备厂商单个最大容量产品仍在 TB 量级，代码中还是扩 ...

double类型的精度不够, 如果输入长度500的大整数,会出错的;应该用 System.Numerics.BigInteger

1. $n,$v,$u=0,[bigint]'%v%','%u%'.split();

复制代码

aloha20200628

flashercs 发表于 2026-10-5 21:16
double类型的精度不够, 如果输入长度500的大整数,会出错的;

   给出的示例脚本仅为实用，即与本帖主题有关的 '字节量转 KB,MB,GB,... 单位' 的实用性（采用5位有效数字 aaa.bb 的浮点数格式），可能更多是用于获取 MB~TB 区段且保留两位小数精度的转换结果
   刚刚用 ai 查获 idc 报告2025年的全球年度数据生成量，也只是 ZB 量级（数据长度不过30位），而被物理存储的数据量，更是其中很小一部分...

jiavip

你们有毅力，，，
我都是直接硬桥硬码的硬推，，
钓鱼时候（空军），爪机临时查资料，拼出来的，，
回来之后随便校对一下代码可行性，就硬推了，，，，
我以为我自己已经够懒了，，结果，我那叼毛朋友比我还懒，，，
这几天没口，，呆着，就又用A1 随便写了个 HTA 小说阅读工具，，，

功能和其他设置都有，还能保存设置，阅读记录，书签等等，才100K 不到，，够用了，，