@echo off
:0
cls
echo.
echo.                               ╭────────╮
echo.          ╭───────┤ 使 用  说 明 ├───────╮
echo.          │                   ╰────────╯                 │
echo.          │                                                               │
echo.          │   1、本工具的用途是——把指定目录      │
echo.          │      里，某类指定后缀名的文件，批        │
echo.          │      量的修改为其它指定的后缀名。        │
echo.          │                                                               │
echo.          │   2、每一步输入完毕，都请敲回车！     │
echo.          │                                                               │
echo.          │   3、注意——只输入后缀名，不要         │
echo.          │      输入后缀名前的“.”                         │
echo.          │                                                               │
echo.          │   4、文件夹的路径中如有空格和特殊      │
echo.          │      字符，请手打输入，不要拖放！        │
echo.          │                                                               │
echo.          ╰────────────────────────╯
echo.&echo           请输入文件夹的路径，或拖放文件夹到本窗口
set LJ=
set /p LJ=
if /i "%LJ%"=="" goto 0
echo.&echo         请输入修改前的后缀名：
set q=
set /p q=
if /i "%q%"=="" goto 0
echo.&echo          请输入修改后的后缀名：
set h=
set /p h=
if /i "%h%"=="" goto 0
for /r %LJ% %%i in (*.%q%) do ren %%i *.%h%
echo.&echo.           后缀名已批量修改成功！
echo.&echo.           请打开文件夹看看吧！
start %LJ%
pause
goto 0
复制代码

for /r %LJ% %%i in (*.%q%) do ren %%i *.%h%
复制代码

@echo off
set x0=.bat
set x1=.cmd
set c=1
if "%~1"=="" set m==&goto:b
:a
set "a=%~a1"
if "%a:~0,1%"=="-" (set d==) else set d=
if defined d (
if /i "%~x1"=="%x0%" (
        set "a=%~n1%x1%"
        setlocal enabledelayedexpansion
        ren "%~1" "!a:~0,1!%c%!a:~1!"
        endlocal
) else echo 未处理;"%~1"
)
:b
if not defined m set n="%~1\"
if not defined d for /r %n% %%a in (*) do if /i "%%~xa"=="%x0%" (
        set "a=%%~na%x1%"
        setlocal enabledelayedexpansion
        ren "%%a" "!a:~0,1!%c%!a:~1!"
        endlocal
) else echo 未处理;"%%a"
if defined m goto:end
shift
if not "%~1"=="" goto:a
:end
echo;完成
pause
复制代码

 
ren "%%a" "!a:~0,1!!a:~2!"
复制代码

 
@echo off
:0
cls
echo.
echo.               ╭────────╮
echo.     ╭────┤  使 用 说 明   ├────╮
echo.     │        ╰────────╯        │
echo.     │                                    │
echo.     │   1、本工具的用途是——在指定目录  │
echo.     │      里，建立回收站。              │
echo.     │                                    │
echo.     │   2、每一步输入完毕，都请敲回车！  │
echo.     │                                    │
echo.     │   3、支持文件夹的名字和路径中含有  │
echo.     │      空格和特殊字符！              │
echo.     │                                    │
echo.     │   3、手打输入文件夹的名字和路径、  │
echo.     │      和回收站的名字时，请在前后    │
echo.     │      加上英文的双引号——"         │
echo.     │                                    │
echo.     ╰──────────────────╯
echo.&echo      请输入文件夹的路径，或拖放文件夹到本窗口
set mulu=
set /p mulu=
echo.&echo         请输入回收站的名字：
set /p minzi=
md %mulu%\%minzi%>nul 2>nul
attrib +s +h %mulu%\%minzi%>nul 2>nul
(echo [.ShellClassInfo]
echo CLSID={645FF040-5081-101B-9F08-00AA002F954E})>%mulu%\%minzi%\desktop.ini
attrib +s +h %mulu%\%minzi%\desktop.ini
echo.&echo.         回收站已建立成功！
echo.&echo.         手工打开看看吧！
echo.
pause
goto 0
复制代码

@echo off

:Input_Folder
    echo 请输入文件夹路径（或拖放文件夹到本窗口）：
    set Folder=
    set /p Folder=    
    
    if not defined Folder goto Input_Folder
    if not exist "%Folder:"=%" (
        echo * 错误：不存在该文件夹
        goto Input_Folder
    )

:Input_OldExt
    set OldExt=
    set /p OldExt=请输入原后缀名：
    
    if not defined OldExt goto Input_OldExt

:Input_NewExt
    set NewExt=
    set /p NewExt=请输入新后缀名：
    
    if not defined NewExt goto Input_NewExt

rem 去除路径中的引号、后缀中的“.”及前面的字符
set "Folder=%Folder:"=%"
set "OldExt=%OldExt:*.=%"
set "NewExt=%NewExt:*.=%"

for /f "delims=" %%i in ('dir /a:-d /b /s "%Folder%\*.%OldExt%"') do (
    set fPath=%%~dpi
    set fName=%%~ni
    set fAttr=%%~ai
    SetLocal EnableDelayedExpansion
    
    rem 判断有没有“系统”和“隐藏”属性，有则去除
    set AttrList=
    if "!fAttr:s=!" neq "!fAttr!" set AttrList= s
    if "!fAttr:h=!" neq "!fAttr!" set AttrList=!AttrList! h
    if defined AttrList (
        attrib !AttrList: = -! "!fPath!!fName!.!OldExt!"
    )
    
    rem 计算文件名的字符个数
    set /a n = 8189, b = 0
    for /l %%a in (1 1 13) do (
        set /a "a = (n - b) / 2 + b"
        for %%b in (!a!) do (
            if "!fName:~%%b,1!"=="" (set n=!a!) else set b=!a!
        )
    )
    
    rem 颠倒文件名
    set /a n -= 1
    for /l %%n in (0 1 !n!) do (
        set NewName=!fName:~%%n,1!!NewName!
    )
    
    rem 重命名
    ren "!fPath!!fName!.!OldExt!" "!NewName!.!NewExt!"
    
    rem 如果之前修改了文件属性，则改回去
    if defined AttrList (
        attrib !AttrList: = +! "!fPath!!NewName!.!NewExt!"
    )
    
    EndLocal
)
复制代码