批处理之家 - Powered by Discuz! Board

标题: [文件操作] [已解决]批处理xcopy命令如何复制文件名带括号的文件夹？ [打印本页]

作者: yhcbird 时间: 2011-1-7 13:07 标题: [已解决]批处理xcopy命令如何复制文件名带括号的文件夹？

set x="C:\Documents and Settings\Administrator\桌面"
dir /ad /b %x% >>1.txt 
copy %x%\批处理\不可删除txt\2.txt %x%\批处理
findstr /v /x /r /g:2.txt 1.txt >3.txt
for /f "usebackq delims=" %%i in ("3.txt") do ( xcopy /e /i %x%\%%i F:\桌面文件夹\%%i 
rd /s /q %x%\%%i)
del *.txt

pause
复制代码

以上代码在复制“新建文件夹（2）” “新建文件夹（3）”的时候发现执行不了。而其他如果没有特殊符号的都可以。怎么解决呢

[ 本帖最后由 yhcbird 于 2011-1-7 13:31 编辑 ]

作者: hanyeguxing 时间: 2011-1-7 13:09

所有带变量的路径都用""引号对括起来

作者: yhcbird 时间: 2011-1-7 13:16

用""对括起来后会出现这样的情况就是：

说明多了个引号对。不知道引号应该怎么加呢？除非上面路径的变量不用设置。。实现

"C:\Documents and Settings\Administrator\桌面\新建文件夹（3)" 这样才行的吧

作者: hanyeguxing 时间: 2011-1-7 13:23

@echo off
set "x=%userprofile%\桌面"
dir /ad /b "%x%">>1.txt 
copy "%x%\批处理\不可删除txt\2.txt" "%x%\批处理"
findstr /v /x /r /g:2.txt 1.txt >3.txt
for /f "usebackq delims=" %%i in ("3.txt") do (
	xcopy /e /i "%x%\%%i" "F:\桌面文件夹\%%i" 
	rd /s /q "%x%\%%i"
)
del *.txt
pause
复制代码

作者: yhcbird 时间: 2011-1-7 13:30 标题: 回复楼上的

有道理啊：
set "x=%userprofile%\桌面"
变量这样设置就可以了。。
我刚才相当于是这样：
set x="%userprofile%\桌面"
所以........

欢迎光临批处理之家 (http://bbs.bathome.net/)