批处理之家 - Powered by Discuz! Board

标题: [ 新手习题 9 ] 批处理交换歌曲与歌手 [打印本页]

作者: wxcute 时间: 2008-12-17 18:52 标题: [ 新手习题 9 ] 批处理交换歌曲与歌手

可以是中文歌曲，也可以是英文歌曲。如果你想统一歌曲文件名，歌手都放前面或是都放后面。可能要进行如下操作，可是如果手工来改的话，要前面复制一下后面再复制一下，会很麻烦。
问题来了，拖一个文件到批处理图标上，自动对调歌手与歌曲名。

其中歌名可以由汉字、英语、数字组成，英文歌曲会有空格，但不含特殊符号；
歌手也可以是组合、艺名，也不含特殊符号；
中间用 “ - ” 连接，即（空格）-（空格）。

老狼 - 同桌的你.mp3　　　　　——>　　同桌的你 - 老狼.mp3
Mirror Mirror - M2M.mp3　　——>　　M2M - Mirror Mirror.mp3
复制代码

目的：学习参数的使用，可能用到 for，或是变量替换。

要求：歌曲与歌手对调，本题基本要求是能处理一个文件，当然你想多个一起交换也不反对；不考虑特殊字符。方法不限。

评分：代码可读性 1 分；
　　　首个新方法 6 分，第二个 5 分，依次类推，最少 2 分；
　　　一人可多种方法，新方法追加 3 分，已经出现过的方法追加 1 分。
=========================================
谢谢随风兄提醒，已添加说明。

[ 本帖最后由 wxcute 于 2008-12-17 19:32 编辑 ]

作者: 随风 时间: 2008-12-17 19:19

是否应该说明一下文件名的规律？比如：歌手名和歌曲名是用－号割开的，文件名中是否有多个－号？

作者: tireless 时间: 2008-12-17 22:53

1、

@echo off & setlocal EnableDelayedExpansion
for %%A in (%*) do (
  for /f "tokens=1,* delims=-" %%a in ("%%~nA") do (
    set "L=%%a" & set "R=%%b"
    ren %%A "!R:~1! - !L:~,-1!.mp3"
  )
)
复制代码

2、

@echo off & setlocal EnableDelayedExpansion
for %%A in (%*) do (
  set str=%%~nA
  for /f "delims=\ tokens=1,2" %%a in ("!str: - =\!") do (
    ren %%A "%%b - %%a.mp3"
  )
)
复制代码

[ 本帖最后由 tireless 于 2008-12-18 08:05 编辑 ]

作者: httydolphin 时间: 2008-12-18 10:55

好的看完 OK 批处理下吧

作者: yuhaodong 时间: 2008-12-19 05:15 标题: 答案

@title 更名
@echo off
color 1f
setlocal EnableDelayedExpansion
:kaishi
set /p dir=请输入路径:
if exist %dir%\*.mp3 (for %%i in (%dir%\*.mp3) do (echo %%i >>tmp.txt)) else (echo 路径错误或*.mp3不存在&goto kaishi)
for /f "delims=\-. tokens=1,2,3,4,5,6,7,8,9" %%a in (tmp.txt) do echo %%a %%b %%c %%d %%e %%f %%g %%h %%i %%j %%k %%l %%m %%n %%o %%p %%q %%r %%s %%t %%u %%v %%w %%x %%y %%z >>1.txt
for /f "delims=%%" %%a in (1.txt) do (echo %%a >>2.txt)
for /f "delims=," %%a in (2.txt) do (
set /a s=0
for %%i in (%%a) do set /a s=!s!+1
set /a s1=!s!-2
set /a s2=!s!-1
)
for /f "tokens=%s1%,%s2%" %%a in (2.txt) do (ren "%dir%\%%a - %%b.mp3" "%%b - %%a.mp3" 2>nul
ren "%dir%\%%a-%%b.mp3" "%%b-%%a.mp3" 2>nul
)
del 1.txt
del 2.txt
del tmp.txt
set /p a=文件名已经更改完毕<nul
pause
start %dir%
exit

作者: yuhaodong 时间: 2008-12-19 05:21

