![Board logo](images/default/logo.gif)
标题: [注册表类] [已解决]一个纯批命令开启来宾共享的方案,请大家帮我完善下,谢谢! [打印本页]
作者: yangyf34 时间: 2012-5-17 22:52 标题: [已解决]一个纯批命令开启来宾共享的方案,请大家帮我完善下,谢谢!
本帖最后由 yangyf34 于 2012-5-18 09:04 编辑
经常碰到卖出去的电脑共享的打印机不能用了,原因是:
1:360或者腾讯的安全软件优化过了;
2:administrator用户设置或者更改密码了;
因此萌发了做一个bat,可以让客户自己双击运行搞定的想法:
我的要求是:
XP系统,运行bat并重启后就可以在网上邻居看到其它电脑,并能双击访问对方电脑和打印机,无需密码。
我的思路是:
第一步:修复、开启和共享相关的服务;
第二步:解除相关注册表限制;
第三步:启用Guest用户;
这里我自己都做到了(见下面代码);
下面是我目前没找到办法的几点:
修改注册表:“从网络访问此计算机”有“Guest”
修改注册表:“拒绝从网络访问这台计算机”无“Guest”
第四步:改为统一的工作组workgroup(就是默认的工作组);
第五步:根据当前IP地址更改计算机名,比如IP为101,那么计算机名为pc101。
以上2步有办法那最好了~
请注意:不用第三方软件和工具,就一个bat。谢谢大家帮我完善。
自己做的bat如下:- @ECHO off
- ECHO ┌─────────────────────┐
- ECHO │开通局域网共享?(访问本机无需验证即可进入)│
- ECHO └─────────────────────┘
- pause
-
- ECHO ┌─────────────────────────────────┐
- ECHO │设置:开启网络共享相关服务。 │
- ECHO └─────────────────────────────────┘
- ECHO.
- sc config LanmanServer start= auto
- net start LanmanServer
-
- sc config LanmanWorkstation start= auto
- net start LanmanWorkstation
-
- sc config Browser start= auto
- net start Browser
-
- sc config Schedule start= demand
- net stop Schedule
- ECHO.
- ECHO.
-
- ECHO ┌─────────────────────────────────┐
- ECHO │设置:允许SAM帐户和共享的匿名枚举。 │
- ECHO └─────────────────────────────────┘
- reg add "HKLM\SYSTEM\CurrentControlSet\Control\Lsa" /v restrictanonymous /t REG_DWORD /d 0 /f
- reg add "HKLM\SYSTEM\ControlSet001\Control\Lsa" /v restrictanonymous /t REG_DWORD /d 0 /f
- ECHO.
- ECHO.
-
- ECHO ┌─────────────────────────────────┐
- ECHO │设置:本机帐户若空密码,允许其它机访问本机。 │
- ECHO └─────────────────────────────────┘
- reg add "HKLM\SYSTEM\CurrentControlSet\Control\Lsa" /v limitblankpassworduse /t REG_DWORD /d 0 /f
- reg add "HKLM\SYSTEM\ControlSet001\Control\Lsa" /v limitblankpassworduse /t REG_DWORD /d 0 /f
- ECHO.
- ECHO.
-
- ECHO ┌─────────────────────────────────┐
- ECHO │设置:Windows防火墙:允许文件和打印机共享。 │
- ECHO └─────────────────────────────────┘
- reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\UserAssist\{75048700-EF1F-11D0-9888-006097DEACF9}\Count" /v HRZR_EHAPCY /t REG_BINARY /d 0C00000026000000F0FBE5526495C601 /f
- reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\UserAssist\{75048700-EF1F-11D0-9888-006097DEACF9}\Count" /v "HRZR_EHAPCY:"P:\JVAQBJF\flfgrz32\sverjnyy.pcy"Jvaqbjf 防火墙" /t REG_BINARY /d 0C00000008000000F0FBE5526495C601 /f
-
- reg add "HKLM\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List" /v 445:TCP /t REG_SZ /d 445:TCP:LocalSubNet:Enabled:@xpsp2res.dll-22005 /f
- reg add "HKLM\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List" /v 137:UDP /t REG_SZ /d 137:UDP:LocalSubNet:Enabled:@xpsp2res.dll-22001 /f
- reg add "HKLM\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List" /v 138:UDP /t REG_SZ /d 138:UDP:LocalSubNet:Enabled:@xpsp2res.dll-22002 /f
- reg add "HKLM\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List" /v 139:TCP /t REG_SZ /d 139:TCP:LocalSubNet:Enabled:@xpsp2res.dll-22004 /f
-
- reg add "HKLM\SYSTEM\ControlSet001\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List" /v 445:TCP /t REG_SZ /d 445:TCP:LocalSubNet:Enabled:@xpsp2res.dll-22005 /f
- reg add "HKLM\SYSTEM\ControlSet001\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List" /v 137:UDP /t REG_SZ /d 137:UDP:LocalSubNet:Enabled:@xpsp2res.dll-22001 /f
- reg add "HKLM\SYSTEM\ControlSet001\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List" /v 138:UDP /t REG_SZ /d 138:UDP:LocalSubNet:Enabled:@xpsp2res.dll-22002 /f
- reg add "HKLM\SYSTEM\ControlSet001\Services\SharedAccess\Parameters\FirewallPolicy\StandardProfile\GloballyOpenPorts\List" /v 139:TCP /t REG_SZ /d 139:TCP:LocalSubNet:Enabled:@xpsp2res.dll-22004 /f
-
- reg add "HKLM\SYSTEM\CurrentControlSet\Services\SharedAccess\Epoch" /v Epoch /t REG_DWORD /d 493 /f
- reg add "HKLM\SYSTEM\ControlSet001\Services\SharedAccess\Epoch" /v Epoch /t REG_DWORD /d 493 /f
-
- reg add "HKLM\SYSTEM\ControlSet001\Control\Print\Providers" /v LogonTime /t REG_BINARY /d E8318E4F6495C601 /f
- ECHO.
- ECHO.
-
- ECHO ┌─────────────────────────────────┐
- ECHO │设置:共享方式:本地用户以来宾身份验证。 │
- ECHO └─────────────────────────────────┘
- reg add "HKLM\SYSTEM\CurrentControlSet\Control\Lsa" /v forceguest /t REG_DWORD /d 1 /f
- ECHO.
- ECHO.
-
- ECHO ┌─────────────────────────────────┐
- ECHO │设置:关闭自动搜索网络文件夹、打印机和计划任务。 │
- ECHO └─────────────────────────────────┘
- reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\RemoteComputer\NameSpace\{2227A280-3AEA-1069-A2DE-08002B30309D}" /f
- reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\RemoteComputer\NameSpace\{D6277990-4C6A-11CF-8D87-00AA0060F5BF}" /f
- ECHO.
- ECHO.
-
- ECHO ┌─────────────────────────────────┐
- ECHO │设置:来宾帐户:启用。 │
- ECHO └─────────────────────────────────┘
- reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon\SpecialAccounts\UserList" /v guest /t REG_DWORD /d 0 /f
- net user Guest /active:yes
- ECHO.
- ECHO.
-
- ECHO ┌───────────┐
- ECHO │修改完成,请重启电脑! │
- ECHO └───────────┘
- pause
复制代码
作者: yangyf34 时间: 2012-5-18 00:05
下面是我目前没找到办法的几点:
修改注册表:“从网络访问此计算机”有“Guest”
修改注册表:“拒绝从网络访问这台计算机”无“Guest”
通过lxzzr版主的这片好帖子:http://www.bathome.net/viewthread.php?tid=7528&highlight=
我自己找到解决办法了:
sedenynetworklogonright = 拒绝从网络访问这台计算机
senetworklogonright = 从网络访问此计算机- ECHO ┌─────────────────────────────────┐
- ECHO │设置:[从网络访问此计算机] 增加“Guest”; │
- ECHO │设置:[拒绝从网络访问这台计算机] 删除“Guest”。 │
- ECHO └─────────────────────────────────┘
- (echo [Unicode]
- echo Unicode=yes
- echo [Version]
- echo signature="$CHICAGO$"
- echo Revision=1
- echo [Privilege Rights]
- echo sedenynetworklogonright =
- echo senetworklogonright = Everyone,Administrators,Users,Power Users,Backup Operators)>>admin_sec.inf
- secedit /configure /db admin_sec.sdb /cfg admin_sec.inf /log admin_sec.log /quiet
- del admin_sec.*
- ECHO.
- ECHO.
-
- ECHO ┌─────────────────────────────────┐
- ECHO │设置:根据当前IP地址后3位更改计算机名为PC123 │
- ECHO │设置:更改工作组为“WORKGROUP”。 │
- ECHO └─────────────────────────────────┘
- for /f "tokens=15" %%i in ('ipconfig ^| find /i "ip address"') do set ip=%%i
- set name=PC%IP:~10,3%
-
- reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\ComputerName\ActiveComputerName" /v ComputerName /t reg_sz /d %name% /f
- reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v "NV Hostname" /t reg_sz /d %name% /f
- reg add "HKEY_LOCAL_MACHINE\System\CurrentControlSet\Services\Tcpip\Parameters" /v Hostname /t reg_sz /d %name% /f
-
- wmic computersystem where name="%computername%" call joindomainorworkgroup name=WORKGROUP
- ECHO.
- ECHO.
复制代码
这样,完整的就是:复制代码
欢迎光临 批处理之家 (http://bbs.bathome.net/) |
Powered by Discuz! 7.2 |