批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理用维热纳尔方阵给文本加密 [打印本页]

作者: pusofalse 时间: 2008-7-29 23:20 标题: 批处理用维热纳尔方阵给文本加密

如下，维热纳尔方阵，请发现每行变化的规律。

 
       A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
       a b c d e f g h i j k l m n o p q r s t u v w x y z
-----------------------------------------------------------

1      B C D E F G H I J K L M N O P Q R S T U V W X Y Z A
2      C D E F G H I J K L M N O P Q R S T U V W X Y Z A B
3      D E F G H I J K L M N O P Q R S T U V W X Y Z A B C
4      E F G H I J K L M N O P Q R S T U V W X Y Z A B C D
5      F G H I J K L M N O P Q R S T U V W X Y Z A B C D E
6      G H I J K L M N O P Q R S T U V W X Y Z A B C D E F
7      H I J K L M N O P Q R S T U V W X Y Z A B C D E F G
8      I J K L M N O P Q R S T U V W X Y Z A B C D E F G H
9      J K L M N O P Q R S T U V W X Y Z A B C D E F G H I
10     K L M N O P Q R S T U V W X Y Z A B C D E F G H I J
11     L M N O P Q R S T U V W X Y Z A B C D E F G H I J K
12     M N O P Q R S T U V W X Y Z A B C D E F G H I J K L
13     N O P Q R S T U V W X Y Z A B C D E F G H I J K L M
14     O P Q R S T U V W X Y Z A B C D E F G H I J K L M N
15     P Q R S T U V W X Y Z A B C D E F G H I J K L M N O
16     Q R S T U V W X Y Z A B C D E F G H I J K L M N O P
17     R S T U V W X Y Z A B C D E F G H I J K L M N O P Q
18     S T U V W X Y Z A B C D E F G H I J K L M N O P Q R
19     T U V W X Y Z A B C D E F G H I J K L M N O P Q R S
20     U V W X Y Z A B C D E F G H I J K L M N O P Q R S T
21     V W X Y Z A B C D E F G H I J K L M N O P Q R S T U
22     W X Y Z A B C D E F G H I J K L M N O P Q R S T U V
23     X Y Z A B C D E F G H I J K L M N O P Q R S T U V W
24     Y Z A B C D E F G H I J K L M N O P Q R S T U V W X
25     Z A B C D E F G H I J K L M N O P Q R S T U V W X Y
26     A B C D E F G H I J K L M N O P Q R S T U V W X Y Z 
复制代码

加密实例：
用forset来加密better to do well than to say well

密匙 F O R E S T F O R E S T F O R E S T F O R E S T F O R
明文 b e t t e r t o d o w e l l t h a n t o s a y w e l l
密文 G S K X W K Y C U S O X Q Z K L S G Y C J E Q P J Z C
（看第5行，F开头，明文是b，要用G来加密；第14行，O开头，明文是e，要用S来
加密，如此类推......）

以下。
密匙：trust
明文：believe
密文：U V F A X O V

密匙: false
明文: believe
密文: G E W A I A E

密匙:batch
明文:bbsbathome
密文:C B L D H U H H O L

要求：
一，输入任意密匙和明文，用维热纳尔方阵加密，输出正确结果。
二，如能正确解答出要求一，写出相应的解密程序，只是一个逆推理。

[ 本帖最后由 pusofalse 于 2009-5-1 20:53 编辑 ]

作者: batman 时间: 2008-7-30 01:39

@echo off&setlocal enabledelayedexpansion
rem 生成方阵
set "codes=a b c d e f g h i j k l m n o p q r s t u v w x y z"
set "code=%codes: =%"
set "_a=%code%"
for /l %%i in (1,1,25) do (
    set "code=!code:~1!!code:~,1!"
    set  "_!code:~,1!=!code!"
)
echo.&set /p str=请输入明文:
echo.&set /p pss=请输入密匙:
echo.&set /p=生成的密文:<nul
:again
set "a1=%str:~,1%"&set "a2=%pss:~,1%"
set "str=%str:~1%"&set "pss=%pss:~1%%a2%"
call :lp
if defined str goto again
pause>nul&goto :eof
:lp
for %%i in (%codes%) do (
      set /a n+=1
      if /i "%%i" equ "%a1%" goto next
)
:next
set /a n-=1
set "var=!_%a2%!"
set "var=!var:~%n%,1!"
set /p=%var% <nul&set "n=0"
复制代码