@title 更名
@echo off
color 1f
setlocal EnableDelayedExpansion
:kaishi
set /p dir=请输入路径:
if exist %dir%\*.mp3 (for %%i in (%dir%\*.mp3) do (echo %%i >>tmp.txt)) else (echo 路径错误或*.mp3不存在&goto kaishi)
for /f "delims=\-. tokens=1,2,3,4,5,6,7,8,9" %%a in (tmp.txt) do echo %%a %%b %%c %%d %%e %%f %%g %%h %%i %%j %%k %%l %%m %%n %%o %%p %%q %%r %%s %%t %%u %%v %%w %%x %%y %%z >>1.txt
for /f "delims=%%" %%a in (1.txt) do (echo %%a >>2.txt)
for /f "delims=," %%a in (2.txt) do (
set /a s=0
for %%i in (%%a) do set /a s=!s!+1
set /a s1=!s!-2
set /a s2=!s!-1
)
for /f "tokens=%s1%,%s2%" %%a in (2.txt) do (ren "%dir%\%%a - %%b.mp3" "%%b - %%a.mp3" 2>nul
ren "%dir%\%%a-%%b.mp3" "%%b-%%a.mp3" 2>nul
)
del 1.txt
del 2.txt
del tmp.txt
set /p a=文件名已经更改完毕<nul
pause
start %dir%
exit

作者: yuhaodong 时间: 2008-12-19 05:51

@title 更名
@echo off
color 1f
setlocal EnableDelayedExpansion
:kaishi
set /p dir=请输入路径

格式: X:\..\.. 例如 c:\music)
if exist %dir%\*.mp3 (for %%i in (%dir%\*.mp3) do (echo %%i >>tmp.txt)) else (echo 路径错误或*.mp3不存在&goto kaishi)
for /f "delims=\-. tokens=1,2,3,4,5,6,7,8,9" %%a in (tmp.txt) do echo %%a %%b %%c %%d %%e %%f %%g %%h %%i %%j %%k %%l %%m %%n %%o %%p %%q %%r %%s %%t %%u %%v %%w %%x %%y %%z >>1.txt
for /f "delims=%%" %%a in (1.txt) do (echo %%a >>2.txt)
for /f "delims=," %%a in (2.txt) do (
set /a s=0
for %%i in (%%a) do set /a s=!s!+1
set /a s1=!s!-2
set /a s2=!s!-1

)
for /f "tokens=%s1%,%s2%" %%a in (2.txt) do (ren "%dir%\%%a - %%b.mp3" "%%b - %%a.mp3" 2>nul
ren "%dir%\%%a-%%b.mp3" "%%b-%%a.mp3" 2>nul
)
del 1.txt
del 2.txt
del tmp.txt
set /p a=文件名已经更改完毕<nul
pause
start %dir%
exit

作者: leaparde 时间: 2008-12-26 16:26

@echo off
title Replace the filename
color 1f
mode con:cols=80 lines=30
setlocal enabledelayedexpansion
::列出当前目录下所有文件及文件夹
dir /b>tmp
::findstr用来找出所有的mp3
for /f "tokens=*" %%a in ('findstr ".mp3" "tmp"') do (
   set str=%%a
::把文件名中的“空格-空格”替换成“-”
   set str=!str: - =-!
::歌曲名称和歌手互换
   for /f "tokens=1-3 delims=-." %%i in ("!str!") do (
      set name=%%i
      set music=%%j
      echo %%a  change to !music! - !name!.mp3
      rename "%%a" "!music! - !name!.mp3"
      )
)
echo.
echo 以上文件改名成功！
del /f /q tmp
pause>nul
复制代码

空格不太会处理，代码感觉有点繁了，期待高手指点指点啊!

[ 本帖最后由 leaparde 于 2008-12-26 16:33 编辑 ]

作者: i520king 时间: 2009-11-13 10:12

学习学习了

作者: zgq0301 时间: 2009-11-13 13:15

@echo off 
for %%i in (*.mp3) do (
     for /f "delims=-. tokens=1,2" %%a  in ("%%i") do (
          ren %%i  %%b-%%a.mp3
          )
  )
  pause>nul
复制代码

[ 本帖最后由 zgq0301 于 2009-11-13 13:17 编辑 ]

作者: battab 时间: 2014-2-18 22:16

本帖最后由 battab 于 2014-2-18 22:20 编辑

回复 1# wxcute

@echo off
set name=%~nx1
for /f "tokens=1,2,3 delims=-." %%a in ("%name%") do set new_name=%%b - %%a.%%c
move /y %1 "C:\Documents and Settings\Administrator\桌面\%new_name%"
复制代码

