批处理之家 - Powered by Discuz! Board

标题: 批处理脚本实现C语言趣味编程百例010：进制转换 [打印本页]

作者: HAT 时间: 2012-3-20 00:06 标题: 批处理脚本实现C语言趣味编程百例010：进制转换

要求用BAT脚本实现：数制转换将任一整数转换为二进制形式

加分：1个技术分或者10个PB

*问题分析与算法设计
将十进制整数转换为二进制的方法很多，这里介绍的实现方法利用了C语言能够对位进行操作的特点。对于C语言来说，一个整数在计算机内就是以二进制的形式存储的，所以没有必要再将一个整数经过一系列的运算转换为二进制形式，只要将整数在内存中的二进制表示输出即可。

*程序说明与注释

#include<stdio.h>
void printb(int,int);
int main()
{
int x;printf("Input number:");
scanf("%d",&x);
printf("number of decimal form:%d\n",x);
printf(" it's binary form:");
printb(x,sizeof(int)*8); /*x:整数 sizeof(int):int型在内存中所占的字节数
sizeof(int)*8:int型对应的位数*/
putchar('\n');
}

void printb(int x,int n)
{
if(n>0)
{
putchar('0'+((unsigned)(x&(1<<(n-1)))>>(n-1))); /*输出第n位*/
printb(x,n-1); /*归调用，输出x的后n-1位*/
}
}
复制代码

*运行结果
输入：8
输出：
number of decimal form:8
it's bunary form:0000000000001000
输入：-8
输出：number of decimal form:-8
it's binary form:1111111111111000
输入：32767
输出：number of decimal form:32767
it's binary form:0111111111111111
输入：-32768
输出：number of decimal form:-32768
it's binary form:1000000000000000
输入：128
输出：number of decimal form:128
it's binary form:0000000010000000

*问题的进一步讨论
充分利用C语言可以对位进行操作的特点，可以编写许多其它高级语言不便于编写甚至根本无法编写的程序。位操作是C语言的一大特点，在深入学习C语言的过程中应力求很好掌握。
程序中使用的位运算方法不是最佳的，也可以不用递归操作，大家可以自行对程序进行优化。

*思考题
将任意正整数转换为四进制或八进制数

作者: defanive 时间: 2012-3-20 04:38

@echo off
set /p dec=Input : 
:loop
if "%dec%"=="0" echo Output : %bin%&pause&exit
set /a "m=dec%%2","dec/=2"
set "bin=%m%%bin%"
goto loop
复制代码

作者: terse 时间: 2012-3-20 12:24

仅能转换正整数到任意进制（64内支持大数转换）

@echo off&setlocal enabledelayedexpansion
set/p S=输入转换数:
set/p H=请输入要转换的几进制?
set "str=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ_@"
:lp
set Ln=&set R=&set "Sn=!s!"
for %%i in (4096 2048 1024 512 256 128 64 32 16)do if "!Sn:~%%i!" NEQ "" set/aLn+=%%i&set Sn=!Sn:~%%i!
set Sn=!Sn!FEDCBA9876543210&set/aLn+=0x!Sn:~16,1!
for /l %%i in (0,1,%Ln%) do (
   set/a "N=!S:~%%i,1!+(R*10),R=N%%H,N/=H"
   set M=!M!!N!
)
   set B=!str:~%r%,1!!B!
   for /f "tokens=* delims=0" %%i in ("0!M!") do set "S=%%i"
   if defined S set M=&goto lp
   echo "!B!"
pause
复制代码

作者: fatcat 时间: 2012-3-20 15:53

@echo off & setlocal enabledelayedexpansion
:next
set /p num=请输入一个整数: 
echo BIN: & (for /l %%b in (31 -1 0) do set /a "b=^!^!(1<<%%b&num)"&<nul set /p=!b!)&echo,
echo QUA: & (for /l %%b in (30 -2 0) do set /a "b=(3<<%%b&num)>>%%b"&<nul set /p=!b!)&echo,
echo OCT: & set /a "b=^!^!(1<<30&num)"&<nul set /p=!b!
(for /l %%b in (27 -3 0) do set /a "b=(7<<%%b&num)>>%%b"&<nul set /p=!b!)&echo,
echo,&goto :next
复制代码

作者: CrLf 时间: 2012-3-20 17:19

本帖最后由 CrLf 于 2012-3-22 14:15 编辑

16 进制查表法：

@echo off&setlocal enabledelayedexpansion
set num=42

set n=0
for %%a in (0 1) do for %%b in (0 1) do for %%c in (0 1) do for %%d in (0 1) do (
	set _!n!=%%a%%b%%c%%d&set /a n+=1
)
rem 创建 0~15 的表

for /l %%a in (28 -4 0) do (
	set /a "m=num>>%%a&15"
	for %%b in (!m!) do set /p=!_%%b!<nul
)
echo;
rem 位运算分别获取相应位的值，并查表

pause
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)