Board logo

标题: 【练习-023】按要求替换文本字符的批处理 [打印本页]
作者: batman    时间: 2008-9-10 16:50     标题: 【练习-023】按要求替换文本字符的批处理

前言：
　　本人最近眼睛出了毛病，所以不能常在论坛和群里为大家服务了，在此深表遗憾，也请
大家予以谅解。
　　今天帮同事解决了一个工作上的小问题，觉得这个问题比较有代表性，所以整理了下出
了这题（个人无法在excel表格中完成操作，不知有高人能否做到）。
出题目的：
　　唯一的目的在于通过解题灵活掌握字符替换技巧
加分原则：
　　1　思路新颖基分5分
　　2　代码高效基分4分
　　3　代码简洁基分3分
　　4　代码通用基分2分
　　5　无临时文件基分1分
　　6　完美代码加15分
题目如下：
　　有a.txt内容如下（在实际中有数万行）
  1. 330001--330002--330106

  2. 330001--330006--330108

  3. 330001--330007--330112

  4. 330101--330108--330205

  5. 330101--330110--330212

  6. 330201--330211--330301

  7. 330302--330304--330309

  8. 330302--330308--330402

  9. 330302--330410--330408

  10. 330402--330406--330411

  11. 330505--330511--330807
复制代码
　　要求用批处理对字符进行逐行替换，将其中的330＊＊替换为200＊年＊月，但不允许
出现05月（正确为5月）字样，同时输出如下：
  1. 2000年1月--2000年2月--2001年6月

  2. 2000年1月--2000年6月--2001年8月

  3. 2000年1月--2000年7月--2001年12月

  4. 2001年1月--2001年8月--2002年5月

  5. 2001年1月--2001年10月--2002年12月

  6. 2002年1月--2002年11月--2003年1月

  7. 2003年2月--2003年4月--2003年9月

  8. 2003年2月--2003年8月--2004年2月

  9. 2003年2月--2004年10月--2004年8月

  10. 2004年2月--2004年6月--2004年11月
复制代码

[ 本帖最后由 batman 于 2008-9-24 08:03 编辑 ]
作者: pusofalse    时间: 2008-9-10 17:01

BATMAN兄多注意休息，一切安好。
另想问一下，文本中有无类似于330125--330125--330125这样的数据
即330之后的125，要替换为2012年5月--2012年5月--2012年5月吗？
还是说表示月份的后两个数字一定leq 12？

[ 本帖最后由 pusofalse 于 2008-9-10 17:30 编辑 ]
作者: pusofalse    时间: 2008-9-10 19:40

先来抛砖，拿来献丑了，看下是否是这样的输出：
  1. @echo off&setlocal enabledelayedexpansion

  2. for /f "delims=" %%a in (a.txt) do (

  3.       set "str=%%a"&set "var="

  4.       set "str=!str:330=200!"

  5.       for /f "tokens=1-3 delims=-" %%i in ("!str!") do (

  6.            set/a i=%%i,j=%%j,k=%%k

  7.            for %%s in (i j k) do (

  8.                 set "c=!%%s:~-2!"

  9.                 if "!c!" neq "10" set "c=!c:0=!"

  10.                 set "var=!var!!%%s:~,4!年!c!月--"

  11.            )

  12.            echo !var:~,-2!

  13. ))

  14. echo.&pause
复制代码
在excel表格中操作，我也不知如何完成，对OFFICE一窍不通，求教高人。

[ 本帖最后由 pusofalse 于 2008-9-10 19:43 编辑 ]
作者: 随风    时间: 2008-9-10 20:26

版主保重身体
  1. @echo off&setlocal enabledelayedexpansion

  2. for /f "delims=" %%a in (a.txt) do (

  3.    set "str=%%a"

  4.    set str=!str:-= !&set "str=!str:330=200!"

  5.    for %%i in (!str!) do (

  6.      set "var=%%i"

  7.      set /a num=100!var:~-2!%%100

  8.      set "ok=!ok!--!var:~0,4!年!num!月"

  9. )

  10.     echo !ok:~2!

  11.     set "ok="

  12. )

  13. pause
复制代码
作者: batman    时间: 2008-9-11 08:06     标题: 我的方案

利用shift移位：
  1. @echo off

  2. for /f "tokens=1,2* delims=-" %%i in (a.txt) do set "s=%%k"&call :lp %%i %%j %%k   

  3. pause>nul&goto :eof

  4. :lp

  5. set "str=%1"

  6. set "a=%str:~3,1%"&set /a b=1%str:~-2%%%100

  7. set "var=%var%--200%a%年%b%月"

  8. if "%1" neq "%s%" shift&goto lp

  9. echo %var:~2%&set "var="
