Board logo

标题: [文本处理] 紧急求助:删除指定路径下指定天数之前（以文件的创建日期为准）的文件 [打印本页]
作者: shugeer    时间: 2014-10-15 13:45     标题: 紧急求助:删除指定路径下指定天数之前（以文件的创建日期为准）的文件

我采用的是这个帖子的方案四(以文件的创建日期为准),在演示过程中我的文件创建日期不在指定的范围内也会删除,这是为什么?
http://bbs.bathome.net/thread-3334-1-1.html
作者: Batcher    时间: 2014-10-15 13:52

在第50行代码上面加一行：
echo "%%h" leq "%DstDate%"
测试结果发出来看看
作者: shugeer    时间: 2014-10-15 14:23

回复 2# Batcher

加入上面代码后显示如下面(抱歉上传不了图片):del /a /f /q "D:\DCIM\823WGTMA\IMG_1197.JPG"
"2014/09/04" leq "2014-08-31"
del /a /f /q "D:\DCIM\823WGTMA\IMG_1218.JPG"
"2014/09/04" leq "2014-08-31"
del /a /f /q "D:\DCIM\823WGTMA\IMG_1219.JPG"
"2014/09/04" leq "2014-08-31"

这些文件是2014/09/04日创建的，距今计算日期是41天，我现在设置了日期为45天之前的，但现在还是删除了
应该是日期计算的错误，求Batcher大神修改下,谢谢!

原代码如下
  1. @echo off

  2. ::演示：删除指定路径下指定天数之前（以文件的创建日期为准）的文件。

  3. ::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。

  4. ::本例调用了 Ritchie Lawrence 的日期函数进行日期计算

  5. ::日期转换的核心算法请参考http://bbs.bathome.cn/thread-3056-1-1.html

  6. ::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，

  7. ::处理完毕之后再把日期格式恢复成原来的状态。

  8. 

  9. rem 指定待删除文件的存放路径

  10. set SrcDir=D:\DCIM\823WGTMA

  11. rem 指定天数

  12. set DaysAgo=45

  13. for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (

  14.     set "RegDateOld=%%a"

  15. )

  16. set RegDateOld=%RegDateOld:~-8%

  17. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul

  18. call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays

  19. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul

  20. set /a PassDays-=%DaysAgo%

  21. call :DaysToDate %PassDays% DstYear DstMonth DstDay

  22. set DstDate=%DstYear%-%DstMonth%-%DstDay%

  23. 

  24. for /f "delims=/" %%a in ('dir /s /b /a-d "%SrcDir%"') do (

  25.     call :CompareTime "%%a"

  26. )

  27. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul

  28. pause

  29. goto :eof

  30. 

  31. :DateToDays %yy% %mm% %dd% days

  32. setlocal ENABLEEXTENSIONS

  33. set yy=%1&set mm=%2&set dd=%3

  34. if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)

  35. set /a dd=100%dd%%%100,mm=100%mm%%%100

  36. set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2

  37. set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633

  38. endlocal&set %4=%j%&goto :EOF

  39. 

  40. :DaysToDate %days% yy mm dd

  41. setlocal ENABLEEXTENSIONS

  42. set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a

  43. set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5

  44. set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10

  45. (if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)

  46. endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

  47. 

  48. :CompareTime

  49. for /f "skip=5 tokens=1-2 delims= " %%h in ('dir /a-d /tc %1') do (

  50. echo "%%h" leq "%DstDate%"

  51.     if "%%h" leq "%DstDate%" (

  52.         if exist %1 (

  53.             echo del /a /f /q %1

  54.         )

  55.     )

  56.     goto :eof

  57. )
复制代码
作者: Batcher    时间: 2014-10-15 14:29

回复 3# shugeer


打开一个CMD窗口，依次执行这三个命令：
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f
reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate
dir /a-d /tc

结果发出来
不用截图，我能看到结果就行。
作者: shugeer    时间: 2014-10-15 15:02

回复 4# Batcher

结果如下:
C:\Users\EGNTT>reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShor
Date /t REG_SZ /d yyyy-M-d /f
操作成功完成。

C:\Users\EGNTT>reg query "HKEY_CURRENT_USER\Control Panel\International" /v sSh
rtDate

HKEY_CURRENT_USER\Control Panel\International
    sShortDate    REG_SZ    yyyy-M-d


C:\Users\EGNTT>dir /a-d /tc
驱动器 C 中的卷没有标签。
卷的序列号是 EE81-3F3B

C:\Users\EGNTT 的目录

2014-08-17  09:09           153,956 gpreport.html
2014-08-01  12:44         3,932,160 NTUSER.DAT
2014-08-01  12:44           565,248 ntuser.dat.LOG1
2014-08-01  12:44                 0 ntuser.dat.LOG2
2014-08-01  12:44            65,536 NTUSER.DAT{2b468684-d713-11e1-8545-a4badb40
f56}.TM.blf
2014-08-01  12:44           524,288 NTUSER.DAT{2b468684-d713-11e1-8545-a4badb40
f56}.TMContainer00000000000000000001.regtrans-ms
2014-08-01  12:44           524,288 NTUSER.DAT{2b468684-d713-11e1-8545-a4badb40
f56}.TMContainer00000000000000000002.regtrans-ms
2014-08-01  12:44                20 ntuser.ini
2014-08-01  12:44               468 ntuser.pol
               9 个文件      5,765,964 字节
               0 个目录 54,564,569,088 可用字节

