@echo off
:loop
cls&setlocal enabledelayedexpansion
for %%a in (一 二 三 四 五 六 天) do set/a n+=1&set ".!n!=%%a"
set /p var=几天前/后? 
set/a s=var, x=4
set/a var%%=7
if "%var:~,1%" equ "-" (
   set "op=+"&set "str=后"
   set /a m=8,y=1
   ) else (
   set "op=-"&set "str=前"
   set /a m=0,y=7
)
for /l %%a in (1 1 %var:-=%) do (
      set/a x%op%=1
      if !x! equ %m% set x=%y%
)
echo %s:-=% 天%str%是星期!.%x%!
endlocal
pause>nul&goto loop
复制代码

@echo off
>星期计算.vbs Echo  aDate = InputBox("请输入一个日期：", "BY: fastslz",date)
>>星期计算.vbs Echo  Wscript.Echo WeekDayName(DatePart("w", aDate))
for /f "delims=" %%i in ('cscript.exe //nologo 星期计算.vbs') do set aDate=%%i&del 星期计算.vbs
Echo %aDate%
pause
复制代码

@echo off
>星期计算.vbs Echo  a = InputBox("计算昨天请输入-1，明天输入1，后天输入2，以此类推：", "BY: fastslz")
>>星期计算.vbs Echo  aDate=FormatDateTime (DateAdd("d", a ,Date),2)
>>星期计算.vbs Echo  Wscript.Echo WeekDayName(DatePart("w", aDate))
for /f "delims=" %%i in ('cscript.exe //nologo 星期计算.vbs') do set aDate=%%i&del 星期计算.vbs
Echo %aDate%
pause
复制代码

 
@echo off
>周计算.vbs Echo  aDate = InputBox("请输入一个日期：", "BY: fastslz",date)
>>周计算.vbs Echo Wscript.Echo  "0" ^&Right(Year(aDate) ,1)^&"年"  ^& DatePart("ww", aDate)^&"周"
for /f "delims=" %%i in ('cscript.exe //nologo 周计算.vbs') do set aDate=%%i&del 周计算.vbs
Echo %aDate%
pause
复制代码

 
@echo off
>天计算.vbs Echo  aDate = InputBox("请输入一个日期：", "BY: fastslz",date)
>>天计算.vbs Echo Wscript.Echo Year(aDate) ^&"年第" ^& DatePart("y", aDate) ^& "天"
for /f "delims=" %%i in ('cscript.exe //nologo 天计算.vbs') do set aDate=%%i&del 天计算.vbs
Echo %aDate%
pause
复制代码

@echo off
:loop
cls&setlocal enabledelayedexpansion
for %%a in (一 二 三 四 五 六 天) do (set /a n+=1 & set ".!n!=%%a" & if "%date:~-1%"=="%%a" set x=!n!)
if not defined x set /a x=4   &rem 如果%date%不包含星期，而今天是星期四，所以令x=4
set /p var=几天前或几天后（前加-）？
set /a "s=((var+x)%%7-7)%%7+7"   &rem 确保s∈[1-7]
if "%var:~,1%" equ "-" (set "str=前") else set "str=后"
echo %var:-=% 天%str%是星期!.%s%!
endlocal&echo.&pause&goto loop
复制代码

@echo off&setlocal enabledelayedexpansion
set "str=日六五四三二一"
set /p day=请指定要追溯的天数：&cls
for /f "tokens=4 delims=:\/- " %%a in ("%date%") do set "xq=%%a"
set /a tian=day&set m=前
if %day% lss 0 (
   set "str=一二三四五六日"
   set /a tian=~day+1&set m=后
)
for /l %%a in (0 1 6) do (
   if not "!str:~0,1!"=="!xq:~-1!" set "str=!str:~1!!str:~0,1!"
)
set /a tian=tian%%7
for /l %%a in (1 1 %tian%) do set "str=!str:~1!!str:~0,1!"
echo %day:-=%天%m%是 星期!str:~0,1!
pause
复制代码

@echo off&setlocal enabledelayedexpansion
for %%a in (1一六 2二五 3三四 4四三 5五二 6六一 0天天) do (
    set "str=%%a"
    set "_!str:~,1!=!str:~1,1!"&set "_!str:~1,1!=!str:~,1!"&set ".!str:~,1!=!str:~2,1!"
)
set /p num=请输入向后的天数:
if %num% lss 0 (set "x=前") else (set "x=后")
if %num% lss -!_%date:~-1%! (set "y=.") else (set "y=_")
set /a d2=num+_%date:~-1%&set "d2=!d2:-=!"
set /a d2=d2%%7
cls&echo.&echo 今天是%date:~-3%，%num:-=%天%x%是星期!%y%%d2%!
pause>nul
复制代码

@echo off&setlocal enabledelayedexpansion
set n=-1
for %%a in (天 一 二 三 四 五 六) do set /a n+=1 & set "%%a=!n!"&set "_!n!=%%a"
set /p n=请指定天数:
if %n% lss 0 (set/a d=^(7-^(~n+1^)%%7+%date:~-1%^)%%7&set x=前)else set/a d=(n+%date:~-1%)%%7&set x=后
echo 今天是 %date:~-3% %n% 天%x% 是%date:~-3,2%!_%d%!
pause
复制代码