批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理可不可以实现动态变量名的功能呢？ [打印本页]

作者: spark12 时间: 2011-1-3 00:43 标题: [已解决]批处理可不可以实现动态变量名的功能呢？

想取文件名的首字符，但是下面的形式会出错，应该怎样写呢？

@echo off
for /f %%a in ('dir /b *.txt') do (
echo %a:~0,1%
)
复制代码

还有，可不可以实现动态变量名的功能，例如：(就是类似 %List%%y% 的写法)

set List1=视频:avi:mpg:3gp
set List2=音频:wma:mp3:wav
set List3=压缩:zip:rar:7z
set List4=图片:jpg:bmp:png

FOR /L %%y IN (1,1,4) DO (
    FOR /F "tokens=1-3 delims=:" %%j IN (%List%%y%) DO (
        echo %%j %%k %%l %%m
    )
)
复制代码

[]

[ 本帖最后由 spark12 于 2011-1-6 12:45 编辑 ]

作者: caruko 时间: 2011-1-3 00:48

在for内调用循环变量Y，必须%%Y
而且动态变量需要开启变量延迟，把下面这个加在For之前
setlocal enabledelayedexpansion

另外你的%List%%y%应该是 !List%%y!

[ 本帖最后由 caruko 于 2011-1-3 00:50 编辑 ]

作者: wc726842270 时间: 2011-1-3 00:56

你的错误实在是太明显了,

@echo off&setlocal enabledelayedexpansion
for /f %%a in ('dir /b *.txt') do set a=%%a&&set b=!a:~0,1!&echo !b!
pause
复制代码

我想只要第一个字符,就不要引号了

作者: spark12 时间: 2011-1-3 01:01

啊，那就是说必须得有中间变量了？

作者: wc726842270 时间: 2011-1-3 01:10

2L说的是变量优先级的问题啊
http://www.bathome.net/thread-6537-1-2.html
这篇可是非常不错的文章啊

作者: hanyeguxing 时间: 2011-1-3 10:49

1，

@echo off&setlocal enableDelayedExpansion
for %%a in (*.txt) do set a=%%a&echo !a:~0,1!
pause
复制代码

2，如果要显示新定义的变量：

@echo off
set List1=视频:avi:mpg:3gp
set List2=音频:wma:mp3:wav
set List3=压缩:zip:rar:7z
set List4=图片:jpg:bmp:png
set List
pause
复制代码

如果要解析新定义的变量：

@echo off
set List1=视频:avi:mpg:3gp
set List2=音频:wma:mp3:wav
set List3=压缩:zip:rar:7z
set List4=图片:jpg:bmp:png
FOR /F "tokens=1-5 delims==:" %%i IN ('set List') DO echo %%i %%j %%k %%l %%m
pause
复制代码

[ 本帖最后由 hanyeguxing 于 2011-1-3 10:50 编辑 ]

欢迎光临批处理之家 (http://bbs.bathome.net/)