批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]如何以txt文件中的标识字符批量更改文件夹及文件名？ [打印本页]

作者: plues 时间: 2011-1-23 22:20 标题: [已解决]如何以txt文件中的标识字符批量更改文件夹及文件名？

问题描述如下，恳求各位前辈相助，谢谢！！

一、说明
① abc文件夹下存储有N个子文件夹，每个子文件夹下含有以txt、doc、xls作为后缀名的文件，请见图1。
② 子文件夹名及所属文件名无规律。
③ 每个txt文件均包含一行形如“名称：*/*/*/...../*”的标识字符。其中 * 表示1个或多个字符。
特殊情况：某些txt文件中，无“/”,形如：“名称：*”

二、处理目的
查找每个子文件夹下的txt文件中的以“名称：”作为关键字的行。
提取“名称：”后面的字符 * 作为子文件夹名及子文件夹下所有文件的名称。

三、处理规则
如果“名称：”后面无“/”,则直接提取“名称：”后面的字符更改所有文件及子文件夹名；
如果后面包含“/”,则提取“名称：”后面中的 * 字符更改所有文件及子文件夹名，“/”改为“_”。

四、示例

[ 本帖最后由 plues 于 2011-1-23 23:48 编辑 ]

作者: hanyeguxing 时间: 2011-1-23 23:06

@echo off&setlocal enabledelayedexpansion
for /r "C:\abc" %%a in (*.txt) do for /f "tokens=1* delims=：" %%c in ('findstr /bi "名称：" "%%a"') do (
        set "d=%%d"&set "d=!d:/=_!"
        for %%b in ("%%~dpa*") do ren "%%~b" "!d!%%~xb"
        ren "%%~dpa" "!d!"
)
复制代码

或：

@echo off
for /r "C:\abc" %%a in (*.txt) do for /f "tokens=1* delims=：" %%c in ('findstr /bi "名称：" "%%a"') do (
        set "d=%%d"
        setlocal enabledelayedexpansion
        set "d=!d:/=_!"
        for %%b in ("%%~dpa*") do ren "%%~b" "!d!%%~xb"
        ren "%%~dpa" "!d!"
        endlocal
)
复制代码

[ 本帖最后由 hanyeguxing 于 2011-1-23 23:57 编辑 ]

作者: plues 时间: 2011-1-23 23:46

代码非常完美！批处理真是太强大了！繁杂的问题终于解决了，非常感谢版主亲自出马相助！！！

欢迎光临批处理之家 (http://bbs.bathome.net/)