复制代码

[ 本帖最后由 batman 于 2008-9-11 08:10 编辑 ]
作者: batman    时间: 2008-9-11 13:03

＆＆这题真的不难，不知大家为什么不愿尝试呢？本版块的出题环节一直在继续中，但个人
觉得并没有达到预期的效果，具体表现在：基本上都是几个版主和技术人员在解答题目，却
鲜见其他会员跟贴解题。
　　于是，个人有所反省，是不是这样的题目超越了大多数会员的能力范围了？是不是这样
的题目并不具有代表性？是不是这样的题目脱离实际太远了？是不是大家不能接受这样的学
习形式？
　　为了加强论坛学习指导的针对性，还请大家畅所欲言，就你所认为的，论坛应从哪些方
面出发来引导和提高大家学习批处理，来提出自已的建议；我们将根据大家的建议，不断完
善论坛的学习功能，健全学习机制，以达到共同提高的最终目的。

[ 本帖最后由 batman 于 2008-9-11 13:08 编辑 ]
作者: huahua0919    时间: 2008-9-11 13:07

这些数据是在Excle中的吗.斑竹是否能够上传这个文件来看看
我对Excle小有研究。也许能够解决
作者: batman    时间: 2008-9-11 21:47

原帖由 huahua0919 于 2008-9-11 13:07 发表
这些数据是在Excle中的吗.斑竹是否能够上传这个文件来看看
我对Excle小有研究。也许能够解决

兄弟可以直接把a.txt的内容复制到execel中进行处理啊。。。
作者: bater    时间: 2008-9-11 22:03     标题: 我用excle的解决方案

在空白单元里输入公式
  1. =LEFT(REPLACE(A1,1,3,200),4)&"年"&RIGHT(A1,2)&"月"
复制代码
然后按照内容多少把数据全部选中后，全部数据转换成下列：
  

2000年01月 2000年02月 2001年06月 2000年01月  2000年06月 2001年08月


然后把数据全部选中，右键选择复制-->选择性粘贴-->选择数值，这样就把单元格的公式属性去掉了
选择编辑菜单下的，替换 输入 "年0" 全部替换为 "年"，就得到你要的数据了！

这是用函数方法完成，用vba的方法也可以完成，也是用到for循环，和批处理的方法类似！

[ 本帖最后由 bater 于 2008-9-11 22:34 编辑 ]
作者: batman    时间: 2008-9-12 07:57

原帖由 bater 于 2008-9-11 22:03 发表
在空白单元里输入公式=LEFT(REPLACE(A1,1,3,200),4)&"年"&RIGHT(A1,2)&"月"然后按照内容多少把数据全部选中后，全部数据转换成下列：
  

2000年01月 2000年02月 2001年06月 2000年01月  200 ...

本人实是愚钝，照兄弟所述的在excel中搞了半天，硬是不得法，没有成功转换，汗。。。

本人也摸索了一个公式：=MID(B1,1,4)&"年"&MID(B1,5,2)&"月"&"--"&MID(B1,9,4)&"年"&MID(B1,13,2)&"月"&"--"&MID(B1,17,4)&"年"&MID(B1,21,2)&"月"，基本上能达到替换的要求了。。。

[ 本帖最后由 batman 于 2008-9-12 08:42 编辑 ]
作者: bater    时间: 2008-9-12 09:11

呵呵，是我没有读懂题目，我首先把你A.txt的 数据利用
替换把-- 换成空格  ，然后由excel的数据导入进去
所以得到的数据，是没有--的，又看了下题目正如你说的用&把“--”是可以的，总之，我的excle老师告诉我，在excle下能得到正确答案，就是好的，因为，效率已经比
手动修改，提高很多了.
另外，在论坛学习了你很多的p处理知识。希望能从你身上学到更多的知识！
作者: batman    时间: 2008-9-12 09:39

原帖由 bater 于 2008-9-12 09:11 发表
呵呵，是我没有读懂题目，我首先把你A.txt的 数据利用
替换把-- 换成空格  ，然后由excel的数据导入进去
所以得到的数据，是没有--的，又看了下题目正如你说的用&把“--”是可以的，总之，我的excle老师告诉我，在 ...

兄弟太客气了，呵呵，咱们一起学习，共同进步了。
作者: zhangmi    时间: 2008-9-15 07:12

