批处理之家 - Powered by Discuz! Board

标题: [网络连接] 我在本网站找的ping的批处理怎样改一下？ [打印本页]

作者: xctk2008 时间: 2011-1-24 19:39 标题: 我在本网站找的ping的批处理怎样改一下？

@echo off
echo
set /p ip=你要ping/tracert的IP:
if /I "%ip%"=="" Exit
echo .
echo 正在处理...
echo ------------------------------------------------------------------------>  ping.txt
echo    *科技成就未来，服务创造价值*                            >>ping.txt
echo ------------------------------------------------------------------------>> ping.txt
ping %ip% >> ping.txt
tracert %ip% >> ping.txt
echo ------------------------------------------------------------------------>> ping.txt
echo                   %date% %time% >>ping.txt
echo ------------------------------------------------------------------------>> ping.txt
echo .
echo 处理完成，结果在ping.txt中！

我想把上面的代码  改成固定的  ip  不要自己填IP的  那种谢谢大家了

作者: hanyeguxing 时间: 2011-1-24 20:18

1，如果只是想 ping ，则直接

>"文本.txt" ping -n 1 -w 100 192.168.1.1
复制代码

2，如果是楼主的代码，则把
set /p ip=你要ping/tracert的IP:
改成
set ip=192.168.1.1 等具体的ip

作者: xctk2008 时间: 2011-1-24 20:35 标题: 回复 2楼的帖子

我没有看明白我就是想改成固定的IP
例如这个 ping 192.168.0.1 -l 35500 -t ping1个小时自己就停了
你能帮我改吗

作者: hanyeguxing 时间: 2011-1-24 20:46

延迟1小时要求：
1，%date%形如“2010-01-24 ...”
2，%time%形如“ 9:55:37.88”（9前面有一个空格）
3，桌面位于 %userprofile%\桌面

@echo off
set H=%time:~0,2%&set S=%time:~3%
set/a H=%H: =%+1,H=H*!!(H-24),D=1%date:~8,2%%%100+!H,Y=%date:~0,4%,M=1%date:~5,2%-100,"K=!(M-4)|!(M-6)|!(M-9)|!(M-11)","E=!(M-2)*(28+!(Y%%4))+K*30+(!!(M-2)&!K)*31"
if %D% gtr %E% set/a D=1,M+=1
if %M%==13 set/a M=1,Y+=1
set M=0%M%&set D=0%D%&set H= %H%
:p
>>"%userprofile%\桌面\ping.txt" ping.exe 192.168.0.1 -l 35500
if "%date:~0,10%%time%" leq "%Y%-%M:~-2%-%D:~-2%%H:~-2%:%S%" goto:p
复制代码

[ 本帖最后由 hanyeguxing 于 2011-1-24 21:48 编辑 ]

作者: xctk2008 时间: 2011-1-24 20:53 标题: 回复 4楼的帖子

@echo off
echo
set /p ip=你要ping/tracert的IP:
if /I "%ip%"=="" Exit
echo .
echo 正在处理...
echo ------------------------------------------------------------------------>  ping.txt
echo    *科技成就未来，服务创造价值*                            >>ping.txt
echo ------------------------------------------------------------------------>> ping.txt
ping %ip% >> ping.txt
tracert %ip% >> ping.txt
echo ------------------------------------------------------------------------>> ping.txt
echo                   %date% %time% >>ping.txt
echo ------------------------------------------------------------------------>> ping.txt
echo .
echo 处理完成，结果在ping.txt中！

我的意思就是他现在是让输入  ip我想变成固定的ip
比如 ping 192.168.0.1 -l 35500 ping一个小时自己停  并保存桌面
你能帮我改好吗
谢谢了

作者: ithinkican 时间: 2011-1-24 23:19 标题: [code]

@echo off
ping 192.168.0.1 -n 3600>>ping.txt
start ping.txt
exit
[\code]

[ 本帖最后由 ithinkican 于 2011-1-24 23:21 编辑 ]

欢迎光临批处理之家 (http://bbs.bathome.net/)