批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理如何获取指定字符串的之前第n行的指定的内容？ [打印本页]

作者: cnswb 时间: 2012-9-24 19:06 标题: [已解决]批处理如何获取指定字符串的之前第n行的指定的内容？

本帖最后由 pcl_test 于 2017-3-25 09:06 编辑

一个文本里包含如下内容：
Name: 本地连接
Guid: {9A0760AB-EA91-4E74-B562-C5B1FD7EE8FF}
DeviceName: Intel(R) PRO/1000 PL Network Connection
Status: 2
MediaType: 3
Not Shared... Enabling public connection share...
Shared!

Name: VMware Network Adapter VMnet1
Guid: {ABD6CC7A-521F-40BE-90AB-1801A7C2B677}
DeviceName: VMware Virtual Ethernet Adapter for VMnet1
Status: 2
MediaType: 3

Name: wlan_ap
Guid: {B7850060-CF51-47CC-A7C5-C4D4C0054DAC}
DeviceName: Microsoft Virtual WiFi Miniport Adapter #2
Status: 2
MediaType: 3
Not Shared... Enabling private connection share...
Shared!

Name: 本地连接 2
Guid: {0161B56A-E61F-4014-82F4-3E49C10C81DA}
DeviceName: Sierra Wireless AC595U 1xEV-DO Network Adapter
Status: 7
MediaType: 3

想用根据字符串Enabling public，获取到他上面第五行：Name: 本地连接中的“本地连接”，“本地连接”是不定的，搜索了很多帖子，都是可以通过过for skip跳过往下，怎样才能获取上 n行的指定内容呢？

作者: CrLf 时间: 2012-9-24 19:23

本帖最后由 CrLf 于 2012-9-25 01:09 编辑

方案一，获取 skip 行数：

@echo off
for /f "delims=:" %%a in ('findstr /nc:"Enabling public" 测试.txt') do set /a linenum=%%a-6
for /f "skip=%linenum% tokens=1* delims=: " %%a in (测试.txt) do echo %%b&pause&exit
复制代码

方案二，用变量保存五行：

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1* delims=: " %%a in (a.txt) do (
  set /a n+=1,n%%=5
  set str=%%b
  if "!str:Enabling public=!" neq "!str!" (
     for %%b in (!n!) do echo !ar[%%b]!&pause&exit
  )
  set "ar[!n!]=%%b"
)
复制代码

方案三，逆序文本：

@echo off&setlocal enabledelayedexpansion
set begin=0
for /f "tokens=1* delims=: " %%a in ('sort /+999 测试.txt') do (
   set str=%%b
   if "!str:Enabling public=!" neq "!str!" set begin=1
   if !n!==5 echo !str!
   if !begin!==1 set /a n+=1
)
pause
复制代码

还有其他方案，但我想这三个够用了...

作者: cnswb 时间: 2012-9-24 19:53

回复 2# CrLf

谢谢 CrLf 第一次发帖，没想到回复这么快！

测试了一下！
第一个返回：此时不应有 Not Shared... Enabling public connection share... delims="。
请按任意键继续. . .

第二个返回：Name: 本地连接没问题！

第三个：
'begin' 不是内部或外部命令，也不是可运行的程序
或批处理文件。
此时不应有 =5。

第二个可以使用了。。

其实这个文件里，是记录internet 连接共享的一个log，本想用批处理直接查看，苦于没有办法！这样也算曲线解决了吧

作者: CrLf 时间: 2012-9-24 19:59

代码笔误已修改...

作者: cnswb 时间: 2012-9-24 20:07

回复 4# CrLf

第一个方案，应该是获取的下一行，并不能向上获取

第三个返回此时不应有 =5。

其实第3个，我看不太明白，很菜啊！

作者: cnswb 时间: 2012-9-24 20:37

CrLf 大大，方案二代码返回的 “Name: 本地连接"如何直接在方案二的代码里把"本地连接"前的所有字符过滤掉，包括那个空格？

作者: CrLf 时间: 2012-9-24 20:48

又笔误了...
已修改

第三个只是把文本倒过来读而已

作者: cnswb 时间: 2012-9-24 21:06

回复 7# CrLf

不知道为什么方案一就是报错啊！
返回的是此时不应有 -6 tokens=1* delims=："。我原来也这么试过就是不行好像

作者: forfiles 时间: 2012-9-24 23:07

回复 7# CrLf

@echo off
for /f "delims=:" %%a in ('findstr /nc:"Enabling public" 测试.txt') do set linenum=%%a-6
set "skip=skip=%linenum%"
for /f "%skip% tokens=1* delims=: " %%a in (测试.txt) do echo %%b&pause&exit
复制代码