[attach]1235[/attach]

[ 本帖最后由 Batcher 于 2009-5-1 20:56 编辑 ]

作者: pusofalse 时间: 2008-7-30 02:03

batman兄的代码没有密匙，密文只是通过右移一位而来的。另外有一处错误，是导致每次都右移一位的根本所在。
for %%i in (codes) do (
set /a n+=1
if /i "%%i" equ "%1" goto next
)

维热纳尔方阵加密出的密文非常牢固，要解开，必须要有双方协定好的密匙（可以是个有意义的英文单词）。
可能是我说的太模糊了，已修正。

[ 本帖最后由 pusofalse 于 2008-7-30 02:38 编辑 ]

作者: pusofalse 时间: 2008-7-30 02:59

我出这道题的初衷是希望写出代码之后可以作为一个实用的加密文本的工具，然后再由自己写解密工具，这是挺好的一件事情。
维热纳尔的加密意义不仅在于加密一个单词或一句英文，而是即使加密很长的一段文章也不会被频率破解。

既然是这样，那batman兄的代码也是不通用了，因为一个文本内容的长度问题。。。而密匙的长度就只有那几位，乘以10也不能保证多于明文的长度。

当然如果作为一个工具来讲，要想加密正确，要保证明文中只有字母，空格也不得包括。

作者: batman 时间: 2008-7-30 08:07

原帖由 pusofalse 于 2008-7-30 02:59 发表
我出这道题的初衷是希望写出代码之后可以作为一个实用的加密文本的工具，然后再由自己写解密工具，这是挺好的一件事情。
维热纳尔的加密意义不仅在于加密一个单词或一句英文，而是即使加密很长的一段文章也不会被频 ...

确实是没考虑周全，要通用也容易，只要按生成方阵的办法来循环密文就可以了，已修改于上。

作者: pusofalse 时间: 2008-7-30 08:52

set "pss=%pss:~1%%a2%"
高！

作者: batman 时间: 2008-7-30 12:02

解密程序：

@echo off&setlocal enabledelayedexpansion
rem 生成方阵
set "codes=a b c d e f g h i j k l m n o p q r s t u v w x y z"
set "code=%codes: =%"
for %%i in (%codes%) do set /a n+=1&set "_!n!=%%i"
set "_a=%code%"
for /l %%i in (1,1,25) do (
    set "code=!code:~1!!code:~,1!"
    set  "_!code:~,1!=!code!"
)
echo.&set /p str=请输入密文:
echo.&set /p pss=请输入密匙:
echo.&set /p=解密的明文:<nul
:again
set "a1=%str:~,1%"&set "a2=%pss:~,1%"
set "str=%str:~1%"&set "pss=%pss:~1%%a2%"
set "var=!_%a2%!"&set "n=0"&call :lp
if defined str goto again
pause>nul&goto :eof
:lp
set "a=%var:~,1%"&set /a n+=1
if /i "%a%" equ "%a1%" set /p=!_%n%!<nul&goto :eof
set "var=%var:~1%"
goto lp
复制代码

[attach]1236[/attach]

[ 本帖最后由 Batcher 于 2009-5-1 20:57 编辑 ]

作者: 都市浪子666 时间: 2008-8-3 19:52

厉害呀，我看都看不起懂

作者: lygwdyanzi 时间: 2008-8-22 20:46

到底是什么跟什么啊，一头雾水

作者: mkl 时间: 2008-8-23 13:54

将方阵从右向左用

@echo off&setlocal enabledelayedexpansion
echo 1、加密  2、解密
set /p bs=
set var=1
for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
    set ve=%%i
    set "%%i=!var!" 
	set "!var!=!ve!" 
	set /a var=!var!+1
)
goto %bs%
:1
set /p vaa=请输入明文 ：
goto ss
:2
set /p vaa=请输入密文 ：
:ss
set /p vab=请输入密钥 ：
:st
set va1=%vaa:~0,1% &set vaa=%vaa:~1%
set va2=%vab:~0,1% &set vab=%vab:~1%%vab:~0,1%
goto %bs%%bs%
:11
set /a vav=%va2%+%va1%
if %vav% gtr 26 set /a vav=%vav%-26
goto js
:22
set /a vav=%va1%-%va2%
if %vav% lss 1 set /a vav=%vav%+26
:js
set /p=!%vav%!<nul
if not "%vaa%"=="" goto st 
pause >nul
复制代码

