批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理如何整理SYN扫描的结果？ [打印本页]

作者: cloud213 时间: 2011-9-4 12:02 标题: [已解决]批处理如何整理SYN扫描的结果？

本帖最后由 cloud213 于 2011-9-5 10:21 编辑

首先这是一个SYN 端口扫描批处理.他扫描的端口是3个.然后生成一个Result.txt 的文本 .

代码如下:

@echo off
setlocal
cls
color A

del ips.txt
del Result.txt
for /f "eol= tokens=1,2 delims= " %%i in (1.txt) do s syn %%i %%j 135,1433,3389 /save
复制代码

这是用S扫描器扫描，之后会生成一个Result.txt 的文本

我希望最好能在这段代码的基础上增加处理代码.
让最后只留下IP：并去掉重复IP：再将IP分类保存成3个为端口号命名的文档.
最好能按1-255的顺序排列出来..

Result.txt 的文本 .格式如下.

-------------------------------------------------------------------------------
Performing Time: 12/20/2008 21:39:10 --> SYN Scan: About To Scan 16384 IP For 5 Ports Using 1 Thread
202.96.219.14 135 Open
202.96.219.21 135  Open
202.96.246.22 135  Open
202.96.246.22 1433 Open
202.96.246.22 1433  Open
202.100.24.22 1433  Open
202.96.246.22 3389  Open
202.96.246.194 3389  Open
Scan 16384 IPs Complete In 0 Hours 0 Minutes 4 Seconds. Found 8 Hosts
-------------------------------------------------------------------------------
-------------------------------------------------------------------------------

处理最后想要达到的效果，

202.96.219.14
202.96.219.21
202.96.246.22

这几个135端口的分类保存到135.txt下..去掉重复的IP..并按1-255的顺序排列.

202.96.246.22
202.96.246.22
202.100.24.22

这几个1433端口的分类保存到1433.txt下..去掉重复的IP..并按1-255的顺序排列.

202.96.246.22
202.96.246.194

这几个3389端口的分类保存到3389.txt下..去掉重复的IP..并按1-255的顺序排列.

作者: ArdentMan 时间: 2011-9-4 13:13

@echo Off&SetLocal EnableDelayedExpansion
For /F "tokens=1,2" %%a In ('Findstr "Open" result.txt') Do (
  For /F "tokens=1-4 delims=." %%i In ("%%a") Do (
    Set "stra=000%%i"&Set "strb=000"%%j&Set "strc==000%%k"&Set "strd=000%%l"
    Set "_%%b_!stra:~-3!.!strb:~-3!.!strc:~-3!.!strd:~-3!=%%i.%%j.%%k.%%L"
  )
)
For /F "tokens=1,3 delims==_" %%i In ('Set _') Do Echo %%j>>%%i.txt
复制代码

作者: cloud213 时间: 2011-9-4 13:38

本帖最后由 cloud213 于 2011-9-4 13:42 编辑

这段代码加在最后面吗???

还是直接就用这段代码就行了??

作者: ArdentMan 时间: 2011-9-4 13:43

@Echo Off&SetLocal EnableDelayedExpansion
Del Result.txt 2>Nul
for /f "eol= tokens=1,2 delims= " %%i in (1.txt) do s syn %%i %%j 135,1433,3389 /save
For /F "tokens=1,2" %%a In ('Findstr "Open" result.txt') Do (
  For /F "tokens=1-4 delims=." %%i In ("%%a") Do (
    Set "stra=000%%i"&Set "strb=000"%%j&Set "strc==000%%k"&Set "strd=000%%l"
    Set "_%%b_!stra:~-3!.!strb:~-3!.!strc:~-3!.!strd:~-3!=%%i.%%j.%%k.%%L"
  )
)
For /F "tokens=1,3 delims==_" %%i In ('Set _') Do Echo %%j>>%%i.txt
复制代码

作者: cloud213 时间: 2011-9-4 14:09

本帖最后由 cloud213 于 2011-9-4 14:12 编辑

怎么好像扫描速度很慢呢??

能不能把速度提高点呢?

而且扫出的最后保存结果是.

86.5.52.%L 后面的数字变成.%L了

作者: ArdentMan 时间: 2011-9-4 19:10

手机上网写不了什么代码，看了一下应该是set “strc==000%%k”这里多了个=号，至于扫描的速度与代码无关吧。

作者: cloud213 时间: 2011-9-4 20:21

嗯. 谢谢了呢.

还有那个排序. 好像不是按数字的大小来排列. 排的有点乱..

作者: wc726842270 时间: 2011-9-4 20:46

LZ有兴趣用SORT改一下吧

作者: ArdentMan 时间: 2011-9-5 09:16

还是粗心了

@Echo Off&SetLocal EnableDelayedExpansion
Del Result.txt 2>Nul
for /f "eol= tokens=1,2 delims= " %%i in (1.txt) do s syn %%i %%j 135,1433,3389 /save
For /F "tokens=1,2" %%a In ('Findstr "Open" result.txt') Do (
  For /F "tokens=1-4 delims=." %%i In ("%%a") Do (
    Set "stra=000%%i"&Set "strb=000"%%j&Set "strc=000%%k"&Set "strd=000%%l"
    Set "_%%b_!stra:~-3!.!strb:~-3!.!strc:~-3!.!strd:~-3!=%%i.%%j.%%k.%%l"
  )
)
For /F "tokens=1,3 delims==_" %%i In ('Set _') Do Echo %%j>>%%i.txt
复制代码

作者: cloud213 时间: 2011-9-5 10:21

3Q了. 就是这样.

非常感谢.!!

欢迎光临批处理之家 (http://bbs.bathome.net/)