批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理findstr命令怎么搜索完全匹配行？ [打印本页]

作者: czjt1234 时间: 2010-12-30 08:42 标题: [已解决]批处理findstr命令怎么搜索完全匹配行？

比如 e:\d.txt 内容

完美世界前传
诛仙
System Volume Information
魔兽世界

如果
for /f "delims=" %%i in ('dir d:\ /a/b') do find /i "%%i" e:\d.txt||rd /q/s d:\"%%i"
想删除e:\d.txt里没有的文件夹
但是如果有 d:\完美世界，那么find不能完全匹配该行，所以不能删除

请问findstr怎么用法？

[ 本帖最后由 czjt1234 于 2010-12-30 12:05 编辑 ]

作者: cutebe 时间: 2010-12-30 08:48

findstr /x "完美世界" a.txt

作者: hanyeguxing 时间: 2010-12-30 09:00

不使用 findstr ：

@echo off
set "t=e:\d.txt"
set "p=d:\"
for /f "usebackq delims=" %%a in ("%t%") do set #"%%a"==
for /f "delims=" %%a in ('dir /b/ad "%p%"') do if not defined #"%%a" (
        del "%p%%%a\" /s/q/a/f
        rd "%p%%%a\" /s/q
)
复制代码

使用 findstr ：

@echo off
set "t=e:\d.txt"
set "p=d:\"
for /f "delims=" %%a in ('dir /b/ad "%p%"^|findstr /x /v /i /g:"%t%"') do (
        del "%p%%%a\" /s/q/a/f
        rd "%p%%%a\" /s/q
)
复制代码

[ 本帖最后由 hanyeguxing 于 2010-12-30 09:20 编辑 ]

欢迎光临批处理之家 (http://bbs.bathome.net/)