批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理怎样根据文本文件数字递推？ [打印本页]

作者: necnec1 时间: 2012-3-2 15:21 标题: [已解决]批处理怎样根据文本文件数字递推？

AB110103020
AA120210918                         我有一个文本文件AA.TXT 内容如左
AC090302317
BB100402352

注释：    AB 11 01 03020
前面2个大写字母是指定的  11是年  01是月  03020是万位最高到99999

表述起来有些复杂我希望他最终的结果是
AB110100001
AB110100002
AB110103020    一直到3020

AA120200001
AA120200002
AA120210918 一直到10918

然后将这些内容保存到文本文件里去  请会的朋友帮帮忙谢谢

作者: apang 时间: 2012-3-2 16:45

请问楼主，前面2个大写字母是依据什么排序呢？

type aa.txt |sort >bb.txt
复制代码

这样可以吗？

作者: necnec1 时间: 2012-3-2 16:54

回复 2# apang

回复楼上的前面2个大写的字母就按照文本文件里既定的前面来就可以了

作者: QIAOXINGXING 时间: 2012-3-2 17:13

楼主是这意思吗?

@echo off&SetLocal EnableDelayEdexpansion&cd /d "%~dp0"
echo 等一下...........
(for /l  %%i in (1 1 3020 ) do (
  set "n=0000%%i"
  set "n=!n:~-5!"
  echo AB1101!n!
))>1.txt

(for /l  %%i in (1 1 10918) do (
  set "n=0000%%i"
  set "n=!n:~-5!"
  echo AA1202!n!
))>2.txt
pause
复制代码

作者: necnec1 时间: 2012-3-2 17:25

本帖最后由 necnec1 于 2012-3-2 17:28 编辑

回复 4# QIAOXINGXING

回复三楼  你这个只能对指定其中的几类进行排序  不够智能
由于我的文本前2个大写的字母  是指定的并非随机大概有几百个我想要批处理自动读文本找到AB 然后依次递归下去  然后再找到第二个AA 依次递归一直到文本的最后
AB110103020
AA120210918
AC090302317
BB100402352
然后把总的结果写到一个文本里去

作者: QIAOXINGXING 时间: 2012-3-2 17:44

回复 5# necnec1

对于字母相同的行,年和月是不是也是相同的?
对于字母相同的行,后五位数字是不是连续的?
如果都是,那么 2 楼的应该可以吧.

如果第一问是,第二问不是,那么你的意思是:对于字母相同的行,找到后五位数字的最大值,然后从 00001 递增到最大值??
是这意思吗??
我得去上课了....

作者: CrLf 时间: 2012-3-2 17:51

sort /+2 AA.txt>BB.txt
复制代码

作者: necnec1 时间: 2012-3-2 17:59

本帖最后由 necnec1 于 2012-3-2 18:03 编辑

不知道怎么说  我还是举例子把 AB110103020 这个分解一下首先的2个大写字母是指定的不动
11是年份 01是月份  03020是数字  第一位是00001 最大是99999
AB110103020
AA120210918
AC090302317
BB100402352       这是我从文本文件里随便截取的4组总共有好几百组

第一个
AB110103020 总数是3020个

AB110100001
AB110100002
AB110103020 依次类推  一直到3020

AA120210918  总数是10918个

AA120210001
AA120210002
AA120210918  依次类推  一直到10918
然后把所有递归的总的结果写到一个文本里去

不知道这样表述的是否清楚

作者: namejm 时间: 2012-3-2 18:01

代码：

@echo off
setlocal enabledelayedexpansion
(for /f %%i in (test.txt) do (
    set str=%%i
    set endNum=!str:~-5!
    for /l %%j in (100001,1,1!endNum!) do (
        set tmpNum=%%j
        echo !str:~0,6!!tmpNum:~1!
    )
    echo;
))>result.txt
start result.txt
复制代码

作者: necnec1 时间: 2012-3-2 18:07

回复 9# namejm

namejm 版主的批处理做的真好能够满足我的要求谢谢~

欢迎光临批处理之家 (http://bbs.bathome.net/)