批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理findstr命令多文本数据检索时如何不显示文件名？ [打印本页]

作者: ftjm268 时间: 2011-7-19 14:21 标题: [已解决]批处理findstr命令多文本数据检索时如何不显示文件名？

假设有3个文本文件，分别为：a1.txt ; a2.txt ; a3.txt
a1.txt 里面的数据是：
1
1

a2.txt里面的数据是：
1
2

a3.txt里面的数据是：
1
3

用findstr "1" a*.txt > b.txt，得到的结果是：
a1.txt:1
a1.txt:1
a2.txt:1
a3.txt:1
它把所有文件面都自动添加到每一行的行首了，我只想要：
1
1
1
1
这样的结果，用for命令说啥也试不出来，请教各位DX，帮帮忙吧。

作者: tmplinshi 时间: 2011-7-19 14:25

type a*.txt | findstr "1"
复制代码

作者: ftjm268 时间: 2011-7-19 15:03

type a*.txt | findstr "1"
tmplinshi 发表于 2011-7-19 14:25

非常感谢，这么简单的一句话就搞定了

再继续问一下，能否返回查询行数，这个例子返回数值4。

再次感谢

作者: CrLf 时间: 2011-7-19 15:43

本帖最后由 zm900612 于 2011-7-19 15:45 编辑

3# ftjm268

type a*.txt |findstr /v "a.*\.txt"|find /c "1"
复制代码

作者: tmplinshi 时间: 2011-7-19 16:08

本帖最后由 tmplinshi 于 2011-7-19 16:14 编辑

3# ftjm268

type a*.txt 2>nul | find /c "1" >b.txt
复制代码

2>nul 可要可不要，不会影响结果，不加 2>nul 的话文件名会显示在 cmd 窗口。

作者: tmplinshi 时间: 2011-7-19 16:11

3# ftjm268 type a*.txt |findstr /v "a.*\.txt"|find /c "1"
zm900612 发表于 2011-7-19 15:43

type 输出的文件名，是输出到了 standard error。

作者: CrLf 时间: 2011-7-19 16:16

6# tmplinshi

这倒没注意，好技巧！

作者: ftjm268 时间: 2011-7-19 16:22

可能我没说明白，我是想搜索一下三个文本里面的“1”的数量，然后把结果赋值给一个变量

作者: cjiabing 时间: 2011-7-19 16:26

@echo off
set nb=0
for /f "tokens=1,*" %%a in ('find "1" *.txt') do if not %%a==---------- echo %%a %%b&&set /a nb+=1
echo 总共：%nb%
pause
复制代码

作者: ftjm268 时间: 2011-7-19 16:40

shi兄给我的第一个答案，我在测试文件上成功了，但用到真实数据上错了，

真实数据里的查询条件类似：382 -VB814266

条件中有空格，如果用：type 110715*.txt|findstr "382 -VB814266" > sum.txt

则会将以110715开头的文本文件中所有不包括382 -VB814266的数据汇总到sum.txt里，我发誓没用/V开关。

作者: tmplinshi 时间: 2011-7-19 17:15

本帖最后由 tmplinshi 于 2011-7-19 17:29 编辑

因为 findstr "382 -VB814266" 查找的是两个关键词 "382" 和 "-VB814266"。

@echo off
set str="1"
set file="110715*.txt"
type %file% 2>nul | findstr /c:%str% >sum.txt
for /f %%a in (' "type %file% 2>nul | find /c %str%" ') do set n=%%a
echo %n%
pause
复制代码

作者: ArdentMan 时间: 2011-7-19 19:09

@Echo Off
For /F %%a In ('Findstr /c:"382 -VB814266" 110715*.txt') Do Set /A Count+=1
Echo %Count%
Pause>Nul
复制代码

作者: ftjm268 时间: 2011-7-20 12:00

