批处理之家 - Powered by Discuz! Board

标题: [文本处理] 【已解决】修改bat :合并多个txt文档中对应的行 [打印本页]

作者: 思想之翼 时间: 2013-10-31 04:05 标题: 【已解决】修改bat :合并多个txt文档中对应的行

本帖最后由思想之翼于 2013-11-3 13:31 编辑

下述BAT处理如下文本：
a.txt为
w e
w e
w e
b.txt为
c d
c d
c d
合并后为c.txt
w e c d
w e c d
w e c d

@echo off
setlocal enabledelayedexpansion
set n1=0
for /f "delims=" %%a in (a.txt) do (
set /a n1=n1+1
set n2=0
for /f "delims=" %%b in (b.txt) do (
set /a n2=n2+1
if !n1! equ !n2! (
echo %%a %%b>>c.txt
)
)
)
pause

实际运用中有所变化，需要合并如下21个txt文本：
1.txt为
1
2
3

2.txt为
2
3
4
...

21.txt为
7
8
9

这21个txt文本欲合并对应的行，结果文本c.txt为
1 2...7
2 3...8
3 4...9

上述BAT代码如何修改？恳望得到帮助。

作者: foxJL 时间: 2013-10-31 09:28

本帖最后由 foxJL 于 2013-10-31 16:10 编辑

你的代码结构不对,要处理21个文件太难
我写了个,你看看.时间太赶没有想出更好的方法

@echo off & setlocal enabledelayedexpansion
for /l %%i in (1,1,4) do (
  set "n="
  for /f %%j in (%%i.txt) do (set /a n+=1 & set str_%%i_!n!=%%j)
)
for /l %%i in (1,1,4) do (
  for /l %%j in (1,1,4) do (set/p=!str_%%j_%%i!<nul)
  echo,
)
pause
复制代码

作者: 思想之翼 时间: 2013-10-31 11:20

回复 2# foxJL

谢谢您的热心帮助！
您的代码经过测试，只能合并4个txt文本。如要合并21个，或63个txt，代码如何修改？恳望继续得到您的帮助。

作者: foxJL 时间: 2013-10-31 11:30

把代码里for/l后的1,1,4改成1,1,21就行了.

作者: xxpinqz 时间: 2013-10-31 11:41

@echo off&setlocal enabledelayedexpansion
set 文件数=21
for /l %%a in (1,1,%文件数%) do (
    for /f "delims=" %%i in (%%a.txt) do (
        set /a n+=1
        for %%a in (!n!) do set "#%%a=!#%%a! %%i"
    )
    set /a m=n,n=0
)
(for /l %%a in (1,1,%m%) do echo,!#%%a:~1!)>all.txt
复制代码

作者: apang 时间: 2013-10-31 15:28

回复 2# foxJL

貌似 str_%%i_!n!=%%j 比 str_%%i!n!=%%j 好些吧？
%%i值为1、n值为23，与%%i值为12、n值为3时set表达式是一样的，比如：set str_123=aaa

作者: jy01299802 时间: 2013-10-31 15:52

学到新东西了

作者: foxJL 时间: 2013-10-31 16:11

回复 6# apang

疏忽了,感谢提醒!

欢迎光临批处理之家 (http://bbs.bathome.net/)