注意:最后重命名成新名字的路径要给出到目标地址上，否则默认存在...\Administrator\下!

作者: fcxk 时间: 2015-5-19 14:15

@echo off
for /f "tokens=1-3* delims=-." %%i in (1.txt) do (
echo;%%j - %%i.%%k
)
pause

偷懒的方法

作者: fcxk 时间: 2015-5-19 14:57

@echo off
setlocal EnableDelayedExpansion
for %%i in (%*) do (
set vv=%%~nxi
for /f "tokens=1-3* delims=-." %%i in ('type "!vv%%i!"') do echo;%%j - %%i.%%k
)
pause

拖放功能

作者: 437153 时间: 2015-6-8 12:04

@echo off
for %%a in (%*) do (
	for /f "tokens=1,2,3 delims=-. " %%i in ("%%~nxa") do (
		ren "%%~nxa" "%%j - %%i.%%k"
	)
)
复制代码

作者: 437153 时间: 2015-6-8 15:20

回复 3# tireless

高，学习了。字符截取原来有如此妙用！

作者: smss 时间: 2018-12-24 16:47

1、2、

[ 本帖最后由 tireless 于 2008-12-18 08:05 编辑 ]
tireless 发表于 2008-12-17 22:53

我试了下上边的所有脚本会导致文件名-左右删字符
如：AAA-BBB 会生成 BB-AA
然而我们需要的是生成BBB-AAA

以下提供可用脚本

@echo off&setlocal EnableDelayedExpansion  
for /f "tokens=1,2 delims=-." %%a in ('dir /b *.mp3') do (
set var=%%a
::去除var变量左边第一个空格
if "!var:~0,1!"==" " set var=!var:~1!
if "!var:~0,1!"==" " set var=!var:~1!
if "!var:~0,1!"==" " set var=!var:~1!
if "!var:~0,1!"==" " set var=!var:~1!
if "!var:~0,1!"==" " set var=!var:~1!
if "!var:~0,1!"==" " set var=!var:~1!
if "!var:~0,1!"==" " set var=!var:~1!
if "!var:~0,1!"==" " set var=!var:~1!
::去除var变量右边第一个空格
if "!var:~-1!"==" " set var=!var:~0,-1!
if "!var:~-1!"==" " set var=!var:~0,-1!
if "!var:~-1!"==" " set var=!var:~0,-1!
if "!var:~-1!"==" " set var=!var:~0,-1!
if "!var:~-1!"==" " set var=!var:~0,-1!
if "!var:~-1!"==" " set var=!var:~0,-1!
if "!var:~-1!"==" " set var=!var:~0,-1!
if "!var:~-1!"==" " set var=!var:~0,-1!
set jar=%%b
::去除jar变量左边第一个空格
if "!jar:~0,1!"==" " set jar=!jar:~1!
if "!jar:~0,1!"==" " set jar=!jar:~1!
if "!jar:~0,1!"==" " set jar=!jar:~1!
if "!jar:~0,1!"==" " set jar=!jar:~1!
if "!jar:~0,1!"==" " set jar=!jar:~1!
if "!jar:~0,1!"==" " set jar=!jar:~1!
if "!jar:~0,1!"==" " set jar=!jar:~1!
if "!jar:~0,1!"==" " set jar=!jar:~1!
::去除jar变量右边第一个空格
if "!jar:~-1!"==" " set jar=!jar:~0,-1!
if "!jar:~-1!"==" " set jar=!jar:~0,-1!
if "!jar:~-1!"==" " set jar=!jar:~0,-1!
if "!jar:~-1!"==" " set jar=!jar:~0,-1!
if "!jar:~-1!"==" " set jar=!jar:~0,-1!
if "!jar:~-1!"==" " set jar=!jar:~0,-1!
if "!jar:~-1!"==" " set jar=!jar:~0,-1!
if "!jar:~-1!"==" " set jar=!jar:~0,-1!
::重命名文件
ren "%%a-%%b.mp3" "!jar!-!var!.mp3"
)
复制代码

作者: xczxczxcz 时间: 2018-12-24 18:09

回复 16# smss

微软给我们的 WINDOWS 提供了更好的工具不用，还要这么绕脑。

Powershell :

