当指向为非空的句柄被重新设置时要进行备份，而且是备份到第一个没有指向的句柄。
语句运行完后要取回其备份，而不管备份中的句柄指向有没有改变。
如果当前状态下 3 - 9 这七个句柄都有了指向，这时新设置的句柄其原指向将不再备份。
复制代码

另一种表述：也就是说当指向为（空）的句柄被设定时是不需要备份的。如：复制句柄时源句柄不备份，因为没有被再次设置。
补充说明：一个句柄只能存储一个指向。
复制代码

@echo off
echo 哇，这就是传说中的树叶吗？>con 3>nul
echo 我有一片神奇的树叶（吹口哨），
echo 你看不见我，
echo 我现身，>con
echo 我又隐身啦。
echo 谁偷了我的叶子，快还我。>con 4>con
echo 没穿裤裤被你们看到了！
pause>nul
复制代码

:: 句柄模拟.cmd - 模拟运算句柄操作后的句柄状态
:: qzwqzw - 2009-6-12
@echo off & setlocal EnableDelayedExpansion
if [%1]==[] (
    echo. 这是句柄操作示例, 模拟运算进行几次句柄操作后的句柄状态
    echo --------------------- call %~n0 "1>&2" "3>nul" ---------------------
    call %0 "1>&2" "3>nul" >nul
    set 句柄
    echo.
    echo --------------------- call %~n0 "1>&2" "4>file1.txt" ---------------------
    call %0 "1>&2" "4>file1.txt" >nul
    set 句柄
    echo.
    echo --------------------- call %~n0 "1>&2" "5>con" ---------------------
    call %0 "1>&2" "5>con" >nul
    set 句柄
    echo.
    pause
    goto :eof
)
set "0=con" & set "1=con" & set "2=con"
for %%h in (%句柄%) do set %%h
echo.----- 起始状态 Initiation state -----
for %%h in (0 1 2 3 4 5 6 7 8 9) do set/p=%%h=!%%h! <nul
echo.

echo.----- 预处理 Pre-process -----
:loop
if [%1]==[] goto :end
echo.----- %1 -------
set "_tmp=%~1"
set _句柄=%_tmp:~0,1%
set _句柄_2=
set _dev=
if "%_tmp:~2,1%"=="&" (set _句柄_2=%_tmp:~3%) else (set _dev=%_tmp:~2%)
for %%h in (0 1 2 3 4 5 6 7 8 9) do (
    if "!%%h!"=="" (
        set/p=b: %_句柄%[!%_句柄%!]=^>%%h[!%%h!] : <nul
        set "%%h=!%_句柄%!"
        set bak_%%h=%_句柄%
        goto :set
    )
)
:set
for %%h in (0 1 2 3 4 5 6 7 8 9) do set/p=%%h=!%%h! <nul
echo.
if defined _dev (
    set/p=a: %_dev%=^>%_句柄%[!%_句柄%!] : <nul
    set %_句柄%=%_dev%
) else if defined _句柄_2 (
    set/p=a: %_句柄_2%[!%_句柄_2%!]=^>%_句柄%[!%_句柄%!] : <nul
    set %_句柄%=!%_句柄_2%!
)
for %%h in (0 1 2 3 4 5 6 7 8 9) do set/p=%%h=!%%h! <nul
echo.
shift
goto :loop

:end
echo.----- 后处理 Post-process -----
for %%h in (0 1 2 3 4 5 6 7 8 9) do (
    if not "!bak_%%h!"=="" (
        set/p=r: !bak_%%h![]^<=%%h[!%%h!] : <nul
        set !bak_%%h!=!%%h!
        set %%h=
        set bak_%%h=
        for %%h in (0 1 2 3 4 5 6 7 8 9) do set/p=%%h=!%%h! <nul
        echo.
    )
)
set 句柄=
for %%h in (0 1 2 3 4 5 6 7 8 9) do set 句柄=!句柄! "%%h=!%%h!"
endlocal & set 句柄=%句柄%
echo.----- 结束状态 End Status -----
for %%h in (%句柄%) do set/p=%%~h <nul
echo.
复制代码

abc
复制代码

'abc' 不是内部或外部命令，也不是可运行的程序
或批处理文件。
复制代码

abc 3>nul 2>&3
复制代码

set /p name=输入
复制代码

echo %name%
复制代码

set /p p=输入 3<a.txt 0<&3
复制代码

echo %p%
复制代码