作者: cnswb 时间: 2012-9-24 23:21

本帖最后由 cnswb 于 2012-9-24 23:24 编辑

回复 9# forfiles

也是不行的，返回仍是：此时不应有 -6 tokens=1* delims=: "。

-6 是因为 "set linenum=%%a-6“ set后面没有加 /a 参数吗？！不知道tokens=1* delims=: " 为什么会报错

作者: forfiles 时间: 2012-9-24 23:26

回复 10# cnswb

@echo off
for /f "delims=:" %%a in ('findstr /nc:"Enabling public" 测试.txt') do set /a linenum=%%a-6
set "skip=skip=%linenum%"
for /f "%skip% tokens=1* delims=: " %%a in (测试.txt) do echo %%b&pause&exit

作者: cnswb 时间: 2012-9-24 23:29

回复 11# forfiles

返回：此时不应有 tokens=1* delims=: "。我就是搞不清为啥这段不应该有呢？

作者: forfiles 时间: 2012-9-24 23:59

回复 12# cnswb

把@echo off删掉，执行过程贴出来看看

作者: terse 时间: 2012-9-25 00:32

变通一下

@echo off
for /f "tokens=1* delims=:" %%i in ('findstr /inc:"Enabling public" 测试.txt') do set /a N=%%i-5
for /f "tokens=1,2* delims=: " %%i in ('findstr /in ".*" "测试.txt"') do if %%i equ %N% set str=%%k&goto end
:end
echo %str%
pause
复制代码

作者: CrLf 时间: 2012-9-25 01:10

回复 10# cnswb

貌似是...唉，我这眼神

作者: terse 时间: 2012-9-25 02:01

skip=0 呢当前长度: 系统限制:

作者: CrLf 时间: 2012-9-25 02:29

回复 16# terse

嗯，forfiles 在 11楼弥补了这个考虑不周之处

作者: cnswb 时间: 2012-9-25 21:23

本帖最后由 cnswb 于 2012-9-25 21:26 编辑

回复 13# forfiles

不好意思昨天有急事儿，没打招呼就慌乱的下线了
去掉@echo off这样的：
D:\桌面\新建文件夹>for /F "delims=:" %a in ('findstr /nc:"Enabling public" a.txt
') do set /a linenum=%a-6

D:\桌面\新建文件夹>set /a linenum=6-6

D:\桌面\新建文件夹>set "skip=skip=0"

D:\桌面\新建文件夹>for /F "skip=0 tokens=1* delims=: " %a in (a.txt) do echo %b
& pause & exit
此时不应有 tokens=1* delims=: "。

测试了一下，把那个字符串往下换了几行就可以找到相应的地方了，不知道什么原因

terse的那个倒是可以，但是不知道为什么输出之后尾部都会多一个空格符号

作者: terse 时间: 2012-9-25 22:13

回复 18# cnswb
我16楼已经说了 SKIP=0 的时候是出错的啊也就是值必须大于0
至于空格具体是什么情况

作者: cnswb 时间: 2012-9-25 22:22

回复 19# terse

比如我把结果 > 1.log 发现行尾有空格，后来看其他几个也有空格，不知道是怎么回事

作者: forfiles 时间: 2012-9-25 22:37

回复 20# cnswb

@echo off
for /f "tokens=1* delims=:" %%i in ('findstr /inc:"Enabling public" 测试.txt') do set /a N=%%i-5
for /f "tokens=1,2* delims=: " %%i in ('findstr /in ".*" "测试.txt"') do if %%i equ %N% set str=%%k&goto end
:end
>1.log echo %str%
pause

作者: cnswb 时间: 2012-9-25 23:11

本帖最后由 cnswb 于 2012-9-25 23:14 编辑

回复 21# forfiles

呵呵可以了多谢，不知道原因是什么！这个名字要带入下一个命令中使用的，在下一个命令中，直接引用不知道还会不会有空格了
还要自己多学习了

这里的高人，都比较热心，！！等我吧做完的完整批处理给大家看吧！

作者: forfiles 时间: 2012-9-25 23:18

回复 22# cnswb

试试就知道了，没有问题。你写入文件的时候有空格是因为你的重定向符号前面多了空格，比如 echo xxx >1.log

作者: cnswb 时间: 2012-9-25 23:25

回复 23# forfiles

果然是重定向时的问题！！！多谢您的耐心解释！！

作者: pcl_test 时间: 2017-3-25 09:58

win7及以上系统运行

powershell "(gc '文本.txt'|select-string '\bEnabling public\b' -context 5,1).Context.PreContext[0].split(':')[1]"
pause
复制代码

欢迎光临批处理之家 (http://bbs.bathome.net/)