批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理怎样复制少于指定行数的文件？ [打印本页]

作者: jgyc123 时间: 2011-11-6 15:06 标题: 批处理怎样复制少于指定行数的文件？

A件夹里有N个文本，怎么样把少于100行的文本，全部复制到B文件夹里？

100行只是举例，希望这个数字能够手动输入。（因为每次都要筛选不同行数的文本）

在批处理中判断行，是不是以回车键为依据？

大侠们，帮帮我吧。

作者: yyykkkyyyy 时间: 2011-11-6 17:24

本帖最后由 yyykkkyyyy 于 2011-11-6 17:26 编辑

这个不算难,就不用高手来回答吧
在批处理中判断行是以回车为依据
假如文件夹　Ａ　Ｂ在同级位置，则把批处理文件也放于此，不然两文件夹名（改代码第2、３行等号后）都要带全路径

@echo off
set da=A
set db=B
set/a n=100
if not exist "%db%" md "%db%"
for /f "delims=" %%a in ('dir/b/a-d %da%\')do (
    more +%n% "%da%\%%a"|find/v "">nul||(
    echo %%a&set/a m+=1
    copy "%da%\%%a" "%db%\">nul))
if defined m (echo 已复制 %m% 个文件)else echo 没发现满足条件的文件
pause
复制代码

作者: sxw 时间: 2011-11-6 17:52

版主会打你的，标题不行啊

作者: FOR 时间: 2011-11-6 20:47

@echo off
set n=100
for /f "tokens=2,3 delims=: " %%i in ('find /c /v "" *.txt') do (
	if %%j lss %n% copy "%%i" "b"
)
pause
复制代码

作者: terse 时间: 2011-11-6 21:17

@echo off&setlocal enabledelayedexpansion
set mun=100
for /f "tokens=1,2 delims=:" %%i in ('find /v /c "" *.TXT') do (
    if %%j lss %mun% (
       set str=%%i
       >nul 2>nul copy "!str:* =!" "b\" 
    )
)
PAUSE
复制代码

作者: jgyc123 时间: 2011-11-6 21:24

谢谢，大家，能不能改成，请输入行数：，然后手动输入100，回车再运行啊？麻烦了。谢谢

作者: awk 时间: 2011-11-6 21:28

回复 6# jgyc123

@echo off
set /p n=请输入行数：
for /f "tokens=2,3 delims=: " %%i in ('find /c /v "" *.txt') do (
    if %%j lss %n% copy "%%i" "b"
)
pause
复制代码

作者: CrLf 时间: 2011-11-7 07:04

倾向于 7 楼的解，另外提供一个思路：

@echo off
set /p n=跳过多少行？
for %%a in (*.txt) do (
set copy=1
for /f "skip=%n%" %%b in (%%~sa) do (
if defined copy set copy=
)
if defined copy copy "%%a" "b\"
)
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)