批处理之家 - Powered by Discuz! Board

@echo off
setlocal enabledelayedexpansion
if "%cd%" neq "%userprofile%\桌面" echo 请把该文件放到桌面上使用！&pause>nul&exit
for /f "delims=:" %%a in ('findstr /n /c:"[文件夹设置]" %0') do set fdk=%%a
for /f "delims=:" %%a in ('findstr /n /c:"[文件设置]" %0') do set flk=%%a
for /f "delims=" %%i in ('dir /ad /b *.*') do (
call :fd "%%i"
)
for /f "delims=" %%j in ('dir /a-d /b *.*') do (
call :file "%%j"
)
pause
::判断文件夹部分
:fd
for /f "skip=%fdk% delims=" %%m in (%~sdpnx0) do (
if %1 equ "%%m" goto :eof
set a=%%m
if "!a:~0,3!"=="***" echo rd /s /q %1&goto :eof
)
echo rd /s /q %1
goto :eof
::判断文件部分
:file
for /f "skip=%flk% delims=" %%n in (%~sdpnx0) do (
if %1 equ "%%n" goto :eof
)
if %1 neq "%~nx0" echo del /f /q %1
goto :eof
*******************************************************************************
[文件夹设置]（请在下面输入你要保留的“文件夹”每行只能输入一个）
新建文件夹
小游戏
*******************************************************************************
[文件设置]（请在下面输入你要保留的“文件”每行只能输入一个）
a.txt
uc.lnk
a.vbs
a.bat
一键上网.bat
腾讯QQ.lnk
MvBox.lnk
132.wma
快速关机.bat
HTML语言教程.exe

复制代码

In addition, substitution of FOR variable references has been enhanced.
You can now use the following optional syntax:

%~I       - expands %I removing any surrounding quotes (")
%~fI       - expands %I to a fully qualified path name
%~dI       - expands %I to a drive letter only
%~pI       - expands %I to a path only
%~nI       - expands %I to a file name only
%~xI       - expands %I to a file extension only
%~sI       - expanded path contains short names only
%~aI       - expands %I to file attributes of file
%~tI       - expands %I to date/time of file
%~zI       - expands %I to size of file
%~$PATH:I - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string

The modifiers can be combined to get compound results:

%~dpI    - expands %I to a drive letter and path only
%~nxI    - expands %I to a file name and extension only
%~fsI    - expands %I to a full path name with short names only
%~dp$PATH:I - searches the directories listed in the PATH
               environment variable for %I and expands to the
               drive letter and path of the first one found.
%~ftzaI    - expands %I to a DIR like output line