批处理之家 - Powered by Discuz! Board

标题: [文件操作] 【已解决】批处理:帮忙改一下重命名文件的脚本啊 [打印本页]

作者: 001011 时间: 2013-8-18 06:45 标题: 【已解决】批处理:帮忙改一下重命名文件的脚本啊

本帖最后由 001011 于 2013-8-18 09:03 编辑

下面的这个脚本，原先设计的改变jpg的文件名。现在的一批文件夹里面同时有两种格式 jpg和tif 请帮忙改一下叫吧感谢
原先求助的帖子链接：http://www.bathome.net/thread-25445-1-1.html

@echo off&setlocal enabledelayedexpansion
set "mypath=E:\成品\1"
for /r "%mypath%" %%a in (.) do (
  set /a n=0
  for /f "delims=" %%b in ('dir /a-d /b "%%~dpna\*.jpg" 2^>nul') do (
     set /a n+=1&set "num=00!n!"
     ren "%%~dpna\%%b" "%%~na-!num:~-3!.jpg"
  )
)
复制代码

作者: canyuexiaolang 时间: 2013-8-18 07:24

好歹也是二级士官了，难道一点都没学么。

@echo off&setlocal enabledelayedexpansion
set "mypath=E:\成品\1"
for /r "%mypath%" %%a in (.) do (
  set /a n=0
  for /f "delims=" %%b in ('dir /a-d /b "%%~dpna\*.jpg" 2^>nul ^& dir /a-d /b "%%~dpna\*.wma" 2^>nul') do (
     set /a n+=1&set "num=00!n!"
     echo ren "%%~dpna\%%b" "%%~na-!num:~-3!%%~xb"
  )
)
pause
复制代码

作者: gawk 时间: 2013-8-18 08:40

@echo off
setlocal enabledelayedexpansion
set "mypath=E:\成品\1"
for /r "%mypath%" %%a in (.) do (
    set n=0
    for /f "delims=" %%b in ('dir /a-d /b "%%~dpna\" 2^>nul') do (
        set /a n+=1
        set "num=00!n!"
        ren "%%~dpna\%%b" "%%~na-!num:~-3!%%~xb"
    )
)
复制代码

作者: 001011 时间: 2013-8-18 09:02

非常感谢不是没学只是按照我所学的测试了几次都没有成功
我再努力

作者: CrLf 时间: 2013-8-18 11:12

个人比较喜欢 set /a n+=1001 来代替 set /a n+=1&set "num=00!n!"
仅适用低于 %06d 的格式

欢迎光临批处理之家 (http://bbs.bathome.net/)