批处理之家 - Powered by Discuz! Board

标题: [文本处理] 【已解决】横着两个数字塔的效果BAT批处理怎么写？ [打印本页]

作者: battab 时间: 2014-1-25 10:36 标题: 【已解决】横着两个数字塔的效果BAT批处理怎么写？

@echo off
for /l %%a in (0,1,1) do (
	for /l %%i in (0,1,9) do (
	for /l %%j in (0,1,%%i) do set /p=%%j<nul
	echo=
	)
)
pause
复制代码

我这个BAT可以竖下来输出2个数字塔，如果我想达到附件里效果要怎么写呢？

作者: weichenxiehou 时间: 2014-1-25 15:38

回复 1# battab

@echo off&setlocal enabledelayedexpansion
set "space=          "
for /l %%i in (0,1,9) do (
	set/a n=10-%%i,m=%%i-1
	for %%z in (!n!) do set t=!space:~,%%z!
	for /l %%j in (0,1,!m!) do set /p=%%j<nul
	set/p=%%i!t!<nul
	for /l %%j in (0,1,%%i) do set /p=%%j<nul
	echo,
)
pause
复制代码

作者: apang 时间: 2014-1-25 15:42

@echo off & setlocal enabledelayedexpansion
for /l %%i in (0 1 9) do set "sp=!sp! "
for /l %%i in (0 1 9) do (
    set "s="
    for /l %%j in (0 1 %%i) do set "s=!s!%%j"
    set "str=!s!!sp!"
    echo,!str:~,11!!s!
)
pause
复制代码

作者: CrLf 时间: 2014-1-25 18:44

本帖最后由 CrLf 于 2014-1-25 20:03 编辑

继续发另类解：

@echo off
%1 cmd /v /c @%0 :|more /t11&pause&exit

for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
for /l %%a in (0 1 9) do set str=!str!%%a&echo !str!!tab!!str!
复制代码

作者: simon4055 时间: 2014-1-25 20:43

这个好 mark一下留着用.
学习了..

作者: terse 时间: 2014-1-27 14:43

这样简化

@echo off&setlocal enabledelayedexpansion
for /l %%i in (0 1 9) do set "sp=!sp! "
for /l %%i in (0 1 9) do (
    set "str=!str!%%i"
    echo !str!!sp:~%%i!!str!
)
pause
复制代码

作者: mq0036 时间: 2014-2-8 14:31

本帖最后由 mq0036 于 2014-2-8 14:32 编辑

我也给个自己写的，把第二个for的参数改下，横向的可以打印1，2，3，4，5，6........个数字塔

@echo off
for /l %%i in (0,1,9) do (
for /l %%j in (0,1,1) do (
for /l %%k in (0,1,10) do (
if %%k leq %%i (set /p =%%k<nul) else (set /p = <nul)
)
)
echo.
)
echo.
复制代码

作者: DAIC 时间: 2014-2-8 20:10

回复 7# mq0036

不要把所有的代码都顶格写

@echo off
for /l %%i in (0,1,9) do (
    for /l %%j in (0,1,1) do (
        for /l %%k in (0,1,10) do (
            if %%k leq %%i (
                set /p =%%k<nul
            ) else (
                set /p = <nul
            )
        )
    )
    echo.
)
echo.
复制代码

作者: battab 时间: 2014-2-8 21:20

本帖最后由 battab 于 2014-2-8 21:21 编辑

回复 4# CrLf

这个确实很另类，看得一头雾水，谁能解说下，谢谢先！

作者: mq0036 时间: 2014-2-11 15:48

回复 8# DAIC

呵呵，用别人的电脑，随手拿记事本写的，手头也没有现成的工具可用。

欢迎光临批处理之家 (http://bbs.bathome.net/)