批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理如何在文件中的字符串里面加一空格？ [打印本页]

作者: 1130342432 时间: 2011-7-29 08:13 标题: 批处理如何在文件中的字符串里面加一空格？

现有一文本文件1.txt，内容为abcdefghijklmnopqrstuvwxyz,如何编写批处理使输出
a b c d e f g h i j k l m n o p q r s t u v w x y z？

作者: CrLf 时间: 2011-7-29 09:21

只有单字节字符的文本可以这样：

@echo off&setlocal enabledelayedexpansion
set n=1
for /f "tokens=1* delims=:" %%a in ('
   "cmd /u /c type 1.txt|more|findstr /n ."
') do (
   if %%a neq !n! (
      echo;!str:~1!
      for /l %%b in (!n! 9 %%a) do if %%b neq !n! echo;
      set str=
   )
   set /a n=%%a+1
   set str=!str! %%b
)
echo;!str:~1!
pause
复制代码

作者: 1130342432 时间: 2011-7-29 09:48

good
good
good
good

作者: CUer 时间: 2011-7-29 10:42

sed "s/./& /g" a.txt
复制代码

作者: CUer 时间: 2011-7-30 10:51

gawk -F "" "$1=$1" a.txt
复制代码

作者: cjiabing 时间: 2011-7-30 11:34

@echo off&setlocal enabledelayedexpansion
for /f "tokens=*" %%a in ("abcdefghijklmnopqrstuvwxyz") do (
set var=%%a
for /l %%i in (0,1,100000) do if not "!var:~%%i,1!"=="" set /p=!var:~%%i,1! <nul
)
pause>nul
复制代码

作者: Hello123World 时间: 2011-7-31 13:51

@echo off&SetLocal EnableDelayedExpansion
Set n=0
Set c=
For /f %%i in (1.txt) do Call :hello %%i
pause >nul & exit
:hello
Set a=%1
Set b=!a:~%n%,1!
if not "!b!"=="" Set /p c=%c% %b%<nul 
Set /a n+=1
if not "!b!"=="" goto hello
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)