批处理之家 - Powered by Discuz! Board

标题: [文本处理] 请教：批处理替换文本内容为何出错？ [打印本页]

作者: stu_p 时间: 2011-9-24 22:18 标题: 请教：批处理替换文本内容为何出错？

想把d:\222.txt中的11替换为6，但下面这个批文件会在空行处输出11=6
这个批文件是参考的论坛中高手们写的批文件，稍微改动了一下,不知错在哪？
222.txt内容如下：

6666 111 3!
;<<< ...%%% % | |||

ijklmnab
mmmm!
!s!
批文件：

@echo off
for /f "delims=" %%i in ('findstr /n .* d:\222.txt') do (
        set "var=%%i"
        setlocal enabledelayedexpansion
        set var=!var:*:=!
        set var=!var:11=6!
        echo.!var!>>output.txt
        endlocal
)
复制代码

执行批后output.txt的结果：
11=6
6666 61 3!
;<<< ...%%% % | |||
11=6
ijklmnab
mmmm!
!s!

作者: hankerer 时间: 2011-9-24 22:59

看一下

findstr /n .* d:\222.txt
复制代码

跟

findstr /n . d:\222.txt
复制代码

的区别应该有用

作者: weichenxiehou 时间: 2011-9-25 01:27

@echo off
(for /f "delims=" %%i in ('findstr /n .* d:\222.txt') do (
        set "var=%%i"
        setlocal enabledelayedexpansion
        set var=!var:*:=!
        if defined var set "var=!var:11=6!"
        echo.!var!
        endlocal
))>output.txt
复制代码

作者: stu_p 时间: 2011-9-25 08:39

weichenxiehou 发表于 2011-9-25 01:27

这个批能成功，谢谢！
不过不明白(for.....)的用法~我在do后（）内加了pause也没出现提示，这种写法能否解释下？

作者: Batcher 时间: 2011-9-25 09:30

回复 4# stu_p

把>output.txt删掉，再加pause试试。

作者: stu_p 时间: 2011-9-25 10:05

回复 stu_p

把>output.txt删掉，再加pause试试。
Batcher 发表于 2011-9-25 09:30

这样可以了，能否解释一下？不太理解～谢谢。

作者: weichenxiehou 时间: 2011-9-25 11:10

(for ...)>output.txt就是将for这个语句块的所有标准输出重定向到output.txt，所以你在屏幕上看不到内容，删除过后，默认数据流是流向con(屏幕)，所以你又看到啦……

作者: Batcher 时间: 2011-9-25 13:25

回复 6# stu_p

批处理中的重定向符号以及句柄的使用方法和讲解
http://bbs.bathome.net/thread-3296-1-1.html

欢迎光临批处理之家 (http://bbs.bathome.net/)