$a -replace '\s+','' -replace '(.*)-(.*)\.(.*)','$2 - $1.$3'
复制代码

作者: smss 时间: 2018-12-30 16:26

本帖最后由 smss 于 2018-12-30 16:28 编辑

回复 smss

微软给我们的 WINDOWS 提供了更好的工具不用，还要这么绕脑。

Powershell :
xczxczxcz 发表于 2018-12-24 18:09

测试无效

作者: Batcher 时间: 2018-12-30 17:09

回复 18# smss

操作系统什么版本？PowerShell什么版本？把你的测试用例和测试结果发出来看看吧

作者: smss 时间: 2019-1-1 18:52

回复 smss

操作系统什么版本？PowerShell什么版本？把你的测试用例和测试结果发出来看看吧
Batcher 发表于 2018-12-30 17:09

作者: xczxczxcz 时间: 2019-1-1 20:09

回复 20# smss

首先这句脚本写的是改名的正则表达式，没有文件浏览。它当然不能产生任何作用。

看图片，你的系统好像是 win10。WIN7以上自带PWOERSHELL。无需复制PS程序。可以在PS窗口或用PS脚本直接运行。

如修改你的图片所示的RAR文件。

dir *.rar | ren -newname {$_.name -replace '\s+','' -replace '(.*)-(.*)\.(.*)','$2-$1.$3'} -verb
cmd /c "echo;&pause"
复制代码

元旦太冷。

作者: smss 时间: 2019-1-2 21:44

本帖最后由 smss 于 2019-1-2 21:59 编辑

回复 smss

首先这句脚本写的是改名的正则表达式，没有文件浏览。它当然不能产生任何作用。

看图片， ...
xczxczxcz 发表于 2019-1-1 20:09

无论在BAT中还是PowerShell中都无效

作者: xczxczxcz 时间: 2019-1-5 11:32

回复 22# smss

老大，你先确定好工作目录行不行？CD /D ?

作者: miqilaosu 时间: 2019-6-10 11:45

本帖最后由 miqilaosu 于 2019-6-10 16:39 编辑

echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=-" %%i in ('dir /a-d /b "*-*.*"') do (

ren "%%i-%%~nxj" "!str2! - !str1!%%~xj"
)
pause
复制代码

新人交作业

……………………………………………………………………………………………………………………

if "!str1:~0,-1!"==" " call  set /a "str1=!str1:~0,-1!"
复制代码

为什么我替换时数字没问题汉字就出错了

作者: gdfyhao 时间: 2019-7-21 11:11

刚开始学，真的看不懂，还得努力才行

作者: netdzb 时间: 2019-7-22 00:38

回复 10# zgq0301

代码有问题，更名后，文件名带空格。

作者: impk 时间: 2019-8-23 12:31

本帖最后由 impk 于 2019-8-23 13:05 编辑

@echo off
for %%a in ( *.mp3 ) do (
 for /f "tokens=1,2 delims=-. " %%i in ( "%%a" ) do ( ren "%%a" "%%j - %%i.mp3" )
 )
pause
复制代码

这样写不对，如【Mirror Mirror - M2M.mp3】这种歌名里有空格的，这批处理就无效
16楼是正确答案

作者: impk 时间: 2019-8-23 13:14

本帖最后由 impk 于 2019-8-23 13:18 编辑

@echo off
setlocal EnableDelayedExpansion  
for /f "tokens=1,2 delims=-." %%a in ( 'dir /b *.mp3' ) do ( 
set vara=%%a
if "!vara:~0,1!"==" " set vara=!vara:~1!
if "!vara:~-1!"==" " set vara=!vara:~0,-1!
set varb=%%b
if "!varb:~0,1!"==" " set varb=!varb:~1!
if "!varb:~-1!"==" " set varb=!varb:~0,-1!
ren "%%a-%%b.mp3" "!varb! - !vara!.mp3"
)
pause
复制代码

作者: guzm002 时间: 2021-3-29 22:39

为什么都只改4个文件就停了

作者: ycjsplxp 时间: 2023-3-23 20:21

回复 8# leaparde
大佬是直接复制编辑bat文件就可以用吗咋用没研究明白😊

作者: ycjsplxp 时间: 2023-3-23 20:26

回复 16# smss
大佬只支持 mp3吗，别的音频格式再怎么加

欢迎光临批处理之家 (http://bbs.bathome.net/)