虽然有些地方和batman相似但绝非抄袭

[ 本帖最后由 mkl 于 2008-8-23 13:57 编辑 ]

作者: pusofalse 时间: 2008-8-23 14:03 标题: 回复 10楼的帖子

测试如下

1、加密  2、解密
1
请输入明文 ：bbsbathome
请输入密钥 ：batch
dcmeiviipm
复制代码

而正确结果应该是

请输入密匙:batch
加密明文：bbsbathome
C B L D H U H H O L
复制代码

作者: dishuo 时间: 2008-8-23 14:06

另一种思路,不生成方阵,只计算索引数,加解密支持空格.
密匙:key with space
文本:this is a simple test this is a simple test this is a simple test
模式(1.加密[默认] 2.解密):1
结果:DMGSWRLHASHJPUWJYTAAMHT YTCNCEZ ORFXLXPUHXDERHEATQSSQAVNXUJEWBY T
请按任意键继续. . .
密匙:key with space
文本:DMGSWRLHASHJPUWJYTAAMHT YTCNCEZ ORFXLXPUHXDERHEATQSSQAVNXUJEWBY T
模式(1.加密[默认] 2.解密):2
结果:THIS IS A SIMPLE TEST THIS IS A SIMPLE TEST THIS IS A SIMPLE TEST
请按任意键继续. . .

cls&@echo off&SETLOCAL ENABLEDELAYEDEXPANSION
set "str=. ABCDEFGHIJKLMNOPQRSTUVWXYZ" & set sMAX=27
:main
set/p keystring=密匙:
set/p string=文本:
set/p mode=模式(1.加密[默认] 2.解密):
set/p=结果:<nul
set mode=%mode%1
set mode=%mode:~0,1%
call :getkeyword
set/a i=0,l=1
:loop
call :index !string:~%i%,1!
if %mode% equ 2 (
 set/a idx=index+sMAX-offset%l%
) else (
 set/a idx=index+offset%l%
)
if %idx% gtr %sMAX% set/a idx%%=sMAX
set/p=!str:~%idx%,1!<nul
set/a i+=1,l= l %% keylength + 1
if not "!string:~%i%,1!"=="" goto:loop
echo.&pause&goto:main
:getkeyword
set i=0
:lp
if "!keystring:~%i%,1!"=="" goto:eof
call :index !keystring:~%i%,1!
set/a i+=1
set/a offset!i!=%index%-1,keylength=i
goto:lp
:index
set index=1
if "%1"=="" goto:eof
for %%a in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do if %1 geq %%a set/a index+=1
复制代码

[ 本帖最后由 dishuo 于 2008-8-23 15:35 编辑 ]

作者: pusofalse 时间: 2008-8-23 15:03

如果从右向左，那就不是维热纳尔了。
你的结果可以理解为在用维热纳尔加密之后再向右移一位。
与凯撒移位相结合，虽然又牢固了一些，但看题目，只使用维热纳尔方针加密而已。

作者: mkl 时间: 2008-8-23 15:19

OMG审题错误真是粗心，不过也巧，怎么就变成什么凯撒移位相了，嘿嘿！

作者: mkl 时间: 2008-8-23 15:32

不过
将 set /a vav=%va2%+%va1% 改成 set /a vav=%va2%+%va1%-1
将 set /a vav=%va1%-%va2% 改成 set /a vav=%va1%-%va2% +1
不就符合要求了吗

@echo off&setlocal enabledelayedexpansion
echo 1、加密  2、解密
set /p bs=
set var=1
for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
set ve=%%i &set "%%i=!var!" &set "!var!=!ve!" 
set /a var=!var!+1)
goto %bs%
:1
set /p vaa=请输入明文 ：
goto ss
:2
set /p vaa=请输入密文 ：
:ss
set /p vab=请输入密钥 ：
:st
set va1=%vaa:~0,1% &set vaa=%vaa:~1%
set va2=%vab:~0,1% &set vab=%vab:~1%%vab:~0,1%
goto %bs%%bs%
:11
set /a vav=%va2%+%va1%-1
if %vav% gtr 26 set /a vav=%vav%-26
goto js
:22
set /a vav=%va1%-%va2%+1
if %vav% lss 1 set /a vav=%vav%+26
:js
set /p=!%vav%!<nul
if not "%vaa%"=="" goto st 
pause >nul
复制代码

