Board logo

标题: [注册表类] [已解决]批处理命令REG EXPORT如何截取REG_EXPAND_SZ类型的默认值？ [打印本页]
作者: tz_being    时间: 2012-6-3 21:14     标题: [已解决]批处理命令REG EXPORT如何截取REG_EXPAND_SZ类型的默认值？

我想把%SystemRoot%\system32\SHELL32.dll,-235赋予变量ICO，结果多出了REG_EXPAND字符。
我的代码for /f "skip=4 tokens=1,2,3*" %i in ('reg query "HKCR\CLSID\{450D8FBA-AD25-11D0-98A8-0800361B1103}\DefaultIcon" /ve') do set ICO=%j 错在哪里？
把%j 改为%k也同样不行，结果跟3楼一样。
作者: apang    时间: 2012-6-3 22:07

  1. for /f "skip=4 tokens=1,2*" %i in ('reg query "HKCR\CLSID\{450D8FBA-AD25-11D0-98A8-0800361B1103}\DefaultIcon" /ve') do set ICO=%k
复制代码
试试
作者: tz_being    时间: 2012-6-3 22:12

回复 2# apang
执行结果
作者: powerbat    时间: 2012-6-3 22:20

本帖最后由 powerbat 于 2012-6-3 22:43 编辑

tokens=2* 即可
作者: tz_being    时间: 2012-6-3 22:22

回复 4# powerbat


    一样不行，结果同3楼
作者: apang    时间: 2012-6-3 22:30

win7下不一样
作者: powerbat    时间: 2012-6-3 22:32

本帖最后由 powerbat 于 2012-6-3 22:42 编辑

skip不一定靠谱
  1. for /f "tokens=2*" %i in ('reg query "HKCR\CLSID\{450D8FBA-AD25-11D0-98A8-0800361B1103}\DefaultIcon" /ve^|find "默认"') do set ICO=%j
复制代码
作者: powerbat    时间: 2012-6-3 22:34

另外你的系统是不是xp sp2？sp3之前的版本reg.exe命令有点小bug
作者: tz_being    时间: 2012-6-3 22:35

回复 6# apang


    我的系统是XP SP2，看来是reg的版本的问题。有什么通用的方法没有？
作者: apang    时间: 2012-6-3 22:51

  1. @echo off&setlocal enabledelayedexpansion

  2. for /f "delims=" %%i in ('reg query "HKCR\CLSID\{450D8FBA-AD25-11D0-98A8-0800361B1103}\DefaultIcon"^|findstr /i "reg_expand_sz"') do (

  3.   set "str=%%i"

  4.   set "str=!str:*reg_expand_sz=!"

  5.   for /f "tokens=*" %%a in ("!str!") do echo %%~a

  6. )

  7. pause
复制代码
保存为bat运行，试试看，也不一定行。
作者: powerbat    时间: 2012-6-3 22:52

  1. wmic /namespace:\\root\default path StdRegProv call GetExpandedStringValue "&H80000000","CLSID\\{450D8FBA-AD25-11D0-98A8-0800361B1103}\\DefaultIcon" | findstr sValue
复制代码
作者: tz_being    时间: 2012-6-3 23:11

回复 10# apang

11楼的倒可以，但怎样把sValue变量传递给批处理？
作者: tz_being    时间: 2012-6-3 23:23

本帖最后由 tz_being 于 2012-6-3 23:24 编辑

试验结果，对XP SP2而言，10楼的代码修改为下面这样是可行的，但对XP SP3而言却又不行了：
  1. @echo off&setlocal enabledelayedexpansion

  2. for /f "skip=4 tokens=1,2,3*" %%i in ('reg query "HKCR\CLSID\{450D8FBA-AD25-11D0-98A8-0800361B1103}\DefaultIcon"') do (

  3. set "str=%%j"

  4. set "str=!str:reg_expand=!"

  5. )

  6. echo %str%

  7. pause
复制代码
作者: powerbat    时间: 2012-6-3 23:25

  1. for /f "tokens=2*" %a in ('wmic /namespace:\\root\default path StdRegProv call GetExpandedStringValue "&H80000000"^,"CLSID\\{450D8FBA-AD25-11D0-98A8-0800361B1103}\\DefaultIcon" ^| findstr sValue') do @for %x in (%b) do set ICO=%~fx
复制代码
作者: tz_being    时间: 2012-6-4 12:53