我在excel中用分列去掉－－，然后用公式=LEFT(REPLACE(A1,1,3,200),4)&"年"&（RIGHT(A1,2)*1）&"月"，向右向下一拉就成了。
作者: keen    时间: 2009-5-19 21:12

  1. @echo off&setlocal enabledelayedexpansion

  2. for /f %%i in (a.txt) do (

  3.     set str=%%i&set str=!str:--= !&set "v="

  4.     for %%j in (!str!) do (

  5.         set var=%%j&set var=!var:330=200!

  6.         set var1=!var:~0,4!

  7.         if "!var:~-2,1!" equ "0" (set var2=!var:~-1,1!) else (set var2=!var:~-2,2!)

  8.         set v=!v!!var1!年!var2!月--

  9.        

  10. )

  11. echo !v:~0,-2!

  12. )

  13. pause
复制代码
作者: keen    时间: 2009-5-19 21:17

发现跟pusofalse版主在三楼的一样了！
作者: keen    时间: 2009-5-19 21:34     标题: 回复 5楼 的帖子

shift用法妙，但call ：lp进行循环，效率可能不高吧！
作者: netbenton    时间: 2009-5-19 23:13

::要想高效，利用变量定义，尽量减少循环体内的代码！
  1.  

  2. @echo off&setlocal enabledelayedexpansion

  3. for /l %%a in (3300,1,3315) do (

  4.  set #a=%%a

  5.  for /l %%b in (1,1,9) do (set %%a0%%b=20!#a:~2,2!年%%b月)

  6.         for %%b in (10 11 12) do (set %%a%%b=20!#a:~2,2!年%%b月)

  7. )

  8. for /f "tokens=*" %%a in (a.txt) do (

  9.     for /f "tokens=1-3 delims=-" %%b in ("%%a") do (echo !%%b!--!%%c!--!%%d!)

  10. )

  11. echo.&pause
复制代码
作者: keen    时间: 2009-5-20 00:05     标题: 回复 17楼 的帖子

netbenton兄的想法实在是妙，效率也高，但是付出了内存的代价！
如果这样的数很多，占用内存会很大。
作者: netbenton    时间: 2009-5-20 07:38

当然，如果数很多占用内存就多，
就本题而言，仅仅为：年数*12而已，就算是跨100年，也不过1200个变量定义。
在具体使用时，就要看实际情况了，如果“定义体”比“循环体”要大，则不应该使用变量定义。
作者: zhouyongjun    时间: 2009-6-13 13:59

  1. @echo off&setlocal enabledelayedexpansion

  2. for /f "tokens=1-3 delims=-" %%a in (a.txt) do (

  3.     set/a y1=%%a/100,y1-=1300,m1=%%a%%100,y2=%%b/100,y2-=1300,m2=%%b%%100,y3=%%c/100,y3-=1300,m3=%%c%%100

  4.     echo !y1!年!m1!月--!y2!年!m2!月--!y3!年!m3!月

  5. )

  6. pause
复制代码
作者: tab    时间: 2009-6-13 17:20

sed s/330/200/g;s/--/\n/g a.txt|sed "s/200./&年/;s/$/月/;s/年0/年/"|sed N;N;s/\n/--/|sed N;s/\n/--/
其实允许2009年01月形式的话，会少很多代码而且格式也工整。
作者: curious    时间: 2009-6-13 21:11

我这代码效率不高，仅能做对而已
  1. @echo off&setlocal enabledelayedexpansion

  2. for /f "tokens=1-3 delims=--"  %%i in (a.txt) do (

  3. call :aa %%i

  4. call :aa %%j

  5. call :aa %%k

  6. echo !b:~2!

  7. set b=

  8. )

  9. pause>nul

  10. goto :eof

  11. :aa

  12. set a=%1

  13. set a=!a:330=200!

  14. set a1=!a:~0,4!年

  15. set a2=!a:~-2!

  16. if !a2! lss 10 (set a2=!a2:~-1!) else (set a2=!a2:~-2!)

  17. set a=!a1!!a2!月

  18. set b=!b!--!a!
复制代码
作者: lengmoke    时间: 2021-10-13 10:20

  1. @echo off

  2. setlocal EnableDelayedExpansion

  3. for /f %%i in (a.txt) do (

  4.     set str=%%i

  5.     set str=20!str:~2,2!年!str:~4,2!月--20!str:~10,2!年!str:~12,2!月--20!str:~18,2!年!str:~20,2!月

  6.     echo !str:年0=年!

  7. )
复制代码




欢迎光临 批处理之家 (http://bbs.bathome.net/) Powered by Discuz! 7.2