@echo off
(for /f "tokens=3,5 delims==> " %%a in (1.txt) do for /f "tokens=1,2" %%c in ("%%~a %%~b") do echo %%c,%%d,1)>2.txt
复制代码

@echo off
(for /f "tokens=3,5 delims==> " %%a in (test.txt) do  echo %%~a,%%~b,1)>2.txt
pause>nul
复制代码

@echo off
for /f tokens^=1*^ delims^=^" %%a in ("sd"z"vc") do echo %%b
pause
复制代码

@echo off
(for /f tokens^=2^,4^ delims^=^" %%a in (test.txt) do echo %%a,%%b,1)>2.txt
pause
复制代码

@echo off
(
echo %random%
for /f %%a in ('echo %%random%%') do echo %%a
pause
)
复制代码

abcde^fg^
abcd"efg"
abc^de"fg
abc"de^fg
复制代码

@echo off
::^做分隔符的两种写法
echo "^做分隔符的写法1"
for /f "tokens=1-3delims=^" %%i in (1.txt) do echo %%j
echo "^做分隔符的写法2"
for /f tokens^=1-3delims^=^^ %%i in (1.txt) do echo %%j

::"做分隔符的写法
for /f tokens^=1-3delims^=^" %%i in (1.txt) do echo %%j
::下面的写法提示“命令语法不正确 ”
::for /f "tokens=1-3 delims="" %%i in (1.txt) do echo %%j 

::"和^一起做分隔符
for /f tokens^=1-3delims^=^"^^ %%i in (1.txt) do echo %%j
复制代码

@echo off
echo 123%%456%%789>1.txt
echo 123"456"789>>1.txt
echo 123^&456^&789>>1.txt

for /f tokens^=1-3^,*delims^=^%%^&^"^2 %%i in (1.txt) do @echo ---%%i---%%j---%%k---%%l
pause
复制代码

set a=101
if "!a:~0,1!"=="0" (echo a0===0&if "!a:~1,1!"=="0" (echo a1===0&if "!a:~2,1!"=="0" (echo a2===0) ^
                                                                               else echo a2===1) ^
                                               else echo a1===1&if "!a:~2,1!"=="0" (echo a2===0) ^
                                                                               else echo a2===1) ^
               else echo a0===1&if "!a:~1,1!"=="0" (echo a1===0&if "!a:~2,1!"=="0" (echo a2===0) ^
                                                                               else echo a2===1) ^
                                               else echo a1===1&if "!a:~2,1!"=="0" (echo a2===0) ^
                                                                               else echo a2===1

rem 规范格式
set a=110
if "!a:~0,1!"=="0" (
  echo a0===0
  if "!a:~1,1!"=="0" (
    echo a1===0
    if "!a:~2,1!"=="0" (
      echo a2===0
    ) else (
      echo a2===1
    )
  ) else (
    echo a1===1
    if "!a:~2,1!"=="0" (
      echo a2===0
    ) else (
      echo a2===1
    )
  )
) else (
  echo a0===1
  if "!a:~1,1!"=="0" (
    echo a1===0
    if "!a:~2,1!"=="0" (
      echo a2===0
    ) else (
      echo a2===1
    )
  ) else (
    echo a1===1
    if "!a:~2,1!"=="0" (
      echo a2===0
    ) else (
      echo a2===1
    )
  )
)

pause&goto :EOF
复制代码

for /f %%a in ("测试 test") do echo %%%%a=%%a   %%%%b=%%b
::在for 中除了 usebackq 和 skip 外所有开关均有默认参数，上面这句貌似啥也没设置，其实默认为："eol=; tokens=1 delims=[tab制表符][空格]"
::而因为在隐藏的默认参数中，tokens 仅指定了 1，所以只分配第一节内容给了 %%a，而没有分配任何内容给 %%b

for /f "tokens=1,2,4-5 delims=诗《》：" %%a in ("唐诗经典：（插入广告）《长恨歌》白居易") do echo 由 %%a 代诗人 %%d 所著的 %%c 是一部 %%b 。
::delims 指定了四个分隔符，tokens 以此为据，指定要取第1、2、4、5 节
::这里的 1,2 表示第 1 和 2 节，而 4-5 表示 4 到 5 节（在取连续多节的时候是很有效的简写，此处仅为示例）
::而要注意的是，因为此处未在 tokens 中指定第 3 节，故 %%c 跳过第三节，直接与已被声明的第 4 节对应，%%d 则紧随其后，与第 5 节对应。

for /f "tokens=2* delims=-" %%a in ("当前日期-北京时间-2011-11-24") do echo %%b
::tokens 中 * 除非是唯一参数，否则必须跟在某个数字后面，以声明其位置。
::在 tokens 中指定了某一节后我们可以不引用它，但是他会占用一个对应位置的令牌

for /f "tokens=* delims=0" %%a in ("000001234000") do echo %%a
::将第一节与其后内容作为一个整体，去掉前缀的所有分隔符 0
::"tokens=*" 与 "delims=" 的区别就在于此，前者将删除第一节之前的所有分隔符取其后内容，而后者则是不指定分隔符所以整行文本作为一节内容输出。
复制代码

:: cmd命令行下粘贴如下代码
:: "老" 到 "耣" 的unicode编码（连续地）为 "8001" 到 "8023"
set ss=1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32
for /f "tokens=1-31" %老 in ("%ss%")do @echo %老 %耂 %考 %耄 %者 %耆 %耇 %耈 %耉 %耊 %耋 %而 %耍 %耎 %耏 %耐 %耑 %耒 %耓 %耔 %耕 %耖 %耗 %耘 %耙 %耚 %耛 %耜 %耝 %耞 %耟 %耠 %耡 %耢 %耣
复制代码