批处理之家 - Powered by Discuz! Board

标题: [文件操作] [已解决]批处理如何可以历遍根目录下所有文件并改名？ [打印本页]

作者: playinthesky 时间: 2011-6-30 20:39 标题: [已解决]批处理如何可以历遍根目录下所有文件并改名？

本帖最后由 playinthesky 于 2011-6-30 22:01 编辑

@echo off&setlocal enabledelayedexpansion 
for /f %%x in (‘dir/b/a-d/s”*.txt"’) do ( 
set "temp=%%x" 
set temp=!temp: =[! 
ren "%%x" "!temp!"
)
复制代码

想将有空格的文件名替换成带 “{”符号的文件名，写了代码却总是不对，如果去除历遍 dir/b/a-d/s 就是可以使用的，各位高手是否能给我指正？谢谢大家。

作者: batman 时间: 2011-6-30 20:53

本帖最后由 batman 于 2011-6-30 21:10 编辑

@echo off&setlocal enabledelayedexpansion
for /r %%a in (*.txt) do (
  set "str=%%~nxa"
  ren "%%a" "!str: ={!"
)   
复制代码

作者: tmplinshi 时间: 2011-6-30 20:54

错误 1：dir 的参数不能和文件名连在一起。
错误 2：你使用了两个全角单引号、一个全角双引号。应该使用半角的符号。
错误 3：少了 "delims=" 或 "tokens=*"。
错误 4：重命名时，新的文件名不能包含路径。
潜在的错误：路径中含有半角感叹号时，重命名会出错。

作者: tmplinshi 时间: 2011-6-30 20:54

本帖最后由 tmplinshi 于 2011-6-30 21:05 编辑

@echo off
for /f "delims=" %%i in (' dir /a:-d /b /s "* *.txt" ') do (
    set file=%%i
    set fname=%%~nxi
    setlocal enabledelayedexpansion
    ren "!file!" "!fname: =[!"
    endlocal
)
复制代码

作者: playinthesky 时间: 2011-6-30 22:01

谢谢两位版主的指点！！

欢迎光临批处理之家 (http://bbs.bathome.net/)