@echo off&setlocal enabledelayedexpansion
for /f "delims==" %%a in ('set') do if /i %%a neq path set "%%a="
set /a 层数=200,时间范围=43200
::层数决定为一个初始种子检测多少层，时间范围设置的是向上追溯多少秒

for /l %%a in (1 1 %random:~,2%) do break !random!
::随机引用 n 次 %random%，使种子偏离初始值，对 random 的所有引用次数不能超过预设的层数
ping /n !random:~,1! 127.1 >nul
::随机延时 1 次 %random%，拉开时间差

echo 开始于 !time!

set /a rand1=%random%,rand2=%random%
::获取两个用于参照的随机数，与计算结果完全符合时认定为取得种子

for /f "tokens=1-9 delims=:./\- " %%a in ("!date:~,10! !time!") do (
        set /a "m=(1%%b+29)%%12,y=%%a-m/10,t=365*y+y/4-y/100+y/400+(m*306+5)/10+1%%c-719569"
        set /a t=t*86400+%%d*3600+1%%e*60+1%%f-34900,end=t-t%% 时间范围
)
::换算 1970.1.1 至今的总秒数

for /l %%a in (!t! -1 !end!) do (
        title %%a
        set /a "seed=%%a*0x343fd+0x269ec3,r2=(seed>>0x10)&0x7fff"
        for /l %%b in (1 1 %层数%) do (
                set /a "r1=r2,r2=(seed*0x343fd+0x269ec3>>0x10)&0x7fff,seed=seed*0x343fd+0x269ec3"
                if !r1!_!r2!==%rand1%_%rand2% (
			set /a 时间间隔=t-%%a
			echo 向前追溯共 !时间间隔! 秒
			echo 向上追溯第 %%b 层
                        echo 初始种子为 %%a
                        goto end
                )
        )
)
echo 未能发现种子，可能是因为层数太浅或延时超过 !时间范围! 秒
pause&exit

:end
echo 当前种子为 %seed%
echo 结束于 !time!
echo;

set /a "r=(seed*0x343fd+0x269ec3>>0x10)&0x7fff,seed=seed*0x343fd+0x269ec3"
echo 下个随机数也许是 !r!，按任意键查看
pause>nul
echo !random!
pause
复制代码

for /l %%a in (1 1 %random:~,2%) do rem %random%
复制代码

for /l %%a in (1 1 %random:~,2%) do rem !random!
复制代码