批处理之家 - Powered by Discuz! Board

标题: [问题求助] [已解决]vbs怎么读取网页指定内容 [打印本页]

作者: 522235677 时间: 2013-9-1 21:20 标题: [已解决]vbs怎么读取网页指定内容

本帖最后由 522235677 于 2013-9-29 09:18 编辑

最好是不要生成临时文件。
比如读取http://www.ip138.com/ips138.asp?ip=www.baidu.com&action=2
绿色的文字

作者: wcymiss 时间: 2013-9-27 14:56

Dim strText
with CreateObject("MSXml2.xmlhttp")
	.Open "GET","http://www.ip138.com/ips138.asp?ip=www.baidu.com&action=2",false
	.Send
	strText = ByteToStr(.Responsebody)
end with
strText = Split(Split(strText,"<td align=""center""><ul class=""ul1""><li>")(1),"</li></ul></td>")(0)
strText = Replace(strText,"</li><li>",vbCr)
MsgBox strText
WScript.Quit

Function ByteToStr(ByVal arrByte)
    With CreateObject("Adodb.Stream")
        .Type = 1 'adTypeBinary
        .Open
        .Write arrByte
        .Position = 0
        .Type = 2 'adTypeText
        .Charset = "GB2312"
        ByteToStr = .Readtext
        .Close
    End With
End Function
复制代码

作者: 522235677 时间: 2013-9-27 16:07

本帖最后由 522235677 于 2013-9-27 16:17 编辑

回复 2# wcymiss

感谢，但是这个我想把这个数据显示在CMD中。那个MsgBox strText改为WScript.echo strText

for /f %%i in ('"cscript //nologo 1.vbs"') do echo %%i
复制代码

但是只能显示第一行，不能显示第二行

本站主数据：浙江省杭州市
Press any key to continue . . .
复制代码

作者: wcymiss 时间: 2013-9-28 23:11

strText = Replace(strText,"</li><li>",vbCr)
改成
strText = Replace(strText,"</li><li>",vbtab)

作者: 522235677 时间: 2013-9-29 09:17

回复 4# wcymiss

333333333333333333333qqqqqqqqqqqqqqqqqqqqqqqqqqqq

欢迎光临批处理之家 (http://bbs.bathome.net/)

Powered by Discuz! 7.2