C:\Users\EGNTT>
作者: Batcher    时间: 2014-10-15 15:09

回复 5# shugeer


这个结果看起来没有问题。
一般来说修改注册表之后，第50行%%h获取的值应该是"2014-09-04"这种格式，而不应该是"2014/09/04"这种。
你在第49行上面加个延时看看能否解决问题：
ping -n 10 127.1 >nul
作者: shugeer    时间: 2014-10-15 15:57

回复 6# Batcher
我的是win8系统，执行批处理可能不够权限修改注册表，
现在已经用你4楼给出的命令手动修改日期为这种格式了"2014-09-04"，是可以了!
我的系统系统要默认用"2014/09/04"这种格式的,能否帮我修改下代码?
谢谢!
作者: shugeer    时间: 2014-10-15 16:21

回复 6# Batcher

我把代码中日期的"-"符号改为"/"竟然可以了,谢谢Batcher 大神!

  1. @echo off

  2. ::演示：删除指定路径下指定天数之前（以文件的创建日期为准）的文件。

  3. ::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。

  4. 

  5. rem 指定待删除文件的存放路径

  6. set SrcDir=D:\DCIM\823WGTMA

  7. rem 指定天数

  8. set DaysAgo=42

  9. for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (

  10.     set "RegDateOld=%%a"

  11. )

  12. set RegDateOld=%RegDateOld:~-8%

  13. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy/M/d /f>nul

  14. call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays

  15. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul

  16. set /a PassDays-=%DaysAgo%

  17. call :DaysToDate %PassDays% DstYear DstMonth DstDay

  18. set DstDate=%DstYear%/%DstMonth%/%DstDay%

  19. 

  20. for /f "delims=/" %%a in ('dir /s /b /a-d "%SrcDir%"') do (

  21.     call :CompareTime "%%a"

  22. )

  23. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul

  24. pause

  25. goto :eof

  26. 

  27. :DateToDays %yy% %mm% %dd% days

  28. setlocal ENABLEEXTENSIONS

  29. set yy=%1&set mm=%2&set dd=%3

  30. if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)

  31. set /a dd=100%dd%%%100,mm=100%mm%%%100

  32. set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2

  33. set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633

  34. endlocal&set %4=%j%&goto :EOF

  35. 

  36. :DaysToDate %days% yy mm dd

  37. setlocal ENABLEEXTENSIONS

  38. set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a

  39. set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5

  40. set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10

  41. (if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)

  42. endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

  43. 

  44. :CompareTime

  45. for /f "skip=5 tokens=1-2 delims= " %%h in ('dir /a-d /tc %1') do (

  46.     if "%%h" leq "%DstDate%" (

  47.         if exist %1 (

  48.             echo del /a /f /q %1

  49.         )

  50.     )

  51.     goto :eof

  52. )
复制代码
作者: Batcher    时间: 2014-10-15 16:41

回复 8# shugeer


是的。
如果你的系统默认日期格式是 yyyy/mm/dd 的话，可以把注册表相关的语句全部删掉。
  1. @echo off

  2. ::演示：删除指定路径下指定天数之前（以文件的创建日期为准）的文件。

  3. ::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。

  4. 

  5. rem 指定待删除文件的存放路径

  6. set SrcDir=D:\DCIM\823WGTMA

  7. rem 指定天数

  8. set DaysAgo=42

  9. 

  10. call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays

  11. set /a PassDays-=%DaysAgo%

  12. call :DaysToDate %PassDays% DstYear DstMonth DstDay

  13. set DstDate=%DstYear%/%DstMonth%/%DstDay%

  14. 

  15. for /f "delims=/" %%a in ('dir /s /b /a-d "%SrcDir%"') do (

  16.     call :CompareTime "%%a"

  17. )

  18. pause

  19. goto :eof

  20. 

  21. :DateToDays %yy% %mm% %dd% days

  22. setlocal ENABLEEXTENSIONS

  23. set yy=%1&set mm=%2&set dd=%3

  24. if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)

  25. set /a dd=100%dd%%%100,mm=100%mm%%%100

  26. set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2

  27. set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633

  28. endlocal&set %4=%j%&goto :EOF

  29. 

  30. :DaysToDate %days% yy mm dd

  31. setlocal ENABLEEXTENSIONS

  32. set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a

  33. set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5

  34. set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10

  35. (if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)

  36. endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

  37. 

  38. :CompareTime

  39. for /f "skip=5 tokens=1-2 delims= " %%h in ('dir /a-d /tc %1') do (

  40.     if "%%h" leq "%DstDate%" (

  41.         if exist %1 (

  42.             echo del /a /f /q %1

  43.         )

  44.     )

  45.     goto :eof

  46. )
复制代码




欢迎光临 批处理之家 (http://bbs.bathome.net/) Powered by Discuz! 7.2