[ 本帖最后由 mkl 于 2008-8-23 15:44 编辑 ]

作者: lhjoanna 时间: 2008-11-19 01:11

方法:把26位字母与1-26相应的数字对应起来，密文即为明文字母对应的数字与密钥字母对应的数字相加-1所对应的字母。

@echo off&setlocal enabledelayedexpansion
set "code=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z"
for %%i in (%code%) do (
    set /a num+=1
    set t!num!=%%i
    set p%%i=!num!
)
:begin
set /p text=请输入明文:&set /p key=请输入密钥:&set /p=密文:<nul
:loop
set "_text=%text:~,1%"&set "_key=%key:~,1%"
set "text=%text:~1%"&set "key=%key:~1%%_key%"
set /a n=!p%_text%!+!p%_key%!
set /a n=!n!%%26-1
set /p=!t%n%! <nul
if defined text goto loop 
echo.&echo.&goto begin
复制代码

set "key=%key:~1%%_key%"一句借鉴了batman的，感觉好多种方法这种最简洁。

哦，好像和上楼的思想一样啊，不好意思啊，发表以后才仔细看。把标头去了！
复制代码

[ 本帖最后由 lhjoanna 于 2008-11-19 01:24 编辑 ]

作者: hkmhd 时间: 2009-5-13 13:16

翻了一个不得了的帖子出来, 有很多东西可以学

作者: 随风 时间: 2009-5-13 14:45

@echo off&setlocal enabledelayedexpansion
set "x=ABCDEFGHIJKLMNOPQRSTUVWXYZ"&set code=!x!&set "miwen="
for /l %%a in (1 1 26) do (
   set /a .!x:~0,1!=%%a
   set code2=!code2! !x:~0,1!
   set "x=!x:~1!"
)
set /p my=请输入密匙 
set /p mw=请输入明文 
for %%a in (!code2!) do set mw=!mw:%%a= %%a !
for %%a in (!mw!) do (
   if not defined my_ set "my_=!my!"
   set /a yum=.!my_:~0,1!,w=.%%a-1
   for %%i in (!yum!) do set "codex=!my_:~0,1!!code:~%%i!!code:~0,%%i!"
   for %%i in (!w!) do set "miwen=!miwen!!codex:~%%i,1!"
   set "my_=!my_:~1!"
)
echo 密文:  !miwen!
pause
复制代码

作者: netbenton 时间: 2009-5-13 19:47

 
@echo off&setlocal enabledelayedexpansion
set x=ABCDEFGHIJKLMNOPQRSTUVWXYZ
set miwen=&set yum=miwen
for /l %%a in (0 1 25) do (
   set /a n=%%a+1,#!x:~%%a,1!=n
   set #!n!=!x:~%%a,1!
)
set /p my=请输入密匙 
set /p mw=请输入明文 
set m=0
:lp
set/a mm=m+99
for /l %%a in (!m!,1,!mm!) do (
 for %%b in (!yum!) do (
  set miwen=!miwen!!#%%b!
  if "!mw:~%%a!" equ "" goto :ok
  set /a "yum=(#!my:~0,1!+#!mw:~%%a,1!+24)%%26+1",m=%%a+1
  set my=!my:~1!!my:~0,1!
 )
)
goto :lp
:ok
echo 密文:  !miwen!
pause
复制代码

[ 本帖最后由 netbenton 于 2009-5-14 12:54 编辑 ]

作者: woshixuso1 时间: 2012-6-7 11:21

我来学习下

作者: woshixuso1 时间: 2012-6-8 13:20

为什么不能加解密带数字的字符串啊

作者: 狱渊 时间: 2013-5-1 11:17

我彻底晕了明文密钥是做什么的？

作者: CrLf 时间: 2013-5-1 19:27

回复 22# 狱渊

解密算法是动态的，有“无限种”可能
密钥能确定其中的一种，并以此推算出明文

作者: 906053584 时间: 2015-8-29 21:18

话说怎么把加密好的密文输出到比如c：\123.txt

作者: salad 时间: 2018-2-27 19:10

回复 1# pusofalse
看看我这行吗

欢迎光临批处理之家 (http://bbs.bathome.net/)