批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]显示内容写入文本指定行，用bat处理谢谢！ [打印本页]

作者: lateol 时间: 2013-4-2 23:07 标题: [已解决]显示内容写入文本指定行，用bat处理谢谢！

本帖最后由 lateol 于 2013-4-5 21:03 编辑

如 echo asdtcll "xxx">>abc.txt

这里有以下规则“
判断 abc.txt文本内第二行是否有asdtcll字符串（如果有则直接覆盖第二行的内容）（如果没有则在第二行插入内容）
要bat处理的不要VBS谢谢！

作者: apang 时间: 2013-4-3 00:20

@echo off
(for /f "delims=" %%a in ('findstr /n .* a.txt') do (
   set "str=%%a"
   setlocal enabledelayedexpansion
   if "!str:~,2!"=="2:" (
      if "!str:asdtcll=!" neq "!str!" (
         echo,asdtcll "xxx"
      ) else (
         echo,asdtcll "xxx"&echo,!str:~2!
      )
   ) else set "str=!str:*:=!"&echo,!str!
   endlocal
))>b.txt
pause
复制代码

作者: lateol 时间: 2013-4-3 21:09

回复 2# apang

为何前面 ('findstr /n .* a.txt') 后面))>b.txt

运行无法打开 a.txt...

作者: apang 时间: 2013-4-3 21:29

回复 3# lateol

我测试没有问题。
提示无法打开a.txt，是因为批处理所在目录下不存在a.txt文件。

作者: lateol 时间: 2013-4-3 21:39

回复 4# apang

那个 a.txt 和b.txt是什么意思？没有目标文件 abc.txt?
新建了一个 a.txt 结果就是生成了个空白的b.txt

作者: apang 时间: 2013-4-3 22:23

改代码，将代码中的a.txt改成实际的abc.txt

作者: lateol 时间: 2013-4-3 22:56

回复 6# apang

明白了它是通过读取然后写入b.txt...
但我把 b.txt改成abc.txt 好像覆盖不了，能不能改成在原文件里完成处理呢？

作者: BAT-VBS 时间: 2013-4-4 11:53

回复 7# lateol

@echo off
(for /f "delims=" %%a in ('findstr /n .* abc.txt') do (
   set "str=%%a"
   setlocal enabledelayedexpansion
   if "!str:~,2!"=="2:" (
      if "!str:asdtcll=!" neq "!str!" (
         echo,asdtcll "xxx"
      ) else (
         echo,asdtcll "xxx"&echo,!str:~2!
      )
   ) else set "str=!str:*:=!"&echo,!str!
   endlocal
))>abc_new.txt
move /y abc_new.txt abc.txt
复制代码

作者: lateol 时间: 2013-4-5 21:02

回复 8# BAT-VBS

真不好意思来晚了，这两比较忙擦~
经过再试 Powerful 给力~ 这样就可以非常感谢~

欢迎光临批处理之家 (http://bbs.bathome.net/)