14楼的代码还是不行。希望有通过VBS实现的方法
作者: powerbat    时间: 2012-6-4 13:31

回复 15# tz_being


    没有xpsp2环境，xpsp3与win7都没问题。
作者: tz_being    时间: 2012-6-4 15:01

我的运行结果
作者: powerbat    时间: 2012-6-4 16:05

本帖最后由 powerbat 于 2012-6-4 16:08 编辑

好像xp中wmi也有bug：如果一个键值从来没有被查询过，直接用wmi查询会失败。wmic返回ReturnValue=87，而vbs调用相应方法的返回值是2。
再次试验发现wmic和vbs都可能返回2或87。
作者: powerbat    时间: 2012-6-4 16:16

Microsoft Windows XP [版本 5.1.2600]
(C) 版权所有 1985-2001 Microsoft Corp.

C:\Documents and Settings\Administrator>wmic /namespace:\\root\default path StdR
egProv call GetExpandedStringValue "&H80000000","CLSID\\{450D8FBA-AD25-11D0-98A8
-0800361B1103}\\DefaultIcon"
执行 (StdRegProv)->GetExpandedStringValue()
方法执行成功。
输出参数:
instance of __PARAMETERS
{
        ReturnValue = 2;
};


C:\Documents and Settings\Administrator>reg query "HKCR\CLSID\{450D8FBA-AD25-11D
0-98A8-0800361B1103}"

! REG.EXE VERSION 3.0

HKEY_CLASSES_ROOT\CLSID\{450D8FBA-AD25-11D0-98A8-0800361B1103}
    SortOrderIndex      REG_DWORD       0x48
    InfoTip     REG_EXPAND_SZ   @%SystemRoot%\system32\SHELL32.dll,-22914
    LocalizedString     REG_EXPAND_SZ   @%SystemRoot%\system32\SHELL32.dll,-9227


HKEY_CLASSES_ROOT\CLSID\{450D8FBA-AD25-11D0-98A8-0800361B1103}\DefaultIcon

HKEY_CLASSES_ROOT\CLSID\{450D8FBA-AD25-11D0-98A8-0800361B1103}\InProcServer32

HKEY_CLASSES_ROOT\CLSID\{450D8FBA-AD25-11D0-98A8-0800361B1103}\shell

HKEY_CLASSES_ROOT\CLSID\{450D8FBA-AD25-11D0-98A8-0800361B1103}\shellex

HKEY_CLASSES_ROOT\CLSID\{450D8FBA-AD25-11D0-98A8-0800361B1103}\ShellFolder

C:\Documents and Settings\Administrator>wmic /namespace:\\root\default path StdR
egProv call GetExpandedStringValue "&H80000000","CLSID\\{450D8FBA-AD25-11D0-98A8
-0800361B1103}\\DefaultIcon"
执行 (StdRegProv)->GetExpandedStringValue()
方法执行成功。
输出参数:
instance of __PARAMETERS
{
        ReturnValue = 0;
        sValue = "C:\\WINDOWS\\system32\\SHELL32.dll,-235";
};


C:\Documents and Settings\Administrator>for /f "tokens=2*" %a in ('wmic /namespa
ce:\\root\default path StdRegProv call GetExpandedStringValue "&H80000000"^,"CLS
ID\\{450D8FBA-AD25-11D0-98A8-0800361B1103}\\DefaultIcon" ^| findstr sValue') do
@for %x in (%b) do set ICO=%~fx


C:\Documents and Settings\Administrator>set ICO=C:\WINDOWS\system32\SHELL32.dll,
-235

C:\Documents and Settings\Administrator>


楼主试试下面这样能不能得到结果
  1. reg query "HKCR\CLSID\{450D8FBA-AD25-11D0-98A8-0800361B1103}" >nul

  2. for /f "tokens=2*" %a in ('wmic /namespace:\\root\default path StdRegProv call GetExpandedStringValue "&H80000000"^,"CLSID\\{450D8FBA-AD25-11D0-98A8-0800361B1103}\\DefaultIcon" ^| findstr sValue') do @for %x in (%b) do set ICO=%~fx
复制代码
作者: tz_being    时间: 2012-6-4 17:58

回复 19# powerbat


    谢谢，这样行了。只是不知道在XP SP3中是否也一样行。



欢迎光临 批处理之家 (http://bbs.bathome.net/) Powered by Discuz! 7.2