批处理之家 - Powered by Discuz! Board

标题: [已解决]最简单的倒记时批处理怎么写？ [打印本页]

作者: qq544935474 时间: 2011-7-13 03:43 标题: [已解决]最简单的倒记时批处理怎么写？

像倒记时那样走，速度和电脑的秒一样

作者: bluewing009 时间: 2011-7-13 09:06

@echo off
for /l %%i in (10,-1,0) do (
    ping 127.0.0.1 -n 1 >nul
    echo %%i
)
pause
复制代码

延时是通过 ping 的 -n 来修改

作者: wolonga123 时间: 2011-7-13 09:08

@echo off
for /l %%i in (10 -1 0) do ping 192.168.0.2>nul 2>nul&echo %%i
复制代码

参考http://www.bathome.net/thread-2494-1-1.html

作者: qq544935474 时间: 2011-7-13 09:18

大家都误会了

作者: Batcher 时间: 2011-7-13 10:59

4# qq544935474

请你在顶楼澄清一下吧

作者: ArdentMan 时间: 2011-7-13 11:45

本帖最后由 ArdentMan 于 2011-7-13 12:41 编辑

@Echo Off&SetLocal EnableDelayedExpansion
Rem 两小时倒计时
For /L %%i In (1,1,50) Do Set "tg=!tg! "
Set /A h=%Time:~,2%+2,m=%Time:~3,2%,s=%Time:~6,2%
If %h% GEQ 24 Set /A h-=24
:Lp
Set /A hto=h-%Time:~,2%,mto=(1%m%%%100)-(1%Time:~3,2%%%100),sto=(1%s%%%100)-(1%Time:~6,2%%%100)
If %sto% lEQ 0 set /A sto+=60,mto-=1
if %mto% lEQ 0 set /A mto+=60,hto-=1
If %hto% LSS 0 Set /A hto+=24
Set /P=当前距%h%:%m%:%s%还有%hto%小时%mto%分%sto%秒<Nul
For /L %%i In (1,1,2000) Do Ver>Nul
Set /P=%tg%<Nul
If "%hto%%mto%%sto%" Neq "000" Goto Lp
Cls&Echo 时间到
Pause>Nul
复制代码

作者: qq544935474 时间: 2011-7-14 08:34

@Echo Off&SetLocal EnableDelayedExpansion
Rem 两小时倒计时
For /L %%i In (1,1,50) Do Set "tg=!tg! "
Set /A h=%Time:~,2%+2,m=%Time:~3,2%,s=%Time:~6,2%
If %h% GEQ 24 Set /A h-=24
p
Set /A ht ...
ArdentMan 发表于 2011-7-13 11:45

正确答案

作者: batman 时间: 2011-7-14 09:01

这已经不是最简单的倒计时了，记得win7好像有choice.exe吧
下面是以前写的：

@echo off
set "n=100"
:begin
cls&echo 请输入任意字母退出,否则%n%秒后程序将启动，计时：%n%秒
choice /c 1abcdefghijklmnopqrstuvwxyz /d 1 /t 1 /n
if %errorlevel% neq 1 goto :eof
set /a n-=1
if %n% neq 0 (goto begin) else (goto next)
:next
cls&echo 程序已启动&pause>nul
复制代码

作者: CrLf 时间: 2011-7-14 15:30

外部命令的启动耗时一旦进入循环，将累积导致计时结果出较大地偏差...
如果是在 win7 下，倒计时还是用 timeout 最好：

timeout /t 10
rem 十秒倒计时
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)