批处理之家 - Powered by Discuz! Board

标题: [文件操作] [已解决]批处理如何将文件名中以指定字符分割成的两部分字符串/字段调换位置 [打印本页]

作者: laihaibin08 时间: 2015-1-19 10:56 标题: [已解决]批处理如何将文件名中以指定字符分割成的两部分字符串/字段调换位置

我要将某文件夹内格式为*-????????的文件批量重命名为????????-*，求代码，万分感谢。

我这样一个文件夹，其中的文件有以下规律：*-????????（后8位是数字日期格式）。现在我需要对这些文件进行批量重命名，调整为????????-*，谁能帮我写这一段代码？

文件夹内的文件如下图（仅局部截图，这样的文件还有很多）

作者: Batcher 时间: 2015-1-19 12:49

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s /a-d ^| findstr "\-[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]"') do (
    set "s1=%%~ni"
    set "s1=!s1:~-8!"
    set "s2=%%~ni"
    set "s2=!s2:~0,-9!"
    ren "%%i" "!s1!-!s2!%%~xi"
)
复制代码

作者: laihaibin08 时间: 2015-1-19 13:34

回复 2# Batcher

非常感谢，所有的文件都处理成功了，但文件夹中的子文件夹都没有处理。

作者: Batcher 时间: 2015-1-19 13:42

您好，能直接将子文件夹的文件名处理了吗
就是不处理子文件夹里的文件名，而是处理子文件夹本身

下次发帖请把问题一次性描述清楚

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d ^| findstr "\-[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]"') do (
    set "s1=%%~ni"
    set "s1=!s1:~-8!"
    set "s2=%%~ni"
    set "s2=!s2:~0,-9!"
    ren "%%i" "!s1!-!s2!%%~xi"
)
for /f "delims=" %%i in ('dir /b /ad ^| findstr "\-[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]"') do (
    set "s1=%%i"
    set "s1=!s1:~-8!"
    set "s2=%%i"
    set "s2=!s2:~0,-9!"
    ren "%%i" "!s1!-!s2!"
)
复制代码

作者: laihaibin08 时间: 2015-1-19 13:45

回复 4# Batcher

非常感谢，全部处理成功。

（另外，不好意思，还是我没有一次把问题描述清楚）

欢迎光临批处理之家 (http://bbs.bathome.net/)