因为 findstr "382 -VB814266" 查找的是两个关键词 "382" 和 "-VB814266"。@echo off
set str="1"
set file="110715*.txt"
type %file% 2>nul | findstr /c:%str% >sum.txt
for /f %%a in (' "type %file% 2>nul ...
tmplinshi 发表于 2011-7-19 17:15

shi兄，这段代码还是不行，返回的数据总数是0,

实在不好意思，这两天非常忙，没有时间分析各位老师给的代码，一有时间我一定认真学习大家给我的代码，并且一定会让这个帖子有始有终

再次感谢大家对我的帮助

作者: tmplinshi 时间: 2011-7-20 12:24

@echo off
set str="382 -VB814266"
set file="110715*.txt"
type %file% 2>nul | findstr /c:%str% >sum.txt
for /f %%a in (' "type %file% 2>nul | find /c %str%" ') do set n=%%a
echo %n%
pause

是不是你忘记修改红色部分了？

作者: ftjm268 时间: 2011-7-20 13:21

是不是你忘记修改红色部分了？
tmplinshi 发表于 2011-7-20 12:24

我修改了变量但返回仍然是0，我把数据源的截屏发上来了，这是我修改了参数的您的代码：
:

echo off
u:
cd MTN\OPSDATA_BKUP
set str="382 -v143788"
set file="200718*.txt"
type %file% 2>nul | findstr /c:%str% >sum.txt
for /f %%a in (' "type %file% 2>nul | find /c %str%" ') do set n=%%a
echo %n%
pause

N=0

原来如果是指定文件名，用findstr检索有空格的订单号就可以，现在即便指定文件名是200718_0844.txt也检索不到数据了

请问，这个2>nul是啥意思？

谢谢shi兄。

作者: ftjm268 时间: 2011-7-20 13:24

本帖最后由 ftjm268 于 2011-7-20 13:26 编辑

发了图，没想到压缩到这么模糊，我还是用文字说明吧
文件名：200718_0844.txt这个文件有382 -v143788这个订单，但即便用：
findstr "382 -v143788" 200718_0844.txt > sum.txt 或者：
findstr /c:"382 -v143788" 200718_0844.txt > sum.txt都检索不到数据

作者: cjiabing 时间: 2011-7-20 13:31

16# ftjm268
如果你不介意的话，你发一小段你的文件内容上来分析，当然，为防止泄密，你可以修改一下，将其他一些无用的内容替换。
这应该是最快的方法，免得你说不清楚我们也搞不懂。

作者: ftjm268 时间: 2011-7-20 15:57

16# ftjm268
如果你不介意的话，你发一小段你的文件内容上来分析，当然，为防止泄密，你可以修改一下，将其他一些无用的内容替换。
这应该是最快的方法，免得你说不清楚我们也搞不懂。
cjiabing 发表于 2011-7-20 13:31

SQ023F|3|U|107 -D1028343|000057|000|X5|X|||802|P02|050|PSHD-999 +|A||20110715|000
SQ023A|3|A|382 -V143788||000|||10||1184||20110715|20110715|0000000||946179|V143788|20110715||E|OT||||AF|Y|F27|20110916|005|2|X||382|030|060|030||000|000|000||000|000|000||000|000|000|000|N|0|1|2|B|V143788||20110715|000

好的，我就发两行吧，有个案例就好，我要第二行订单号是：382 -V143788的整行数据。

作者: tmplinshi 时间: 2011-7-20 16:05

加上 /i 参数忽略大小写：

:echo off
u:
cd MTN\OPSDATA_BKUP
set str="382 -v143788"
set file="200718*.txt"
type %file% 2>nul | findstr /i /c:%str% >sum.txt
for /f %%a in (' "type %file% 2>nul | find /i /c %str%" ') do set n=%%a
echo %n%
pause

N=0

-------------------

2>nul 是用来屏蔽错误输出。

作者: ftjm268 时间: 2011-7-20 16:15

加上 /i 参数忽略大小写：

-------------------

2>nul 是用来屏蔽错误输出。
tmplinshi 发表于 2011-7-20 16:05

可以了，谢谢shi兄指教

作者: Hello123World 时间: 2011-7-21 17:03

@echo off
(For /f "tokens=2 delims=:" %%i in ('findstr "1" a*.txt ') do Echo %%i)>b.txt
pause
复制代码

作者: q115643492 时间: 2011-7-22 11:10

19# tmplinshi
type %file% 2>nul | findstr /i /c:%str% >sum.txt
for /f %%a in (' "type %file% 2>nul | find /i /c %str%" ') do set n=%%a
本人新手，在学习中。有点不明白。为什么用了findstr还要用find呢？还有，findstr是不是不能用在for里？

作者: CUer 时间: 2011-7-22 13:04

22# q115643492

追求高效率。
能放在for循环，但是通常会降低效率。

作者: tmplinshi 时间: 2011-7-22 13:45

本帖最后由 tmplinshi 于 2011-7-22 13:48 编辑

19# tmplinshi
type %file% 2>nul | findstr /i /c:%str% >sum.txt
for /f %%a in (' "type %file% 2>nul | find /i /c %str%" ') do set n=%%a
本人新手，在学习中。有点不明白。为什么用了findstr还要用find呢 ...
q115643492 发表于 2011-7-22 11:10

为了代码更简短、易读。
可以像 9 楼一样只用一个 find。

欢迎光临批处理之家 (http://bbs.bathome.net/)